Tool -Layer name check for number of characters and structure of layer name

[nilesh33]

Hi Friends,

I would like to develop utility/tool/cad standard checker which will do following.

1. It will check and report if layer name contains more than 11 digits/letters/characters
2. It will check and report if layer contains characters as per predefined list or not.
Example first two characters in layer name should be from this list (T-, V-, R-, K-, ...etc)

What would be an easiest and efficient way to develop this?

Thanks,
Nilesh

[Moshe-A]

@nilesh33 hi,

the easiest way to to write a command to do these checking and run it from appload (or acad.lsp)

but in mid session it would be left unchecked (until next open).

a complemetry moudle to it, is using activex reactors to online check each change in layers

post some code if you already have?!

moshe

[DannyNL]

Some quick 'n dirty example code.

Running (Test) will return all layer names which do not start with one of the prefixes in the list or with a length larger than 11.

(defun Test (/ T_LayerPrefixList T_LayerNameMaxLength T_LayerCollection T_LayerName T_Return)
   (setq T_LayerPrefixList '("K-" "R-" "T-" "V-"))
   (setq T_LayerNameMaxLength 11)
   (setq T_LayerCollection (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))))
   (vlax-for T_Layer T_LayerCollection
      (if
         (and
            (/= (setq T_LayerName (vla-get-Name T_Layer)) "0")
            (or
               (not (vl-some '(lambda (T_Item) (wcmatch T_LayerName (strcat T_Item "*"))) T_LayerPrefixList))
               (> (strlen T_LayerName) T_LayerNameMaxLength)
            )
         )
         (setq T_Return (cons T_LayerName T_Return))         
      )            
   )
   (vlax-release-object T_LayerCollection)
   T_Return
)

[ronjonp]

@DannyNL

FWIW..

;;This
(not (vl-some '(lambda (t_item) (wcmatch t_layername (strcat t_item "*"))) t_layerprefixlist))
;; Could be shortened to this
(not (wcmatch t_layername "K-*,R-*,T-*,V-*"))

[Moshe-A]

yes @DannyNL,

it's true and works but it is also could be accomplish more simple way - NO?

(defun Test (/ T_LayerPrefixList T_LayerNameMaxLength T_LayerCollection T_LayerName T_Return)
   (SETQ T_Layer "[KRTV]-*")
   (setq T_LayerNameMaxLength 11)
   (setq T_LayerCollection (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))))
   (vlax-for T_Layer T_LayerCollection
      (if
         (and
            (/= (setq T_LayerName (vla-get-Name T_Layer)) "0")
            (or
               (not (wcmatch T_LayerName T_LayerPrefixList))
               (> (strlen T_LayerName) T_LayerNameMaxLength)
            )
         )
         (setq T_Return (cons T_LayerName T_Return))         
      )            
   )
   (vlax-release-object T_LayerCollection)
   T_Return
)

[Kent1Cooper]

Investigate the STANDARDS command.

[ronjonp]

Even simpler than mine 🙂

(SETQ T_Layer "[KRTV]-*")

[DannyNL]

And @Moshe-A.

Both correct......I sometimes forget that wcmatch supports bracketing