Replace old block with new dynamic block
Hi Brad,
'Quick and Dirty' and not test for locked layers....
(vl-load-com)
(defun c:demo (/ ss blk obj)
(if (and
(setq ss (ssget "_X" (list '(0 . "INSERT") '(2 . "block-1,block-2,block-3") (cons 410 (getvar 'CTAB)))))
(setq blk (findfile "C:\\folder1\\folder\\newdynamicblock.dwg")) ; change to the correct full name
)
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
name (vla-get-effectivename obj)
)
(cond ((= name "block-1")
(setq vis "state-1")
)
((= name "block-2")
(setq vis "state-2")
)
(T
(setq vis "state-3")
)
)
(command "-insert" blk "_S" 1 "_R" 0 "_NONE" (vlax-get obj 'InsertionPoint))
(setq lasthnd (entlast)
lastobj (vlax-ename->vla-object lasthnd)
)
(if (and (vlax-property-available-p lastobj 'IsDynamicBlock)
(eq (vla-get-IsDynamicBlock lastobj) :vlax-true)
)
(progn
(foreach p (vlax-safearray->list
(vlax-variant-value (vla-getdynamicblockproperties lastobj))
)
(if (and (eq (vlax-get p 'PropertyName) "VisibilityName") ; change to the correct Name
(vl-position vis (vlax-get p 'AllowedValues))
)
(vlax-put-property p "Value" vis)
)
)
(vla-delete obj)
)
)
)
)
(princ)
)
Hope this helps,
Henrique
@Anonymous wrote:
Henrique, first of all thanks for your help. It is much appreciated. Unfortunately I haven't been able to get this to work. In the section where you are linking the block to the visibility state it looks like there may be a mix up with the 3rd block since the name is mentioned. I did try a modified version, following the syntax of the previous items (see below), but this did not work either. I don't receive any errors loading or running the lisp.
Thanks,
Brad
(cond ((= name "block-1") (setq vis "state-1") ) ((= name "block-2") (setq vis "state-2") ) ((= name "block-3") (setq vis "state-3") ) )
Hi Brad,
from my code:
; selected 'blocks', only block-1. block-2 and block-3
(cond (; test if name is block-1
(= name "block-1")
; if true
; set vis to state-1
(setq vis "state-1")
)
(; if previous test fail,
; test if name is block-2
(= name "block-2")
; if true
; set vis to state-1
(setq vis "state-2")
)
(; if both previous tests fail
; the 'block' name must be block-3
; the conditional function is just a T
; will return 'true'
T ; (it could be written without this test,
; but I like to write it this way...
; set vis to state-1
(setq vis "state-3")
)
)
If possible, post a sample dwg, with the blocks to to replace, and the DynBlock to replace the static ones...
Hope this helps,
Henrique
Brad,
your dynamic block, dont have the same insertion point as the blocks to be replaced...
Just a starting point, i did commented the 'vla-erase' just for visual debugging...
(vl-load-com)
(defun c:demo (/ ss blk obj)
(if (and
(setq ss (ssget "_X" (list '(0 . "INSERT") '(2 . "IIFM,SDFM,CFFM,PLFM") (cons 410 (getvar 'CTAB)))))
(setq blk "GENERAL INSTRUMENT")
)
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
name (vla-get-effectivename obj)
)
(cond ((= name "IIFM")
(setq vis "INDEPENDENT INSTRUMENTS")
)
((= name "SDFM")
(setq vis "SHARED DISPLAY/SHARED CONTROL OF DISTRIBUTED CONTROL SYSTEM")
)
((= name "CFFM")
(setq vis "COMPUTER FUNCTION")
)
(T
(setq vis "PROGRAMMABLE LOGIC CONTROL")
)
)
(command "-insert" blk "_S" 1 "_R" 0 "_NONE" (vlax-get obj 'InsertionPoint))
(setq lasthnd (entlast)
lastobj (vlax-ename->vla-object lasthnd)
)
(if (and (vlax-property-available-p lastobj 'IsDynamicBlock)
(eq (vla-get-IsDynamicBlock lastobj) :vlax-true)
)
(progn
(foreach p (vlax-safearray->list
(vlax-variant-value (vla-getdynamicblockproperties lastobj))
)
(if (and (eq (vlax-get p 'PropertyName) "Visibility1")
(vl-position vis (vlax-get p 'AllowedValues))
)
(vlax-put-property p "Value" vis)
)
)
;(vla-delete obj)
)
)
)
)
(princ)
)
Hope this helps,
Henrique
@Anonymous wrote:
Henrique,
I was able to get your routine to work, great job and thanks for your effort! Unfortunately it looks like this routine places the new block at the insertion of the existing block rather than an actual block replacement. The issue with this method is the attribute values won't carry over to the new block. I have currently made provisions for each of the different types to be placed on a specific layer that can be isolated to aid in changing the visibility state after doing a blockreplace. This will be a workable solution in our update process. If your tired of my little project feel free to move on. If you would like to continue helping me out perhaps a routine that would select all the "block-1" blocks on layer "layer-1" and change the visibility state to "state-1" would do the trick.
In either case, much thanks for your help!
Brad
Brad,
even using blockreplace, will have to replace one block, for one other using the same insertion point.
Try the revised code, with the attached dwg, with the 'GENERAL INSTRUMENT' redefined by me...
(vl-load-com)
(defun c:demo (/ attlst attlst1 attlst2 b blk i lasthnd lastobj name obj ss vis)
(or adoc (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
(vla-startundomark adoc)
(if (and (setq ss (ssget "_X" (list '(0 . "INSERT") '(2 . "IIFM,SDFM,CFFM,PLFM") (cons 410 (getvar 'CTAB)))))
(setq blk "GENERAL INSTRUMENT")
)
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
name (vla-get-effectivename obj)
attlst (vlax-invoke obj 'GetAttributes)
attlst1 nil
)
(foreach a attlst
(setq attlst1 (cons (cons (vla-get-tagstring a) (vla-get-textstring a)) attlst1))
)
(cond ((= name "IIFM")
(setq vis "INDEPENDENT INSTRUMENTS")
)
((= name "SDFM")
(setq vis "SHARED DISPLAY/SHARED CONTROL OF DISTRIBUTED CONTROL SYSTEM")
)
((= name "CFFM")
(setq vis "COMPUTER FUNCTION")
)
(T
(setq vis "PROGRAMMABLE LOGIC CONTROL")
)
)
(command "-insert" blk "_S" 1 "_R" 0 "_NONE" (vlax-get obj 'InsertionPoint))
(setq lasthnd (entlast)
lastobj (vlax-ename->vla-object lasthnd)
attlst2 (vlax-invoke lastobj 'GetAttributes)
)
(foreach a attlst2
(if (setq b (assoc (vla-get-tagstring a) attlst1))
(vla-put-textstring a (cdr b))
)
)
(if (and (vlax-property-available-p lastobj 'IsDynamicBlock)
(eq (vla-get-IsDynamicBlock lastobj) :vlax-true)
)
(progn
(foreach p (vlax-safearray->list
(vlax-variant-value (vla-getdynamicblockproperties lastobj))
)
(if (and (eq (vlax-get p 'PropertyName) "Visibility1")
(vl-position vis (vlax-get p 'AllowedValues))
)
(vlax-put-property p "Value" vis)
)
)
;(vla-delete obj)
)
)
)
)
(vla-endundomark adoc)
(princ)
)
As I said in an earlier post, the vla-delete is commented, just for visual debugging, to erase the original 'INSERT', just remove the ";".
Hope this helps,
Henrique
@Anonymous wrote:
Works great, thanks Henrique!
You're welcome, Brad!
Glad I could help
Henrique
