Batch Import .stp files into 3ds max 2020

[Roger.Bastow]

Hi, this is my first post and I really hope someone could help. 😃

I need to Batch import about 2000 .stp files into 3DS max 2020. Is there a script that would cover this, or could someone support in writing one?

Kind regards

Roger

[miauuuu]

I don't have .step files to test the code. IF the extensions of your file is .stp you have to modify the code(replace .step with .stp).

The script allows you to select folder where step files are located. You can't select step files separately.

(
	function GetFilesRecursive root pattern =
	(        
		dir_array = GetDirectories (root+"\*")
		for d in dir_array do
			join dir_array (GetDirectories (d+"*"))    
		
		my_files = #()                
		for f in dir_array do
			join my_files (getFiles (f + pattern))
				
		my_files
	)
	
	dir = getSavePath caption:"Select the directory" initialDir:"$scenes"
	if dir != undefined do
	(
		filesArr = #()
		filesArr = getFiles (dir+"\*" + ".step")
		subFiles = GetFilesRecursive dir ("*" + ".step")
		if subFiles.count != 0 then
		(
			msg = "The selected folder has subfolders!\n"
			msg += "Do you want to include the files from the subfolders too?"
			if queryBox  msg title:"Sub-folders found" do
				join filesArr subFiles
		)
		
		if filesArr.count != 0 do
		(
			for f in filesArr do
			(
				importFile f #noPrompt
			)
		)
	)
)

[jetboy_hrn1990]

 Thank you.
I change to  extension to STL. This Script Work STL files. STP cant include.

[miauuuu]

Just tested on max2020 with some STP files downloaded from the internet and the script does work:

(
	function GetFilesRecursive root pattern =
	(        
		dir_array = GetDirectories (root+"\*")
		for d in dir_array do
			join dir_array (GetDirectories (d+"*"))    
		
		my_files = #()                
		for f in dir_array do
			join my_files (getFiles (f + pattern))
				
		my_files
	)
	
	dir = getSavePath caption:"Select the directory" initialDir:"$scenes"
	if dir != undefined do
	(
		filesArr = #()
		filesArr = getFiles (dir+"\*" + ".stp")
		subFiles = GetFilesRecursive dir ("*" + ".stp")
		if subFiles.count != 0 then
		(
			msg = "The selected folder has subfolders!\n"
			msg += "Do you want to include the files from the subfolders too?"
			if queryBox  msg title:"Sub-folders found" do
				join filesArr subFiles
		)
		
		if filesArr.count != 0 do
		(
			for f in filesArr do
			(
				importFile f #noPrompt
			)
		)
	)
)

[denisT.MaxDoctor]

getfiles "c:/temp/*" recurse:on

getfiles has an option #recurse. You don't need a custom method for recursion.

[miauuuu]

I know. 🙂

This was a copy-paste from a very old code.

[denisT.MaxDoctor]

---

@miauuuu wrote:

I know. 🙂

This was a copy-paste from a very old code.

---

be modern ☝️😎

[miauuuu]

OK. 🙂

(	
	dir = getSavePath caption:"Select the directory" initialDir:"$scenes"
	if dir != undefined do
	(
		filesArr = getFiles (dir+"\*" + ".stp")
		files02Arr = getFiles (dir+"\*" + ".stp") recurse:on
		if files02Arr.count > filesArr.count do
		(
			msg = "The selected folder has subfolders!\n"
			msg += "Do you want to include the files from the subfolders too?"
			if queryBox  msg title:"Sub-folders found" do filesArr = files02Arr 
		)
		if filesArr.count != 0 do
		(
			for f in filesArr do importFile f #noPrompt
		)
	)
)

[denisT.MaxDoctor]

(	
	recurse = on
	dir = getSavePath caption:"Select the directory" 
	if dir != undefined do
	(
		path = pathconfig.appendpath dir "*.stp" 
		filesArr = getFiles path recurse:recurse
		for file in filesArr do importFile file #noPrompt
	)
)

initialdir

doesfileexist -- I was wrong!

pathconfig.appendpath

if filearr.count != 0

🙂

[miauuuu]

What if we want to tell the user that there are subfolders with .stp files and to ask if those files has to be included?

[denisT.MaxDoctor]

To the question of how to select files for batch processing - recursively or not. In general, it doesn't matter, but batch processing in any case implies preliminary preparation, and in practice, it makes no sense to give options during the process, but it is enough to set conditions in advance.