Disable clone pop-up in Edit Poly

[office]

Is there a way to temporary disable the clone pop-up (SHIFT+DRAG) in Edit Poly/Editable Poly? I want to clone my meshes for a while and I KNOW that I don't want to detach them completely to separate objects. With so much cloning that I need to do, this pop-up really starts to irritate me.

Thanks in advance!

[Alfred.DeFlaminis]

Hello @office,

Without scripting your own solution, there isn't a default method of disabling this.  If you're simply duplicating an element, maybe you could use an array or PFlow to scatter the objects separately and then attach them all at the end.

I did find this thread where JohnnyRandom wrote an .mcr but it's for an old version, deals with objects and not subobjects, and no longer evaluates correctly.  If you're a maxscripter, you may be able to tweak the code to make it work.  You may also try other script websites and see if a solution exists there. 

Please hit the "Accept as Solution" button if my post fully solves your issue or answers your question. This lets me know that I was effective in helping you, and thank you for doing so.

Best Regards,

[office]

I hoped there was a built-in option somewhere but apparently not. Here's an idea for a new feature.

Thanks for the help anyway. I might take a look at Scriptspot.com or a similar site to check for a script.

[Alfred.DeFlaminis · Accepted solution]

Hello @office,

Sorry it didn't work out for you this time, but you can request a feature here and it will be voted on and possibly implemented in future versions.  The key here to keep your sanity might be doing it on the object level and then attaching.  I think you might check the site you mentioned, it has a good likelihood of having something you could use, and best of luck.

Best Regards,

[office]

Awesome, thanks for the suggestion. 🙂

[Swordslayer]

It would evaluate correctly - but the forum migration screwed a few characters. Anyway, it's a replacement tool to be bound to a shortcut and wouldn't offer dragging the object to a new position, only duplicating it in place.

To answer the orginal question, this will confirm the dialog as soon as it appears:

try destroyDialog ::popupClose catch()
rollout popupClose "Popup Close" width:75
(
	checkButton chbAutoClose "AutoClose" checked:true
	
	global closeDetachPopup = fn closeDetachPopup =
	(
		local hwnd = dialogMonitorOps.getWindowHandle()

		if UIAccessor.getWindowText hwnd == "Clone Part of Mesh" then
		(
			UIAccessor.PressDefaultButton() 
			true
		)
		else false
	)

	fn enableClosing =
	(
		dialogMonitorOps.enabled = true
		dialogMonitorOps.interactive = false
		dialogMonitorOps.registerNotification ::closeDetachPopup id:#close_detach_popup
	)

	fn disableClosing =
	(
		dialogMonitorOps.unRegisterNotification id:#close_detach_popup
		dialogMonitorOps.enabled = false
	)

	on chbAutoClose changed checked do
		if checked then enableClosing() else disableClosing()

	on popupClose open do enableClosing()

	on popupClose close do disableClosing()
)
createDialog popupClose

Bear in mind, that dialogMonitor prevents user interaction with ANY popup dialog, so if you want to open some settings dialog, material editor etc., uncheck the AutoClose button and check it only while you're detaching.

[Alfred.DeFlaminis]

@Swordslayer, you have gone above and beyond here.  Thank you for posting this, this is really great.  Have a great day and thanks again.

Best Regards,