Set all entities "Transparency" and "Material" inside blocks to "ByBlock"
@dlanorh wrote:
I don't think it's possible to change entity transparency, only layer transparency. If you open a block in the block editor, select an entity right click and select properties you will find the transparency is not changeable, unless it is a hatch.
Are all the objects within the blocks on layer "0" (zero)? If they are, this allows the block to take on the transparency of the layer it is inserted on.
Yes, all entities inside blocks are always on layer "0".
Please, see the gif bellow to check what I mean:
As you can see in the example above, if I go to the block editor I can change Transparency and Material properties of all entities by using the "CHPROP" command. But imagine when you have to do that for 500 blocks for example.
Thanks.
; (NestedPutProp "MyBlk" 'entitytransparency "BYBLOCK")
; (NestedPutProp "MyBlk" 'color 3)
(defun NestedPutProp (nme prop val / blk)
(if
(and
(not
(vl-catch-all-error-p
(setq blk
(vl-catch-all-apply
'vla-item
(list
(vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
nme
)
)
)
)
)
(= :vlax-false (vla-get-islayout blk))
(= :vlax-false (vla-get-isxref blk))
)
(vlax-for obj blk (vlax-put obj prop val))
)
)
(defun KGA_Conv_Pickset_To_ObjectList (ss / i ret)
(if ss
(repeat (setq i (sslength ss))
(setq ret (cons (vlax-ename->vla-object (ssname ss (setq i (1- i)))) ret))
)
)
)
(defun C:TRBB ( / doc doneLst ss)
(setq doc (vla-get-activedocument (vlax-get-acad-object)))
(vla-endundomark doc)
(vla-startundomark doc)
(if (setq ss (ssget '((0 . "INSERT"))))
(foreach obj (KGA_Conv_Pickset_To_ObjectList ss)
(if (not (vl-position (strcase (vla-get-name obj)) doneLst))
(progn
(NestedPutProp (vla-get-name obj) 'entitytransparency "BYBLOCK")
(setq doneLst (cons (strcase (vla-get-name obj)) doneLst))
)
)
)
)
(vla-regen doc acactiveviewport)
(vla-endundomark doc)
(princ)
)
I've found this routine on Internet and I don't know if it can help you too. From what I've read, this LISP works by selecting blocks one by one, changing "Transparency" to "ByBlock" of all entities of a selected block. I would like something similar to this, but that puts "Material" properties to "ByBlock" aswell and that applies for ALL blocks of the drawing, without needing to select one by one.
Yet, the above LISP only works for normall blocks and it does not work for Dynamic Blocks. 
Hope it helps!
Accepted solution
@Anonymous wrote:
.... LISP .... to change all entities "Transparency" and "Material" properties inside ALL blocks to "ByBlock....
You don't want something that is insertion-based [the various offerings above look for INSERT objects, i.e. Block references ], because that will unnecessarily run those property assignments on nested entities more than once for any Block that's Inserted more than once. You want one that steps through the Block table, and for each definition there [that isn't an Xref or a Dimension, which also show up there], gives those properties to all the pieces it's made of. Try this:
(defun C:BETMBB ; = Block Entities Transparency & Material to ByBlock
(/ blkdata ent obj)
(while (setq blkdata (tblnext "block" (not blkdata))); still any Block definitions left?
(if
(and
(not (assoc 1 blkdata)); not an Xref [no path]
(not (wcmatch (cdr (assoc 2 blkdata)) "`*D*")); not a Dimension
); and
(progn ; then -- process it
(setq ent (tblobjname "block" (cdr (assoc 2 blkdata)))); Block definition as entity
(while (setq ent (entnext ent)); still something left in definition?
(setq obj (vlax-ename->vla-object ent))
(vla-put-EntityTransparency obj "ByBlock")
(vla-put-Material obj "ByBlock")
); while
); progn
); if
); while
(princ)
); defun
Kent Cooper, AIA 
@Kent1Cooper wrote:
@Anonymous wrote:
.... LISP .... to change all entities "Transparency" and "Material" properties inside ALL blocks to "ByBlock....
You don't want something that is insertion-based [the various offerings above look for INSERT objects, i.e. Block references ], because that will unnecessarily run those property assignments on nested entities more than once for any Block that's Inserted more than once. You want one that steps through the Block table, and for each definition there [that isn't an Xref or a Dimension, which also show up there], gives those properties to all the pieces it's made of. Try this:
(defun C:BETMBB ; = Block Entities Transparency & Material to ByBlock (/ blkdata ent obj) (while (setq blkdata (tblnext "block" (not blkdata))); still any Block definitions left? (if (and (not (assoc 1 blkdata)); not an Xref [no path] (not (wcmatch (cdr (assoc 2 blkdata)) "`*D*")); not a Dimension ); and (progn ; then -- process it (setq ent (tblobjname "block" (cdr (assoc 2 blkdata)))); Block definition as entity (while (setq ent (entnext ent)); still something left in definition? (setq obj (vlax-ename->vla-object ent)) (vla-put-EntityTransparency obj "ByBlock") (vla-put-Material obj "ByBlock") ); while ); progn ); if ); while (princ) ); defun
DAM! That was exactly what I was looking for, sir. I've forgot to mention that mostly of the blocks wouldn't be inserted in drawing, only having their "block definition" inside it. PERFECT! It works for all dynamic blocks aswell. Can't thank you enough for this awesome solution. Kudos! 
@dlanorh wrote:
OK, changing the material & transparency properties of all items in all block definitions (block table) doesn't affect the block references in the drawing(the blocks themselves are still bylayer for both). These need to be changed seperately. So my question is do you want this applying to all block references, a selection of references or something else?
It doesn't apply to Block references, but to Block definitions. Yes, each reference would have its own assignment of such properties separately, which can be different from those of other references of the same Block -- that's the whole point of assigning "ByBlock " for those properties to the pieces inside the Block definitions. What they would apply to Block references [whether all or a selection of them] would not be "this," but would be particular transparency and material values.
Kent Cooper, AIA
@dlanorh wrote:
.... If you redefine the Block Definitions, inserting a redefined block into the drawing still sets the reference blocks transparency and material properties to "ByLayer"....
That's true only when "ByLayer" is the current setting of the CETRANSPARENCY and/or CMATERIAL System Variables. Those are no different from other entity properties, e.g. by initial default everything you draw will have a Color property of "ByLayer" as long as that's the setting of the CECOLOR System Variable, but you can change that, and you can similarly change the Transparency and/or Material that newly-drawn objects will get.
Kent Cooper, AIA