Need help with lisp code
Please show us an example what you want to get.
Jürgen Palme
Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Accepted solution
@Anonymous wrote:
I need a code that will draw a series of concentric circles from a common point (maybe user selected) to points on a line (or nodes). ....
If the User is to select the Points, in simplest terms, something like this [minimally tested]:
(defun c:CTP (/ ptss ctr)
(prompt "\nFor Points through which to draw concentric Circles,")
(setq
ptss (ssget '((0 . "POINT")))
ctr (getpoint "\nCenter of concentric Circles: ")
)
(repeat (setq n (sslength ptss))
(command "_.circle"
"_none" ctr
"_none" (cdr (assoc 10 (entget (ssname ptss (setq n (1- n))))))
)
)
(princ)
)
The same general idea could be applied if the Points are selected by some automatic means, such as collecting them after a MEASURE or DIVIDE command, and likewise if the common center is to determined other than by the User selecting it.
Kent Cooper, AIA 
@Anonymous wrote:
... concentric circles from a common point (maybe user selected) to points on a line (or nodes). ....
Can we get a clarification about terminology? People are interpreting this differently. A reply to @j.palmeL29YX's request may answer it sufficiently, but to clarify why that request was made:
What, exactly, do you mean by "points on a line (or nodes)"? Because NODE is the Object-Snap designator for Point entities [or Point objects, if you prefer], such as are drawn with the POINT or MEASURE or DIVIDE commands, I assumed that was what you meant by "points" in the routine I posted [which would deal with them whether or not there is any "line" or path of any kind involved]. But maybe you are using the word "line" not in the sense that AutoCAD uses it [a Line entity or Line object ], but rather, as some people sometimes do around here, in a looser sense that might include other kinds of "linework" such as Polylines or Arcs or Splines or.... If that's what you mean, and if "nodes" might be something like what AutoCAD would call vertices along a Polyline, then the solution would be very different, and potentially far more complicated if different meanings for both "point" and "line" might be involved in the same operation, as @Anonymous has pointed out.
So what is it?
Kent Cooper, AIA
@Sea-Haven wrote:
....
... (setq pt (getpoint "\Please pick centre point")) (while (setq rad (getreal "\nPlease enter radius Enter to exit")) (command "circle" pt rad) ) ....
That would have been my approach, with one exception: I suggest you use (getdist) rather than (getreal) to ask for the radii. That way, you have options that (getreal) does not allow. You can give it a radius by picking two points on-screen if appropriate. And if you use Imperial Architectural units, you can type in a value in feet and inches and fractions if you want.
Kent Cooper, AIA
@cschnarr wrote:
....
.... (defun c:concirc ( / pt rad dia) (setq pt (getpoint "\nSELECT CENTER POINT")) (while (setq dia (getdist "\nNEXT CIRCLE DIAMETER - Enter to exit")) (setq rad (/ dia 2)) (command "circle" pt rad) ) ........
Just a small suggestion: Any variable that is used only once doesn't need to be saved to a variable. You can just put whatever determines its value in at the place where that value is needed. In this case, the rad variable is not necessary:
....
(defun c:concirc (/ pt dia)
(setq pt (getpoint "\nSELECT CENTER POINT: "))
(while (setq dia (getdist "\nNEXT CIRCLE DIAMETER <exit>: "))
(command "_.circle" "_non" pt (/ dia 2))
)
)
....[I added the "_non" Osnap call before the pt circle center, in case there might sometimes be anything near enough to there that any running Osnap mode(s) could catch it unintended.]
Kent Cooper, AIA
@cschnarr wrote:
....
Can you show me where my structure is incorrect?
(defun c:concirc ( / pt def rad dia) (initget 1 "Diameter Radius") (cond ((eq def "diameter") 2) ((eq def "radius") 1) (setq def (getreal "Options: Diameter/<Radius>")) ) ; end cond ........
Could it have something to do with case-sensitivity?
....
((eq def "Diameter") 2)
((eq def "Radius") 1)
....
But beyond that, the structure is wrong. In one place it checks for a text-string value for the def variable, in nother place for an integer value. One variety is enough -- I don't think you need the integers.
Your (initget) with the 1 argument disallows Enter, so there's no way of accepting the default -- the User is required to type something in at the prompt every time.
I would try something like this:
(defun C:CONCIRC (/ pt dist)
(initget 6 "Diameter Radius"); no 0, no negative [don't disallow Enter]
(setq CCdef ; global variable
(cond
( (getkword
(strcat
"Options [Diameter/Radius] <"
(cond (CCdef) ("Radius"))
; [current value default if present, otherwise Radius]
">: "
); strcat
); getkword
); end User-input condition
(CCdef); current value default if present on Enter
("Radius"); initial default [Enter on first use]
); cond & CCdef
pt (getpoint "\nSELECT CENTER POINT")
); setq
(while
(setq dist
(getdist (strcat "\nNext Circle " def " <exit>: "))
); setq
(command "_.circle" "_non" pt
(if (= CCdef "Radius") dist (/ dist 2))
); command
); while
(princ)
)
Kent Cooper, AIA
Correction:
(getdist (strcat "\nNext Circle " CCdef " <exit>: "))
[The CCdef variable name is to be more distinctive and this-command-specific, to reduce the likelihood of its being overwritten by another routine that might use the same variable name if it were more generic.]
Kent Cooper, AIA
If you do have preset values this may be useful its a library routine. So you could call various list of size options. It is just called from your code. Tick on as many as you want. This has a 1 line spacer so could get twice as many displayed if remove 1 line from code. Just ask if you want help.
(if (not AH:Toggs)(load "Multiple toggles.lsp"))
(ah:toggs '("Choose a diameter" "6.25" "7.125" "8.96" "9.5" "1" "2" "3" "4" "5" "6" "7" "8" "9" "10" "11" "12"))
@cschnarr wrote:
.... None of my vendors specify pipe, or tube or rod, or bolts, or really anything else by radius. We always get diameters. ....
.... ;; All circles are defined by keyboard entry of the next circle's diameter or radius (user's choice). ;; User's choice of circle definition (CCdef) will be used for all consecutive circles (ie. all diameters entered). ;; The next time the routine is called the user is presented with the choice of radius or diameter definitions again. .... "Options [Diameter/Radius] <" (cond (CCdef) ("Radius")) ; [current value default if present, otherwise Radius] ">: " ); strcat ); getkword ); end User-input condition (CCdef); current value default if present on Enter ("Radius"); initial default [Enter on first use] ....
Hope this helps someone else!
If you usually get Diameters, you can make that the initial default option. And a few suggested tweaks of the description, for capabilities that are there even if you don't often use them:
....
;; All circles are defined by keyboard entry of the next circle's diameter or radius (user's choice) or by picking two points on-screen.
;; User's choice of circle definition (CCdef) will be used for all consecutive circles (ie. all diameters or radii entered).
;; The next time the routine is called the user is presented with the choice of radius or diameter definitions again, with the previous choice offered as default.
....
"Options [Diameter/Radius] <"
(cond (CCdef) ("Diameter"))
; [current value default if present, otherwise Diameter]
">: "
); strcat
); getkword
); end User-input condition
(CCdef); current value default if present on Enter
("Diameter"); initial default [Enter on first use]
....
Kent Cooper, AIA