@msmith_ncl wrote:
I've had a look at a few different lisp routines for exporting attributes to different formats and couldn't find anything suitable.
Try this then [ change the block1 to the actual block name ]
(Defun c:TripleCSV ( / _comma data ss i folder opf csvfile)
;; pBe Nov 2020 ;;;;
(setq _comma (lambda (lst)(substr
(apply 'strcat
(mapcar '(lambda (str)
(strcat "," str) ) lst)
) 2
)
)
)
(if
(and
(setq data nil
ss (ssget '((0 . "INSERT")(66 . 1)(2 . "block1"))))
(repeat (setq i (sslength ss))
(setq data (cons
(mapcar '(lambda (atb)
(list (vla-get-tagstring atb)
(Vla-get-textstring atb)))
(Vlax-invoke
(vlax-ename->vla-object
(ssname ss (setq i (1- i)))
)
'GetAttributes
)
)
data
)
) data
)
(setq data (vl-sort data
'(lambda (n m)
(< (cadr (assoc "DEVICE_NUMBER" n))
(cadr (assoc "DEVICE_NUMBER" m))
)
)
)
)
(setq folder (acet-ui-pickdir (Getvar 'dwgprefix)))
)
(foreach itm '(("PREFIX_Devices"
("DEVICE_NUMBER" "DEVICE_TYPE" "PANEL_NUMBER" "PORT_NUMBER" ))
("PREFIX_Inputs"
("DEVICE_NUMBER" "PANEL_NUMBER" "PORT_NUMBER" "INPUT_NUMBER" "INPUT_TYPE" ))
("PREFIX_Outputs"
("DEVICE_NUMBER" "PANEL_NUMBER" "PORT_NUMBER" "OUTPUT_NUMBER" "OUTPUT_TYPE" ))
)
(setq opf (open (setq csvfile (strcat folder "\\" (Car itm) ".csv")) "w"))
(write-line (_comma (setq taglst (Cadr itm))) opf)
(Foreach val data
(write-line
(_comma (mapcar '(lambda (v)
(cadr (assoc v val))) taglst)) opf)
)
(close opf)
(startapp "explorer" csvfile)
)
)
(princ)
)
The CSV filename on selected folder
Tested on posted drawing [ Device Blocks.dwg ]
HTH
@msmith_ncl wrote:
Many thanks, that's exactly what I needed, much appreciated, only 1 thing that would make it more perfect is if the user could be prompted for a reference number - AP123456 or similar and this would be used as the prefix for all 3 csv filenames
You are welcome @msmith_ncl
Here's an idea, I'm not really a big fan of "typing" values., if the "reference number" is part of name of the folder you select to save the files , we can just grab it from there?
Hows' that sound? if that is not possble then we will add the prompy for prefix.
@msmith_ncl wrote:
I would prefer prompt,
HYG
(Defun c:TripleCSV ( / _comma data ss i folder opf csvfile)
;; pBe Nov 2020 ;;;;
(setq _comma (lambda (lst)(substr
(apply 'strcat
(mapcar '(lambda (str)
(strcat "," str) ) lst)
) 2
)
)
)
(if
(and
(setq ReferenceNumber (strcase (getstring "\nEnter Reference Number: ")))
(snvalid ReferenceNumber )
(setq data nil
ss (ssget '((0 . "INSERT")(66 . 1)(2 . "block1"))))
(repeat (setq i (sslength ss))
(setq data (cons
(mapcar '(lambda (atb)
(list (vla-get-tagstring atb)
(Vla-get-textstring atb)))
(Vlax-invoke
(vlax-ename->vla-object
(ssname ss (setq i (1- i)))
)
'GetAttributes
)
)
data
)
) data
)
(setq data (vl-sort data
'(lambda (n m)
(< (cadr (assoc "DEVICE_NUMBER" n))
(cadr (assoc "DEVICE_NUMBER" m))
)
)
)
)
(setq folder (acet-ui-pickdir (Getvar 'dwgprefix)))
)
(foreach itm '(("_Devices"
("DEVICE_NUMBER" "DEVICE_TYPE" "PANEL_NUMBER" "PORT_NUMBER" ))
("_Inputs"
("DEVICE_NUMBER" "PANEL_NUMBER" "PORT_NUMBER" "INPUT_NUMBER" "INPUT_TYPE" ))
("_Outputs"
("DEVICE_NUMBER" "PANEL_NUMBER" "PORT_NUMBER" "OUTPUT_NUMBER" "OUTPUT_TYPE" ))
)
(setq opf (open (setq csvfile (strcat folder "\\" ReferenceNumber (Car itm) ".csv")) "w"))
(write-line (_comma (setq taglst (Cadr itm))) opf)
(Foreach val data
(write-line
(_comma (mapcar '(lambda (v)
(cadr (assoc v val))) taglst)) opf)
)
(close opf)
(startapp "explorer" csvfile)
)
)
(princ)
)
@msmith_ncl wrote:
..Is it an easy fix to only export attributes depending on their visibility state?
Yes
@msmith_ncl wrote:
I have attached a new detail with dynamic version of the block. Any help or advice you can give is much appreciated. Thanks.
Will this be just for this block? any other block you are planning to use it for?
Also, is it always just three of this blocks on the drawing? or more<--- and if it is then how would the result look like on the csv file?
@msmith_ncl wrote:
I might add more blocks or more possibilities in the visibility states, not sure yet, there will always be an ID attribute tag called DEVICE_NUMBER and maybe another block with PANEL_NUMBER attribute. The CSV files wont change much, maybe some adjustments to which attribute lands in each file. Thanks.
Try this.
(Defun c:TripleCSVD ( / _comma _Visible data ss i ev dp attb a b c folder opf csvfile)
;; pBe Nov 2020 ;;;;
(setq _comma (lambda (lst)(substr
(apply 'strcat
(mapcar '(lambda (str)
(strcat "," str) ) lst)
) 2
)
)
)
(defun _Visible (l) (Vl-remove-if '(lambda (atv)
(zerop (car atv))) l))
(and
(setq ReferenceNumber (strcase (getstring "\nEnter Reference Number: ")))
(snvalid ReferenceNumber )
(setq data nil
ss (ssget '((0 . "INSERT")(66 . 1))))
(repeat (setq i (sslength ss))
(setq ev (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
(if (and
(setq vp (Vl-some '(lambda (dy)
(if (eq (Vlax-get dy 'PropertyName) "Lookup1")
(Vlax-get dy 'Value)))
(Vlax-invoke ev 'GetDynamicBlockProperties)))
(setq attb (mapcar '(lambda (atb)
(list (vlax-get atb 'Visible )(vla-get-tagstring atb)
(Vla-get-textstring atb)))
(Vlax-invoke ev 'GetAttributes)
)
)
)
(setq data (cons (list vp (mapcar 'cdr (_Visible attb))) data ))
)
)
(setq folder (acet-ui-pickdir (Getvar 'dwgprefix)))
(setq data (Vl-sort data '(lambda (a b)
(Cond
((< (car a)(Car b)))
((= (car a)(Car b))(< (cadr (caadr a))(cadr (caadr b)))))))
)
(while (setq a (Car data))
(setq opf (open (setq csvfile (strcat folder "\\" ReferenceNumber "_" (Car a) ".csv")) "w"))
(write-line (_comma (mapcar 'car (Cadr a))) opf)
(while (eq (car (setq c (car data))) (Car a))
(write-line (_comma (mapcar 'cadr (Cadr c))) opf)
(setq data (cdr data)))
(Close opf)
(startapp "explorer" csvfile)
)
)
(princ)
)
HTH
(Defun c:TripleCSVD ( / _comma _Visible data ss i ev dp attb a b c folder opf csvfile)
;; pBe Nov 2020 ;;;;
(setq _comma (lambda (lst)(substr
(apply 'strcat
(mapcar '(lambda (str)
(strcat "," str) ) lst)
) 2
)
)
)
(defun _Visible (l) (Vl-remove-if '(lambda (atv)
(zerop (car atv))) l))
(and
(setq ReferenceNumber (strcase (getstring "\nEnter Reference Number: ")))
(snvalid ReferenceNumber )
(setq data nil
ss (ssget '((0 . "INSERT")(66 . 1))))
(repeat (setq i (sslength ss))
(setq ev (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
(if (and
(setq vp (Vl-some '(lambda (dy)
(if (eq (Vlax-get dy 'PropertyName) "Lookup1")
(Vlax-get dy 'Value)))
(Vlax-invoke ev 'GetDynamicBlockProperties)))
(setq attb (mapcar '(lambda (atb)
(list (vlax-get atb 'Visible )(vla-get-tagstring atb)
(Vla-get-textstring atb)))
(Vlax-invoke ev 'GetAttributes)
)
)
)
(setq data (cons (mapcar 'cdr (_Visible attb)) data ))
)
)
(setq folder (acet-ui-pickdir (Getvar 'dwgprefix)))
(setq data (vl-sort data
'(lambda (n m)
(< (cadr (assoc "DEVICE_NUMBER" n))
(cadr (assoc "DEVICE_NUMBER" m))
)
)
)
)
(foreach itm '(("_Devices"
("DEVICE_NUMBER" "DEVICE_TYPE" "PANEL_NUMBER" "PORT_NUMBER" ))
("_Inputs"
("DEVICE_NUMBER" "PANEL_NUMBER" "PORT_NUMBER" "INPUT_NUMBER" "INPUT_TYPE" ))
("_Outputs"
("DEVICE_NUMBER" "PANEL_NUMBER" "PORT_NUMBER" "OUTPUT_NUMBER" "OUTPUT_TYPE" ))
)
(setq opf (open (setq csvfile (strcat folder "\\" ReferenceNumber (Car itm) ".csv")) "w"))
(write-line (_comma (setq taglst (Cadr itm))) opf)
(Foreach val data
(if (vl-every '(lambda (j)(assoc j val)) (Cadr itm))
(write-line
(_comma (mapcar '(lambda (v)
(cadr (assoc v val))) taglst)) opf)
)
)
(close opf)
(startapp "explorer" csvfile)
)
)
(princ)
)
