Replace Polyine Geometry With Another Polylines Geometry - Lisp?
How involved is the "geometry" of the Polylines in question? If they're geometrically rather simple Polylines, that is, without width(s) or arc segments, you should be able to simply impose the 'Coordinates VLA Property from one onto the other. But I guess [without trying it] that could have trouble if they don't have the same number of vertices, and there may be other complications I haven't thought of....
@Kent1Cooper wrote:
.... If they're geometrically rather simple Polylines, that is, without width(s) or arc segments, you should be able to simply impose the 'Coordinates VLA Property from one onto the other. But I guess [without trying it] that could have trouble if they don't have the same number of vertices....
I just tried it. It doesn't mind different numbers of vertices [the target Polyline ends up with the same number as the source], but [as I expected] it transfers only vertex locations. if any segments in the source Polyline are arcs, that doesn't come through into the target one, and if any of the target Polyline's segments are arcs, they remain so even if the corresponding segment of the source is a line, or if that segment in the source is also an arc, the one in the target retains its original bulge factor, rather than matching the one in the source. And similarly, any widths remain per vertex in the re-positioned target Polyline, regardless of any [or lack thereof] in the source.
But if you're using only-line-segment Polylines without widths [in simplest terms]:
(setq
source (vlax-ename->vla-object (car (entsel "\nSource Polyline: ")))
target (vlax-ename->vla-object (car (entsel "\nTarget Polyline: ")))
)
(vla-put-Coordinates target (vla-get-Coordinates source))
@ceethreedee.com wrote:
.... Be good if this worked with 3d polylines as well? .....
Be also awesome if it gave you had an option to delete the object you steal the geometry from..
The code in Post 4 works for 3D as well as both kinds of 2D Polylines, provided the source and target are of the same variety.
You can add this to delete the one you steal from:
(vla-delete source)
@ceethreedee.com wrote:
.....
.... (initget "Y N _Yes No")
(setq dp (getkword "\nDo you want to delete the source polyline? (Yes/No): "))
(if (= dp "Yes")
(progn
(vla-delete source) ; delete source polyline
)
)
....
By the way, all you need for that is (initget) function is:
(initget "Yes No")
That will return "Yes" whether the User types Y or y or YES or yes or YeS or yEs or Ye or .... Read more about (initget) & (getkword) in Help to understand why.
Also, the (progn) isn't doing anything for you -- that's only needed if more than one operation needs to be "wrapped" together to make them into a single 'then' or 'else' expression in an (if) function.
And you can do without that dp variable:
(if (= (getkword "\nDo you want to delete the source polyline? [Yes/No]: ") "Yes")
(vla-delete source) ; delete source polyline
); if
Note the square brackets around the options -- in newer versions, that will put them up where you can pick one on-screen as an option in addition to typing an answer.
There are some other things -- localize variables, verify valid selection before trying to work with something, etc. -- but enough for now.
Pared down a little too far this time -- you left out the
(initget "Yes No")
which will be necessary for a User entry of, for example, just "y" to return the full word "Yes" that the (if) test is looking for.
@Anonymous wrote:
Have you find a Way tô do the same for 3dpolylines?
Have you tried it? See Messages 7 & 8.
But since there were some suggestions and edits and further correction not yet incorporated, here's a consolidated version:
(defun c:repoly (/ source target)
(setq
source (vlax-ename->vla-object (car (entsel "\nSource Polyline: ")))
target (vlax-ename->vla-object (car (entsel "\nTarget Polyline: ")))
); setq
(vla-put-Coordinates target (vla-get-Coordinates source))
(initget "Yes No")
(if (= (getkword "\nDo you want to delete the source polyline? [Yes/No]: ") "Yes")
(vla-delete source) ; then -- delete source polyline
); if
(princ)
); defun
@damian_dymczyk wrote:
.... the geometry I work with is filled with bulges. Is there a way to preserve them while recreating the geometry?
See Message 4 for some discussion of the complications. Do you need the entity name and handle of the target/altered Polyline to remain the same? If not, does COPY not do what you need, or just something like changing the Layer of the source Polyline?