The result of entlast function is not complete

[326047736]

Hello everyone.

I created a boundary that has two polylines by the AutoLISP command function. And then trying to use entlast function to get all the polylines of this boundary, but can only get one. What should I do next?

Any reply might be helpful, thanks!

[hak_vz · Accepted solution]

---

@326047736 wrote:

Hello everyone.

I created a boundary that has two polylines by the AutoLISP command function. And then trying to use entlast function to get all the polylines of this boundary, but can only get one. What should I do next?

---

Function ENTLAST will select only last created entity. Check function SSGET.

[ВeekeeCZ · Accepted solution]

Save the last entity BEFORE you apply your function.

Then get all (entnext) until you reach the end of the database.

[326047736]

Thanks, @hak_vz, so the code below might be work in some cases:

(defun c:test (/ boundaryPnt layername oldlayer flag ss)
  (setq layername "templayer")
  (setq oldlayer (getvar "CLAYER")) ; Save origin layer name
  (setq flag (tblsearch "LAYER" layername)) ; Looking for existing
  (if (null flag) (progn (command "_.-layer" "m" layername ""))) ; Creat new layer if not exist
  (setvar "CLAYER" layername) ; Change current layer to <layername>
  (setq boundaryPnt (getpoint "\nGet point"))
  (command "_.-boundary" "A" "O" "P" "" boundaryPnt "")
  (setq ss (ssget "_X" (list (cons 8 layername))))
  (command "_.move" ss)
  ;; Other code

  (setvar "CLAYER" oldlayer) ; Change back to the origin layer to layername
  ;; (command "_.-laydel" "_N" layername "" "_Y") ; Delete temp layer and all the objects in the layer(if you want)
)

Ref: 

creating-layer-and-styles-with-autolisp

ssget 

[326047736]

Thanks, @ВeekeeCZ, this is a clearer idea and be easier to code:

(defun c:test (/ ss lastBefore)
  (setq lastBefore (entlast) ss (ssadd))
  (setq boundaryPnt (getpoint "\nGet point"))
  (command "_.-boundary" "A" "O" "P" "" boundaryPnt "")
  (while (setq lastBefore (entnext lastBefore)) 
    (setq ss (ssadd lastBefore ss))
  )
  ;; Other code
  (command "_.move" ss)
)

[hak_vz]

@326047736  Yes it will work. Try to come up with your code, I'll look later today to help you finish it. Currently at work so have no time.

[326047736]

You might have found some issues with the origin code too. So I updated the code and it works for me now. But it would be better to add some error handling code.

Thanks again for taking the time to answer the question. 👋