Remove object from blocks (No Deleted)

[neam]

Hi everyone:

Is it possible to remove (no delete) an object (e.g. all text that are in layer "Cement_Total") from all blocks?

[komondormrex]

hey,

you can switch them off

(defun c:twrblkpropchg ( / blc blk doc idx lst sel )
   (if (setq sel (ssget "_X" '((0 . "INSERT"))))
       (progn
           (setq doc (vla-get-activedocument (vlax-get-acad-object))
                 blc (vla-get-blocks doc)
           )
           (repeat (setq idx (sslength sel))
               (setq idx (1- idx)
                     blk (vla-get-effectivename (vlax-ename->vla-object (ssname sel idx)))
               )
                       (vlax-for obj (vla-item blc blk)
                           (if (and (wcmatch (strcase (vla-get-Objectname obj)) "*TEXT") (= (vla-get-layer obj) "Cement_Total"))
                               (vlax-put obj 'visible 0); 0 - off, 1 - on
                           )
                       )
           )
           (vla-regen doc acallviewports)
       )
   )
   (princ)
)
(vl-load-com) (princ)

[ronjonp]

@neam Why don't you just freeze 'Cement_Total' layer? There does not seem to be anything else on that layer but the text.

[paullimapa]

Change the Layer "Cement_Total" status to No Plot

[neam]

Thankful for reply.

I wanted to know if it is possible to do something like the Refedit (Remove from working set) command with the help of Lisp. Because I wanted to use Cement_Total information elsewhere (without exploding them or making them invisible).

[neam]

Thankful for reply.

I wanted to know if it is possible to do something like the Refedit (Remove from working set) command with the help of Lisp. Because I wanted to use Cement_Total information elsewhere (without exploding them or making them invisible).

[neam]

Thankful for reply.

I wanted to know if it is possible to do something like the Refedit (Remove from working set) command with the help of Lisp. Because I wanted to use Cement_Total information elsewhere (without exploding them or making them invisible).

But with the search I made on Google and your guidance.
It seems that this is not possible.

[neam]

for example:

[Kent1Cooper]

---

@neam wrote:

.... I wanted to know if it is possible to do something like the Refedit (Remove from working set) ....

---

Would there ever be more than one insertion of the same Block name?  If so, REFEDITING it [whether or not that can be done with AutoLisp] to remove that Text would remove it from all such insertions, and only the one at the insertion where the RefEditing was done will remain as an independent Text object not nested in a Block.

[neam]

Dear Kent thankful for your reply
As you can see in the last attached file.
There are more than 600 blocks with different names on the map.
In all of them, text: CT=123... is common in layer: Cement_Total.

I would be grateful if you could help me further.

[Kent1Cooper · Accepted solution]

Well, this is weird.  It has to be done with REFEDIT if you want the Text to remain in the drawing.  But REFEDIT is very finicky about how you select the Block.  You can't just give it an entity name, but it wants a pick.  I tried having it select by the insertion point, where there always seems to be something drawn to pick on, but you have a lot with coinciding insertion points, so it was something seeing the wrong one.  So I tried Isolating each one.  That works for over a hundred of them, but it hangs up when it gets to the Block named Bcement1120, asking again for selection.  I don't see anything about that one that's different from others in a way that should cause this.  It even leaves the drawing in a weird state regarding object selection and highlighting.  I tried turning off Undo recording, I tried freezing the "freez" Layer just in case, I tried getting rid of that particular Block but it just hangs up on the next one.  In case you or anyone wants to try whether the same happens for them, here's the latest iteration:

(defun C:UNCT ; = Un-Nest Cement Text
  (/ ss n blk)
  (if (setq ss (ssget "_A" '((0 . "INSERT") (2 . "Bcement*"))))
    (progn ; then
      (command
        "_.layer" "_thaw" "*" "_on" "*" ""
        "_.regen"
      ); command
      (repeat (setq n (sslength ss)); then
        (setq blk (ssname ss (setq n (1- n))))
        (command
          "_.isolateobjects" blk ""
          "_.-refedit"
            (getpropertyvalue blk "Position")
            "_ok" "_all" "_no"
            "_refset" "_remove" (ssget "_A" '((0 . "TEXT") (8 . "Cement_Total") (1 . "CT=*"))) ""
          "_.refclose" "_save"
          "_.unisolateobjects"
        ); command
      ); repeat
    ); progn
  ); if
  (prin1)
)

[ronjonp]

---

@neam wrote:

Thankful for reply.

I wanted to know if it is possible to do something like the Refedit (Remove from working set) command with the help of Lisp. Because I wanted to use Cement_Total information elsewhere (without exploding them or making them invisible).

But with the search I made on Google and your guidance.
It seems that this is not possible.

---

So if you don't want the layer frozen or the text made invisible then what do you gain by storing this information elsewhere to use it later? I'm confused. 🤔

[neam]

Dear Kenet thank you so much.

Thank you for taking the time to solve my problem🙏🙏

[neam]

Dear ronjonp:

I am very sorry that I could not express my meaning properly.
I find that the easiest way to do this is to explode the blocks and extract the cement amount information.
During the construction of the dam, we need to insulate the dam construction site by injecting diluted cement at different depths and with pressure.

And the number of these injections can be up to 6000 in total.

And I wanted to use the Refedit function in Lisp, which I did not know, and I raised it in the forum.

[ronjonp · Accepted solution]

---

@neam wrote:

Dear ronjonp:

I am very sorry that I could not express my meaning properly.
I find that the easiest way to do this is to explode the blocks and extract the cement amount information.
During the construction of the dam, we need to insulate the dam construction site by injecting diluted cement at different depths and with pressure.

And the number of these injections can be up to 6000 in total.

And I wanted to use the Refedit function in Lisp, which I did not know, and I raised it in the forum.

---

@neam No worries. Here's another way to tally those numbers without isolating them.

(defun c:foo (/ b r s)
  (cond	((setq s (ssget '((0 . "INSERT") (2 . "Bcement*"))))
	 (setq b (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))
	 (setq r 0)
	 (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
	   (vlax-for a (vla-item b (cdr (assoc 2 (entget e))))
	     (if (and (= "AcDbText" (vla-get-objectname a)) (= "Cement_Total" (vla-get-layer a)))
	       (progn (print (vla-get-textstring a))
		      (setq r (+ r (atof (substr (vla-get-textstring a) 4))))
	       )
	     )
	   )
	 )
	 (alert (vl-princ-to-string r))
	)
  )
  (princ)
)

[neam]

Thank you again. I hope that I can benefit from your guidance and expertise in the future.

[devitg]

post twice 

[devitg]

@neam Please give it a try, it work with your TMPL_Section 1.dwg

[neam]

Thank you for your attention.
Your code is also a solution, I will use it too.