Lisp to obtain Attribute value to Rotate Block
@Anonymous wrote:The angle will only be whole numbers....no decimal places or m/s/d.....There is a catch however. In the application I am using X= 0 degress, however, X points north in the 90 degree direction....and the angles go clockwise instead of counter clockwise as normal.....so - for instance, an "Azimuth angle" of 60degrees - (which is what is in the tag in the attribute) - is actually pointing at 30 degrees....because Azimuth angles are measurements from the North direction - which correlates to: Azimuth of 60degrees is 60degrees away from North..... North is pointing at 90d....so rotation of 60 degrees away from North (90) is the actual world angle of 30degrees......At any rate, I can program that part with a piece of code.....I just need a Lisp routine which will pull the field angle from the attribute, then rotate the block around its insertion point so that it is at the correct angle.
That's the reason i asked the question 
Is this any block that has the required attribute TAG Name, or a specific block?
What is the attributes TAG name?
Well, there are 4 or 5 blocks which have this same attribute tag within them. And, there are actually some other types of equipment blocks that I could modify the lisp routines to work with. Anyway, I have attached a few pics which show an assembly dwg with the antenna blocks I am referring to....the 2nd pic has one of the blocks with an exploded block showing the Att. Tags...and the insertion point. The 3rd is just another block which has the same Att. Tag - and would be used with the Lisp routine. The long centerline extending from the center of the circle is the line for which the Azimuth angle would correlate....As shown - that line is -310degrees from North, or "Azimuth 0" - which as I stated earlier is 90degrees in normal degrees. Hopefully all of that makes sense. Thanks for replying...I really appreciate your help with this.
Dustin
This is what the actual blocks look like....with 0,0 of each block being the center of the circle on the bottom of each.....The text is just the the Attribute defaults.....So this would be the blocks at "0 rotation"
@Anonymous hi,
check this version that has 2 command:
AZSET for setting to azimuth attribute according the block rotation.
AZROT for rotating the block according the azimuth appears in attribute value.
the (align_attrib) function is than called for each block to make sure attributes is in read state but this causes the attributes to be a little position shifted cause the attributes alignment are not in middle center justify so a block modification is needed here.
you should add the block names to the (ssget) filter - do you know how?
of course this lisp could be upgrade to use reactors to react to an attribute change and rotate change but adding object reactors to AutoCAD increase the system nervousness which i do not recommend 
enjoy
moshe
(defun az:azimuth (action / align_attrib fetch_digits deg2rad ; local functions
ss extval ang newval)
(defun align_attrib (ent / subent sube rot)
(setq subent (entnext ent) sube (entget subent))
(while (/= (cdr (assoc '0 sube)) "SEQEND")
(setq rot (cdr (assoc '50 sube)))
(if (and (> rot (/ pi 2)) (< rot (* pi 1.5)))
(entmod (subst (cons '50 (+ rot pi)) (assoc '50 sube) sube))
)
(setq subent (entnext subent) sube (entget subent))
); while
); align_attrib
(defun fetch_digits (str)
(vl-list->string
(vl-remove-if-not
'(lambda (n)
(and (>= n 48) (<= n 57))
)
(vl-string->list str)
)
)
); fetch_digits
; convert degrees to radians
(defun deg2rad (d)
(* (/ d 360.0) pi 2)
); deg2rad
; here start az:azimuth
(if (setq ss (ssget '((0 . "insert")))) ; add block names to filter
(foreach ename (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
(setq extval (getpropertyvalue ename "azimuth"))
(cond
((eq action 'SETT)
(setq ang (cdr (assoc '50 (entget ename))))
(setq newval (angtos (- (/ pi 2) ang) 0 0))
(setpropertyvalue ename "azimuth" (vl-string-subst newval (fetch_digits extval) extval))
); case
((eq action 'ROT)
(setq ang (deg2rad (atoi (fetch_digits extval))))
(setpropertyvalue ename "rotation" (- (/ pi 2) ang))
); case
); cond
(align_attrib ename)
); foreach
); if
(princ)
)
(defun c:AZset ()
(az:azimuth 'SETT)
)
(defun c:AZrot ()
(az:azimuth 'ROT)
)