Multileader style Name

[MShoesmith]

Hi,

I would like to create a quick selection set of a Multi-leader style (named "ABC").

I am struggling to do this and i understand that you need to drill into the Dictionary to obtain the style name.

I am wanting to select the Multileader style in the current space and this is what i have so far...

(if (setq ss (ssget "_A" (list '(0 . "MULTILEADER")(if (= 1 (getvar 'cvport)) (cons 410 (getvar 'ctab)) '(410 . "Model")))))(sssetfirst nil ss))

 If there is a way of adding the Multileader style  name to this, i would be very grateful for any help.

Ta

Shoey

[Sea-Haven]

Have a look at this a couple of suggestions.

Select MLeader by Mleader style - AutoLISP, Visual LISP & DCL - AutoCAD Forums (cadtutor.net)

[MShoesmith]

Cheers Pal.

So i have tested the code at the link and the code does work when replacing a Multileader style.

However, i would like the selection to go into a selection set.

Code is show below but comes with a "error bad argument type" message.

Again, any help appreciated

(defun c:test  (/ sel int obj)
 (if (setq sel (ssget "_A" (list '(0 . "MULTILEADER")(if (= 1 (getvar 'cvport)) (cons 410 (getvar 'ctab)) '(410 . "Model")))))
   (repeat (setq int (sslength sel))
     (setq obj (vlax-ename->vla-object (ssname sel (setq int (1- int)))))
     (if (eq (vla-get-stylename obj) "ABC")
       (sssetfirst nil obj)
       )
     )
   )
 (princ)
 )

.

[komondormrex · Accepted solution]

hey, somewhat corrected

(defun c:test  (/ mleader_sset mleader_sset_filtered)
 (setq mleader_sset_filtered (ssadd))
 (if (setq mleader_sset (ssget "_A" (list '(0 . "MULTILEADER")(if (= 1 (getvar 'cvport)) (cons 410 (getvar 'ctab)) '(410 . "Model")))))
   (foreach mleader (vl-remove-if 'listp (mapcar 'cadr (ssnamex mleader_sset)))
     (if (= "ABC" (vla-get-stylename (vlax-ename->vla-object mleader)))
     	(ssadd mleader mleader_sset_filtered) 
     )
   )
 )
 (sssetfirst nil mleader_sset_filtered )
 (princ)
 )

[MShoesmith]

Thank you very much. After testing, it does what i require.

I will study the code you have provided and learn from it.

Kind regards

[WeTanks]

In what situation is it useful？

Why not use it？

[komondormrex]

in selecting all mleaders, regardless of their styles 

[MShoesmith]

Select similar selects all Multi-leaders.

I could use QSELECT and select Multi-leader and style that way.

Both of these can use individually in dwg files.

The code given will select all Multi-leader styles in one-click. (Instead of several clicks in QSELECT).

But main reason is that i can use the code via a script when changing layer of the selected Multi-leader style in a batch of drawings.

Thanks

[WeTanks]

thanks for the reply.

I understand.

but, This Lisp can only choose ABC,
Others cannot be selected.
It feels a bit limiting.

[ВeekeeCZ]

@komondormrex @MShoesmith @WeTanks 

you guys explore SELECTSIMILARMODE if you're running it in the default setting.

And yes, SELECTSIMILAR can be used in scripts.

[MShoesmith]

Thanks for that.

I overlooked the SELECTSIMILARMODE for selecting Multi-leader styles. (object style was not checked in the settings for me).

I will look into using that and SELECTSIMILAR in a script too.

But the code provided is fine too.

Regards

[komondormrex]

so did i. too many variables to remember)))

[ВeekeeCZ]

Well, if that's the case, maybe your vision serves you better. 😉

[komondormrex · Accepted solution]

in case

(defun select_mleader_style  (mleader_style_list / mleader_sset mleader_sset_filtered)
	(setq mleader_sset_filtered (ssadd))
 	(if (setq mleader_sset (ssget "_A" (list '(0 . "MULTILEADER")(if (= 1 (getvar 'cvport)) (cons 410 (getvar 'ctab)) '(410 . "Model")))))
   		(if mleader_style_list 
   			(foreach mleader (vl-remove-if 'listp (mapcar 'cadr (ssnamex mleader_sset)))
   			  (if (member (vla-get-stylename (vlax-ename->vla-object mleader)) mleader_style_list)
   			  	(ssadd mleader mleader_sset_filtered) 
   			  )
   			)
			(setq mleader_sset_filtered mleader_sset)
		)
 	)
 	(sssetfirst nil mleader_sset_filtered )
 	(princ)
)

(select_mleader_style nil) - to select all mleaders

(select_mleader_style '("ABC" "BCD")) - to select all mleaders styled with "ABC", "ВCD" styles

[WeTanks]

You are Great!

This is very convenient！

どうもありがとうございました。