manipulation string

[alexandre_benekowski]

Hi people,

I have a string that i´d like to count in a different way. I know (and use) "strlen" but it is not what i want. So, i´d like to count numbers of characters before "+" and after "+":

ex:

1+25

answer

1 and 2

100+25.00

answer

3 and 5

Someone could help me?

[ronjonp]

Quick example:

(defun _foo (string del / i)
  (if (setq i (vl-string-search del string))
    (list (setq i (strlen (substr string 1 i))) (- (strlen string) (1+ i)))
  )
)
(_foo "100+25.00" "+")
;; (3 5)

[doaiena]

I've made a small edit to @Lee_Mac's String to List function. It will work with multiple entries.

;Lee Mac's LM:str->lst routine /with a small edit/
;http://lee-mac.com/stringtolist.html

(defun LM:str->lst ( str del / len lst pos )
    (setq len (1+ (strlen del)))
    (while (setq pos (vl-string-search del str))
        (setq lst (cons (strlen (substr str 1 pos)) lst)
              str (substr str (+ pos len))
        )
    )
    (reverse (cons (strlen str) lst))
)

;;;output:
;(LM:STR->LST "100+25.00+15+22.5+109" "+")
;(3 5 2 4 3)

[ronjonp]

---

@doaiena wrote:

I've made a small edit to @Lee_Mac's String to List function. It will work with multiple entries.

(defun LM:str->lst ( str del / len lst pos )
    (setq len (1+ (strlen del)))
    (while (setq pos (vl-string-search del str))
        (setq lst (cons (strlen (substr str 1 pos)) lst)
              str (substr str (+ pos len))
        )
    )
    (reverse (cons (strlen str) lst))
)

;;;output:
;(LM:STR->LST "100+25.00+15+22.5+109" "+")
;(3 5 2 4 3)

---

FWIW .. no need to change Lee's code. To get the result you have shown, call it like this:

(mapcar 'strlen (lm:str->lst "100+25.00+15+22.5+109" "+"))

[doaiena]

That works too. It just makes the statement a bit longer. Depends on @alexandre_benekowski's needs.

[ronjonp]

Sure .. I'd think the outcome would be something more like this from the description.

(setq l (mapcar 'strlen (lm:str->lst "100+25.00+15+22.5+109" "+")))
(mapcar '(lambda (r j) (list r j)) l (cdr l))
;; '((3 5) (5 2) (2 4) (4 3))

[Kent1Cooper · Accepted solution]

---

@alexandre_benekowski wrote:

... i´d like to count numbers of characters before "+" and after "+":

ex:

1+25

answer

1 and 2

100+25.00

answer

3 and 5

….

---

(setq str "1234+56")

Then:

(strcat

  (itoa (setq pre (vl-string-position (ascii "+") str)))

  " and "

  (itoa (- (strlen str) pre 1))

)

returns:
"4 and 2"

[alexandre_benekowski]

I Kent!!!

thank you so very much!!!

It work!!!!