The total number of DWG files in the title block
@bigcarl5000kgAttach sample drawing with title block. Change of attribute value can be done on all drawings in single folder (or even its subfolders) without separately opening single file.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@bigcarl5000kg wrote:
Total amount of sheets: 13 -> write this value in 13 separate DWGs / each corner stamp block / each specified attribute
Are you saying the string value would include this string "Total amount of sheets:" + the total?
@bigcarl5000kg wrote:
total amount of DWG files only, it is in my case also total amount of "sheets" as information in each drawing,
- This program will modify ONLY files on the selected folder. [ un-opened ]
- The "total" will be based on the number of .dwg files on the selected folder [ we can add a filter just in case there are rogue files on the selected folder.
- The file should have a attribute block named "PAGEHEADER" with a TAG name "TOTAL"
(defun c:TNoS ( / allfiles odbs v adoc odbx AllDrawingFiles Total#Dwg Total_TAG); Total Number of Sheets
(setq odbs "ObjectDBX.AxDbDocument"
v (substr (getvar 'acadver) 1 2)
adoc (vla-get-activedocument (setq app (vlax-get-acad-object)))
)
(setq f (acet-ui-pickdir "Select project Folder" (if f f (getvar 'dwgprefix))))
(setq AllDrawingFiles (vl-directory-files f "*.dwg"))
(setq Total#Dwg (length AllDrawingFiles))
(cond
((vl-catch-all-error-p
(setq odbx (vl-catch-all-apply
'vla-getinterfaceobject
(list app
(if (< (atoi v) 16)
odbs
(strcat odbs "." v)
)
)
)
)
)
(princ "\nObject DBX interface not created!")
)
( AllDrawingFiles
(foreach dwg AllDrawingFiles
(if (vl-catch-all-error-p
(vl-catch-all-apply 'vla-open (list odbx (Strcat f "\\" dwg)))
)
(princ (strcase (strcat "\nError opening: " dwg)))
(progn
(princ (strcat "\nOpening: " dwg))
(vlax-for item (vla-get-layouts odbx)
(if (/= (vla-get-name item) "Model")
(Vlax-for obj (vla-get-block item)
(if (and
(eq (vla-get-objectname obj) "AcDbBlockReference" )
(eq (Strcase (vla-get-EffectiveName obj)) "PAGEHEADER")
(setq Total_TAG (vl-some '(lambda (At)
(if (eq (vla-get-tagstring at) "TOTAL") at))
(Vlax-invoke obj 'GetAttributes)))
)
(vla-put-textstring Total_TAG (itoa Total#Dwg))
)
)
)
)
(and Total_TAG (vla-saveas odbx (Vla-get-name odbx)))
)
)
)
)
)
(princ)
)
Command: Tnos
If the file is read-only. the message
"Error opening: < Filename >" on the command prompt
To make this work on files currently open will require additional coding.
HTH
@bigcarl5000kg wrote:
I have one problem - once a value is defined, it cannot be overwritten by additional invocation of the same command (eg after changing the number of data in the directory).
Not sure what you mean by that, the values will update as soon as you run the program again. Unless the files is currently opened by you or other users. Then that file will not be updated but the others will be.
We can modify the code to deal with that condtion or at least part of it. and also to work on the current dwg session.
Are you using Sheet Set by any chance? If not then you should, that would be the best way to keep track of the number of dwg details on a folder and use FIELDS to populate the attribute.
Let us know if you need help putting that together.
@bigcarl5000kg Here you have another one.
(defun c:append_total_files_in_titleblock ( / find_all_file_paths getDBXDoc oVer include_subfolders dwg_files doc total)
(defun find_all_file_paths (file_extension include_subfolders / subFolderTree acad shell hwnd folder basefolder basefolderpath fso folder_list pathlist) ;
;file_extension ".dwg" ".jpg"
(defun subFolderTree (root_folder / subfolder)
(setq subfolder (vlax-get root_folder 'Subfolders))
(vlax-for sub subfolder
(setq folder_list (cons (vlax-get sub 'Path) folder_list))
(subFolderTree sub)
)
folder_list
)
(setq
acad (vlax-get-acad-object)
shell (vla-getinterfaceobject acad "Shell.Application")
fso (vlax-create-object "Scripting.FileSystemObject")
hwnd (vl-catch-all-apply 'vla-get-hwnd (list acad))
folder (vlax-invoke-method shell 'browseforfolder
(if (vl-catch-all-error-p hwnd) 0 hwnd) "Select folder:" 0 "")
)
(cond
((and folder)
(setq basefolderpath (vlax-get-property (vlax-get-property folder 'Self) 'Path))
(cond
((> (strlen basefolderpath ) 3)
(setq folder_list nil)
(cond
((and include_subfolders)
(setq folder_list (append (list basefolderpath) (reverse (subFolderTree (vlax-invoke-method fso 'GetFolder basefolderpath)))))
)
(T (setq folder_list (list basefolderpath)))
)
(foreach item folder_list
(vlax-for file (vlax-get (vlax-invoke-method fso 'GetFolder item) 'Files)
(cond
((wcmatch (strcase (vlax-get file 'Name) T) (strcat "*" file_extension))
(setq pathlist (cons (strcat "" item "\\" (vlax-get file 'Name)) pathlist))
)
)
)
)
)
(T (alert (strcat "You can not search whole partition " basefolderpath)))
)
)
)
(vlax-release-object shell)
(vlax-release-object fso)
(cond
((not pathlist) (setq folder_list nil))
((and pathlist)
(setq folder_list nil)
(reverse pathlist)
)
)
)
(defun getDBXDoc (dwg / app dbx oVer)
(setq dbx
(if (< (atoi (setq oVer (substr (getvar "acadver") 1 2))) 16)
(vla-GetInterfaceObject (vlax-get-acad-object) "ObjectDBX.AxDbDocument")
(vla-GetInterfaceObject (vlax-get-acad-object) (strcat "ObjectDBX.AxDbDocument." oVer))
)
)
(cond
((and dbx) (vla-open dbx dwg)
dbx
)
)
)
(initget 1 "Yes No")
(setq include_subfolders (strcase(getkword "Include files in subfolders? (Yes or No) ")))
(cond
((= include_subfolders "YES")
(setq dwg_files (find_all_file_paths ".dwg" T))
)
((= include_subfolders "NO")
(setq dwg_files (find_all_file_paths ".dwg" nil))
)
)
(cond
((and dwg_files)
(foreach dwgfile dwg_files
(cond
((and(setq doc (getDBXDoc dwgfile)))
(vlax-for item (vla-get-layouts doc)
(if (/= (vla-get-name item) "Model")
(vlax-for obj (vla-get-block item)
(if (and
(eq (vla-get-objectname obj) "AcDbBlockReference" )
(eq (Strcase (vla-get-EffectiveName obj)) "PageHeader")
(setq total(vl-some '(lambda (At)
(if (eq (vla-get-tagstring at) "TOTAL") at))
(Vlax-invoke obj 'GetAttributes)))
)
(vla-put-textstring total (itoa (length dwg_files)))
)
)
)
)
(and total (vla-saveas doc dwgfile))
)
)
(vlax-release-object doc )
)
)
)
(princ "\nDone!")
(princ)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Probably it can be done, but it's not easy.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@bigcarl5000kg wrote:
General question - it is possible to implement another version of the folder browser in LISP, eg similar to Windows explorer - it does not have to be exactly the same, it has the advantage of faster selection of the required directory (user favorites, entering the path to the server, ...)
One step closer is you can paste a path on the dialog
(defun _getfolder ( m / sh f r)
(setq sh (vla-getinterfaceobject
(vlax-get-acad-object) "Shell.Application" )
f (vlax-invoke-method sh 'browseforfolder 0 m 16)
)
(vlax-release-object sh)
(if f (vlax-get-property (vlax-get-property f 'self) 'path)
)
)(setq f (_GETFOLDER "Select folder to process"))
HTH
it is possible to implement another version of the folder browser This is actually easier to accomplish in .NET, wherein you can even drag files to your list from windows explorer
