Converting Autodesk materials
Case expression is your friend:
However, my preference would still be to use the ConvertToGeneric method.
fn convert_Mtl_to_mrArchitectural mtl =
(
if NOT isKindOf mtl Autodesk_Material then mtl
else case (mtl.DefinitionID as name) of
(
#Ceramic : Arch___Design__mi diffuse:mtl.Ceramic_Color diff_color_map:mtl.Ceramic_Color_Map /*...*/
#Concrete : ()
#Generic : ()
#Glazing : ()
#Hardwood : ()
#Masonry_CMU : ()
#Metal : ()
#MetallicPaint : ()
#Mirror : ()
#Plastic_Vinyl : ()
#Solid_glass : ()
#Stone : ()
#Wall_paint : ()
#water : ()
)
)
However, my preference would still be to use the ConvertToGeneric method.
Okay, in that case this is the next best solution. For all the other case branches I didn't fill in, pass the keyword parameters to the Arch___Design__mi constructor just the same way as in the #Ceramic branch.
Yes, there should be no underscore - #MasonryCMU, #PlasticVinyl, #SolidGlass, #WallPaint
Btw. you can pass the material name to the constructor as well, .. vraymtl name:mtl.name .. Makes it a bit more comfortable using the function.
I think you want isProperty, not hasProperty. Also instead of having nested if expressions you can chain them with and, as in most languages it is sort-circuiting operator in MAXScript, too, which means it won't evaluate the next condition if the previous one is false:
if isProperty varMat "Generic_Image" AND classof varMat.Generic_Image == Autodesk_Map then
varGenericTextureName = varMat.Generic_Image.Parameters_Source
You are creating the material and throwing it away instantly. Use the result of conversion - and btw. there's no need to reassign the materials when using replaceInstances.
--ENTIRESCENE:
1:
(
if MaterialType == 1 then with redraw off
(
if sceneMaterials.count == 0 do
return messageBox "There are no materials in your Scene!" title:"Autodsk Converter"
for mat in sceneMaterials do
replaceInstances mat (convert_Mtl_to_Vray mat)
)
)
--SELECTEDOBJECTS:
2:
(
if MaterialType == 1 then with redraw off
(
for obj in selection where obj.material != undefined do
obj.material = convert_Mtl_to_Vray obj.material
)
)
What exactly doesn't work as expected? I just tested it very briefly and it seems to work without glitches, althought the code (especially the formatting) could be cleaned up a bit:
(
try (destroyDialog ::Material_Convertor) catch()
fn convert_Mtl_to_vray mtl =
(
if NOT isKindOf mtl Autodesk_Material then mtl
else case (mtl.DefinitionID as name) of
(
#Ceramic : vraymtl name:mtl.name Diffuse:mtl.Ceramic_Color Reflection:(color 200 200 200) reflection_glossiness: 0.85 reflection_subdivs: 16 reflection_fresnel: on reflection_lockIOR:off reflection_ior: 1.8
#Concrete : vraymtl name:mtl.name Diffuse:(color 120 120 120)
#Generic : vraymtl name:mtl.name Diffuse:mtl.Generic_Color
#Glazing : vraymtl name:mtl.name Diffuse:(color 0 0 0) reflection:(color 255 255 255) refraction:(color 255 255 255) reflection_fresnel: on refraction_ior: 1.52 refraction_fogColor: (color 234 252 247) refraction_fogMult: 5 option_traceReflection:on option_doubleSided:on option_reflectOnBack: on
#Hardwood : vraymtl name:mtl.name textmap_diffuse:mtl.wood_image
#MasonryCMU : vraymtl name:mtl.name Diffuse:mtl.Masonry_Color
#Metal : vraymtl name:mtl.name Diffuse:(color 156 156 156)
#MetallicPaint : vraymtl name:mtl.name Diffuse:mtl.Metallic_Paint_Color
#Mirror : vraymtl name:mtl.name Diffuse:mtl.Mirror_Tint_Color reflection:(color 255 255 255) refraction:(color 0 0 0) reflection_fresnel: on refraction_ior: 0.0 option_traceReflection:on option_doubleSided:on option_reflectOnBack: on
#PlasticVinyl : vraymtl name:mtl.name Diffuse:(color 177 177 177)
#Solidglass : vraymtl name:mtl.name Diffuse:(color 0 0 0) reflection:(color 255 255 255) refraction:(color 255 255 255) reflection_fresnel: on refraction_ior:mtl.Solid_Glass_Refraction refraction_fogColor: (color 234 252 247) refraction_fogMult: 5 option_traceReflection:on option_doubleSided:on option_reflectOnBack: on
#Stone : vraymtl name:mtl.name Diffuse:(color 120 120 120)
#WallPaint : vraymtl name:mtl.name Diffuse:mtl.Wall_Paint_Color
#water : vraymtl name:mtl.name Diffuse:(color 1 7 36) reflection:(color 255 255 255) refraction:(color 176 176 176) reflection_fresnel: on refraction_ior: 1.1
)
)
--Interface--
rollout Material_Convertor "--Autodsk Convtr--" width:120 height:170
(
label lbl_Name "Material Converter" pos:[5,2] width:127 height:17
groupBox grp_convert "Convert to:" pos:[3,19] width:113 height:40
radiobuttons ToMaterialType "" pos:[25,33] width:77 height:64 labels:#("Vray") columns:1
groupBox grp_SceneMat "Scene Materials:" pos:[3,60] width:113 height:67
radioButtons ChangeWhat "" pos:[8,75] width:104 height:48 labels:#("Entire Scene", "Selected Objects", "Active Mat. Slot") columns:1
button instanceMat "Instance mats" pos:[3,130] width:113 height:16 toolTip:""
button convertScene "Convert" pos:[3,150] width:113 height:16 toolTip:""
-- toMaterialType enum
local VRAY_MAT = 1
-- changeWhat enum
local ENTIRE_SCENE = 1
local SELECTED_OBJECTS = 2
local ACTIVE_SLOT = 3
on instanceMat pressed do
( --- instance materials with same name
local checkedMats = #()
local checkedMatNames = #()
local counter = 0
for mat in sceneMaterials
where isKindOf mat Material do
(
local checkNum = findItem checkedMatNames mat.name
if checkNum > 0 then
append checkedMats[checkNum] mat
else
(
append checkedMatNames mat.name
append checkedMats #(mat)
)
)
for mats in checkedMats
where mats.count > 1 do
for i = 2 to mats.count do
replaceInstances mats[i] mats[1]
)
on convertScene pressed do
(
case ChangeWhat.state of
(
ENTIRE_SCENE :
(
if sceneMaterials.count == 0 do
return messageBox "There are no materials in your Scene!" title:"Autodsk Converter"
if ToMaterialType.state == VRAY_MAT then with redraw off
for mat in sceneMaterials do
replaceInstances mat (convert_Mtl_to_vray mat)
)
SELECTED_OBJECTS :
(
if ToMaterialType.state == VRAY_MAT then with redraw off
for obj in selection where obj.material != undefined do
obj.material = convert_Mtl_to_Vray obj.material
)
ACTIVE_SLOT :
(
if ToMaterialType.state == VRAY_MAT then
(
local origMtl = meditMaterials[medit.GetActiveMtlSlot()] -- get Active Material Slot
setMeditMaterial (medit.GetActiveMtlSlot()) (convert_Mtl_to_Vray origMtl) -- put the material to the slot
)
)
)
)
)
createDialog Material_Convertor style:#(#style_toolwindow, #style_border, #style_sysmenu)
)
Could you provide a test scene? The case expression can return undefined when it doesn't find a value in any of the branches. It might be something else, as #Concrete is there, eitherway I'd like to check it.
So what exactly doesn't work there? Converting entire scene works for me, individual materials slots too. Any clue on how to reproduce the exception?