Selection filter for 2dPolyline

[Browning_Zed]

Hi All,
When using the entsel / nentselp function, I need to check if the picked object is "LWPOLYLINE" or "2DPOLYLINE". To check the LWPolyLine, I use the following expression:

(= (cdr (assoc 0 (entget (car (entsel "\nPick: "))))) "LWPOLYLINE")

how to make a check for 2DPolyLine besides this (not 3DPolyline)?

[pbejse]

---

@Browning_Zed wrote:

Hi All,
When using the entsel / nentselp function, I need to check if the picked object is "LWPOLYLINE" or

---

In terms of using entsel/nentsel/nentselp its basically the same as you already have

its just good habit to evaluate the values first

(while
  (setq e   (car (entsel "\nPick: ")))
	  (princ (Strcat "\nSelected Object is "
		  (cond
		    ((eq (setq etype (cdr (assoc 0 (setq ent (entget e))))) "LWPOLYLINE")
			" 2DPolyLine" 	)
		    ((eq etype	"POLYLINE") "3DPolyLine"
				     	)
		    ( "Something else other than a Polyline")))
		 )
  )

HTH

[Browning_Zed]

Please, tell me, how to use the condition in this code:

(while
    (progn
        (setvar 'errno 0)
        (setq sel (nentselp "\nSelect LWPoly or 2DPoly <Exit>: "))
        (cond
            (   (= 7 (getvar 'errno))
                (princ "\nMissed, try again.")
            )
            (   (= 'ename (type (car sel)))
                (if
                    (not
                        <<!!! OBJECT IS LWPOLY OR 2DPOLY !!!>>
                    )
                    (princ "\nInvalid object selected.")
                )
            )
        )
    )
)

[pbejse]

---

@Browning_Zed wrote:

Please, tell me, how to use the condition in this code:

---

Remember the loop will continue to prompt the user to select except the time the user press enter.

(defun c:demo ()
(while
    (progn
        (setvar 'errno 0)
        (setq sel (nentselp "\nSelect LWPoly or 2DPoly <Exit>: "))
        (cond
            (   (= 7 (getvar 'errno))
                (princ "\nMissed, try again.")
            )
            (   (= 'ename (type (car sel)))
	     	(if (/= (cdr (assoc 0 (entget (car sel)))) "LWPOLYLINE")
		  	(princ "\nInvalid Object Selected.")
                        (princ "\n <<!!! OBJECT IS LWPOLY OR 2DPOLY !!!>> | Do something or press enter to exit the loop")
		  	
                    )
	        )
            )
        )
    )
(princ)
)

[Browning_Zed]

You do not understand me. I also need to check 2D polylines besides LW polylines.
This place in the code is marked like this: << HERE MUST BE CHECKED 2DPOLYLINE IS TRUE >>

(while
    (progn
        (setvar 'errno 0)
        (setq sel (nentselp "\nSelect LWPoly or 2DPoly <Exit>: "))
        (cond
            (   (= 7 (getvar 'errno))
                (princ "\nMissed, try again.")
            )
            (   (= 'ename (type (car sel)))
                (if
                    (not
                        (or (= (cdr (assoc 0 (entget (car sel)))) "LWPOLYLINE") ; LWPOLY IS TRUE
							<< HERE MUST BE CHECKED 2DPOLYLINE IS TRUE >>
						)
                    )
                    (princ "\nInvalid object selected.")
                )
            )
        )
    )
)

[hak_vz · Accepted solution]

(and
	(setq e (car (entsel "\nPick: ")))
	(setq eo (vlax-ename->vla-object e))
	(or
		(= (vlax-get eo 'Objectname)   "AcDbPolyline")
		(= (vlax-get eo 'Objectname)   "AcDb2dPolyline") 		
	)
)

[pbejse]

---

@Browning_Zed wrote:

You do not understand me. I also need to check 2D polylines besides LW polylines.
This place in the code is marked like this: << HERE MUST BE CHECKED 2DPOLYLINE IS TRUE >>

---

Did you even try to understand the snippet i posted?

What is your idea of 2DPOLYLINE anyway? "LWPOLYLINE" is 2Dpolyline or "AcDbPolyline"

While POLYLINE is "AcDb3dPolyline" or "3D Polyline"

[Browning_Zed]

When polylines are picked, your code returns results:

LW polyline: T
2D polyline: T
3D polyline: T

I need:
LW polyline: T
2D polyline: T
3D polyline: nil

Only LW polyline or 2D polyline should be selected.

[CADaSchtroumpf]

By filtering?

(sssetfirst nil (ssget '((0 . "*POLYLINE") (-4 . "<NOT") (-4 . "&") (70 . 120) (-4 . "NOT>"))))

[Browning_Zed]

LW polyline = "AcDbPolyline"
2D polyline = "AcDb2dPolyline"
3D polyline = "AcDb3dPolyline"

[pbejse]

---

@Browning_Zed wrote:

When polylines are picked, your code returns results:

LW polyline: T
2D polyline: T
3D polyline: T

Only LW polyline or 2D polyline should be selected.

---

Maybe i'm missing something, can you post an example with those 3 diffrent types if polyline so we can be on the same page?

[hak_vz]

---

@Browning_Zed wrote:

When polylines are picked, your code returns results:

LW polyline: T
2D polyline: T
3D polyline: T

I need:
LW polyline: T
2D polyline: T
3D polyline: nil

Only LW polyline or 2D polyline should be selected.

---

I' ve changed code above

[pbejse]

---

@hak_vz wrote:

....
		(= (vlax-get eo 'Objectname)   "AcDb2dPolyline") 		
...

---

What?!!!?? there is an actual "AcDb2dPolyline"? 😮 silly me.

All these years and I did not know that?  Maybe i have not came across one before 🤔

[hak_vz]

@pbejseYes, in dxf definition for POLYLINE entity is stands

100  Subclass marker (AcDb2dPolyline or AcDb3dPolyline)

[Kent1Cooper]

---

@pbejse wrote:
....What?!!!?? there is an actual "AcDb2dPolyline"? 😮 silly me.

All these years and I did not know that?  Maybe i have not came across one before 🤔

---

Read about the PLINETYPE System Variable.  In addition to that determining whether new [non-3D] Polylines are "lightweight" [which are called "optimized" there] or "heavy," any time you use the Fit or Spline option in the PEDIT command on a LWPolyline, the result is a "heavy" 2D Polyline.

The confusion is understandable.  The entity type in entity data for both "heavy" 2D and 3D Polylines is (0 . "POLYLINE"), compared to (0 . "LWPOLYLINE") for "LightWeight" ones.  But in the Properties palette, a selected "lightweight" one is listed as just a "Polyline."  The other types have the "2D" or "3D" prefixes there.

[pbejse · Accepted solution]

FWIW

(defun c:demo ()
(while
    (progn
        (setvar 'errno 0)
        (setq sel (entsel "\nSelect LWPoly or 2DPoly : "))
        (cond
            (   (= 7 (getvar 'errno))
                (princ "\nMissed, try again.")
            )
            (   (= 'ename (type (car sel)))
	     	(if ( not (member (vlax-get (setq ev (vlax-ename->vla-object (car sel))) 'Objectname) '("AcDb2dPolyline" "AcDbPolyline" "AcDb2dVertex")))
		  	(princ "\nInvalid Object Selected.")
                        (princ "\n <<!!! OBJECT IS LWPOLY OR 2DPOLY !!!>> | Do something or press enter to exit the loop")
		  	
                    )
	        )
            )
        )
  )
(princ)
)

[Browning_Zed]

Thanks to hak_vz for solving the problem. Thanks pbejse too 🙂

As it was already noted, the confusion arises because of the same dxf codes for 2D and 3D polylines (0. "POLYLINE"), despite the fact that they are different objects.

I have attached a file where there are all three types of polylines: LW, 2D and 3D, if someone else needs it.

[Sea-Haven]

red (0 . "POLYLINE") (100 . "AcDb2dPolyline")
green (0 . "POLYLINE")(100 . "AcDb3dPolyline")
white (0 . "POLYLINE")(100 . "AcDbPolyline")

[hak_vz]

---

@Sea-Haven wrote:

red (0 . "POLYLINE") (100 . "AcDb2dPolyline")
green (0 . "POLYLINE")(100 . "AcDb3dPolyline")
white (0 . "POLYLINE")(100 . "AcDbPolyline")

---

We have for polylines something like

(0 . "LWPOLYLINE")
(100 . "AcDbEntity") 
(100 . "AcDbPolyline") 

This double key 100 may causes that not all entities are selected. Also for lwpolyline key 0 is not POLYLINE