Assign Display Vertex Colors to Hotkey

[bsaliga]

Is there a way to assign the Vertex Colors check box under the display properties panel to a hotkey. I want to toggle the box on and off with a hotkey, or at least drag it into a custom toolbar and then assign that button to a hotkey. Oddly enough the "Vertex Ticks" toggle above that one is found in the Customize User interface window, but not "vertex colors"....  (See image attached).

**I'm using 3ds Max 2024**

[dmitriy.shpilevoy · Accepted solution]

(
	obj = selection[1]
	if obj != undefined and classof obj == Editable_Poly do (
		if polyop.getMapSupport obj 0 do (
			obj.vertexColorType = #color
			if obj.showVertexColors then (
				obj.showVertexColors = off
			) else (
				obj.showVertexColors = on
			)
		)
	)
)

[bsaliga]

Thanks this works. Had to have the material on the mesh for it to work.

[bsaliga]

Is there any way to get it to work with multiple selected objects and also in editable mesh mode?

[dmitriy.shpilevoy · Accepted solution]

Strange. I tested it on teapot with no material.

(
	function isValidObject obj = (
		valid = false
		case classOf(obj) of (
			Editable_Poly: (
				if polyop.getMapSupport obj 0 do (
					valid = true
				)
			)
			Editable_mesh: (
				if meshop.getMapSupport obj 0 do (
					valid = true
				)
			)
		)
		valid
	)
	
	for i in selection do (
		obj = i
		if isValidObject obj then (
			obj.vertexColorType = #color
			if obj.showVertexColors then (
				obj.showVertexColors = off
			) else (
				obj.showVertexColors = on
			)
		)
	)
)

[bsaliga]

Thank you! Can confirm this now works in Editable Mesh/Poly and with multiple objects selected. I appreciate it!