Selection set by rotation angle
Bonjour @dlbsurveysuk
It is possible to click the text whose angle of rotation we want to know,
then to make a selection set of the other texts, then to make a loop on the first selection set by comparing the rotations,
if it is equal to the example, we can add it to the second selection set.
The selection ss2 contains all texts entities who have the same rotation angle than the example text entity.
(setq text_example (car (entsel "\nSelect the text example\n")))
(prompt "\nSelection of other texts\n")
(setq ss1 (ssget '((0 . "text"))))
(setq ss2 (ssadd))
(setq rotexample (cdr (assoc 50 (entget text_example))))
(repeat (setq x (sslength ss1))
(if (= rotexample (cdr (assoc 50 (entget (ssname ss1 (setq x (1- x)))))))
(ssadd (ssname ss1 x) ss2)
)
)
(sssetfirst nil ss2) Amicalement
This is the kind of thing that can [depending on how the angle was determined] come out with tiny differences in value [perhaps ten or twelve decimal places down] that may foil the (=) function that looks for exact equality, or similarly inclusion of the (50 . SourceObjectRotation) entry in an (ssget) filter. I would suggest testing in a matter such as this, with a fuzz factor:
(if (equal SourceObjectRotation TestObjectRotation 1e-4)
... put it in the restricted selection set, or whatever ...
)
works perfectly for me...see attached dwg with rotated text & blocks
also here is a screen capture of the command sequence and the rotated texts & blocks afterwards
I checked again on your dwg and could only find 1 thing take a bit of care picking 1st text angle.
@john.uhden wrote:
....
Kent (et al): I'm not sure if I have ever tried to include a fuzz factor in a selection set filter with a 'REAL variable. Can you show us how (if it can be done)?
You can use >relational testing< in a selection set filter. This will find/select/grip/highlight all objects that have a rotation in a DXF-50 entry that is within less than 1° of 180°:
(sssetfirst nil
(ssget "_X"
(list
'(-4 . ">") (cons 50 (- pi (/ pi 180)))
'(-4 . "<") (cons 50 (+ pi (/ pi 180)))
)
)
)
The (/ pi 180) is 1° in radians. It's filtering for everything with a rotation that is more than 179° but less than 181°.
Replace pi with your targe rotation angle [in radians, but that's what you'll get if you pull it from a selected object], and (/ pi 180) with your fuzz factor. Add other entries to the filter list for object type, Layer if you want, eliminate the "_X" if you want only from among a User selection, probably skip the (sssetfirst) for your purposes, etc.
(ssget
(list
'(-4 . "<OR")
'(-4 . "<AND") '(0 . "TEXT") (cons 50 rot) '(-4 . "AND>")
'(-4 . "<AND") '(0 . "INSERT") (cons 50 rot) '(-4 . "AND>")
'(-4 . "OR>")
) ; list
) ; ssget
That much doesn't need to have two separate logical groupings of entity type with rotation, given that the rotation is the same for both. You can get more than one entity type in (wcmatch)-style string format with comma-separated types. It could be just:
(ssget (list '(0 . "TEXT,INSERT") (cons 50 rot)))
If that misses some and you need a fuzz factor, here assuming 0.01 radians [about 0.57°] is an appropriate value:
(ssget
(list
'(0 . "TEXT,INSERT")
'(-4 . ">") (cons 50 (- rot 0.01))
'(-4 . "<") (cons 50 (+ rot 0.01))
)
)
Tighten that 0.01 down to something smaller for a closer-to-exact rotational match.
