Round up numbers

[andreas7ZYXQ]

Is it possible to round up numbers like..

2.1 = 3
2.5 = 3

I can only use normal math rules now. But im searching for a other way. Any ideas?


Thanks

[ВeekeeCZ]

Most simple is
(rtos (+ 2. 0.49) 2 0)
But if you actually DO a search, you'll find plenty of solutions.

[_gile · Accepted solution]

Hi,

Here's a way:

;; round up
(defun ceil (x / n)
  (if (or (= (setq n (fix x)) x) (< x 0))
    n
    (1+ n)
  )
)

;; round down
(defun floor (x / n)
  (if (or (= (setq n (fix x)) x) (< 0 x))
    n
    (1- n)
  )
)

[andreas7ZYXQ]

Thanks!

Great solution

[john.uhden]

0.49??  Is your inflation driving down the value of numbers?

Um, how about (fix (+ n 0.5))?

I've got something back home that can round to any precision, but I forget the code.

It might help if we had a reverse exponent function, as in (expt 10 n) = 100 and solve for n.

Maybe...

(defun revexpt (val n / exp)
  (setq exp 1)
  (while (/= val n)
    (setq exp (1+ exp))
    (setq val (/ val (expt n exp)))
  )
  (1+ exp)
)

No good... "divide by zero" sometimes

[_gile]

;; round
(defun round (x)
  (fix ((if (minusp x) - +) x 0.5))
)

;; round to
(defun roundTo (num prec)
  (if (zerop (setq prec (abs prec)))
    num
    (* prec
       (fix ((if (minusp num)
               -
               +
             )
              (/ num prec)
              0.5
            )
       )
    )
  )
)

;; round up
(defun ceil (x / n)
  (if (or (= (setq n (fix x)) x) (< x 0))
    n
    (1+ n)
  )
)

;; round down
(defun floor (x / n)
  (if (or (= (setq n (fix x)) x) (< 0 x))
    n
    (1- n)
  )
)

_$ (roundTo 0.49 0.1)
0.5
_$ (round 0.49)
0
_$ (roundTo 0.49 0.1)
0.5
_$ (ceil 0.49)
1
_$ (floor 0.49)
0

_$ (round pi)
3
_$ (roundTo pi 0.01)
3.14
_$ (ceil pi)
4
_$ (floor pi)
3

[john.uhden]

minusp...  EXCELLENT!

[ВeekeeCZ]

---

@john.uhden wrote:

0.49??  Is your inflation driving down the value of numbers?

...

---

I've meant (rtos (+ x 0.49) 2 0) for round up. Still most simple I think. 

But sure, it converts a result into string, so @_gile's suggestions are proper solutions.

[Kent1Cooper]

---

@ВeekeeCZ wrote:

I've meant (rtos (+ x 0.49) 2 0) for round up. Still most simple I think. 

But sure, it converts a result into string, so @_gile's suggestions are proper solutions.

---

That depends on the precision of your number argument.  It wouldn't  round 6.009 up to 7.

But if the numbers are of no more than two decimal places and that's precise enough, you could, of course, wrap the whole thing in (atoi) to return an integer.

[john.uhden]

Somewhere in my education I was taught to round even numbers down and odd numbers up.

2.5 => 2

3.5 => 4

I guess that would involve something like

(if (> (rem n 2) 1) => odd

[_gile]

---

john.uhden a écrit :

Somewhere in my education I was taught to round even numbers down and odd numbers up.

2.5 => 2

3.5 => 4

---

It is just one convention among others.