Lisp to isolate layers that have multiple hatches

[Anonymous]

Hello,

As the title suggests, any idea? 

[ВeekeeCZ · Accepted solution]

Perhaps like this?

(defun c:LayIsoWHatches ( / def lay sel lst)

  (while (setq def (tblnext "LAYER" (null def)))
    (and (setq lay (cdr (assoc 2 def)))
         (setq sel (ssget "_X" (list '(0 . "HATCH") (cons 8 lay))))
         (> (sslength sel) 1)
         (setq lst (cons lay lst))))

  (if lst
    (progn
      (command "_.-LAYER"
               "_Off" "*" "_Yes")
      (foreach l lst
        (command "_On" l))
      (command "_Set" (car lst) "")))
  (princ (strcat "\n" (itoa (length lst)) " layers isolated."))
  (princ)
)

[Anonymous]

Hello again,

Is possible to make this to isolate layers that have multiple polylines?

Thanks

[ВeekeeCZ]

Just replace "HATCH" with "LWPOLYLINE".

[Anonymous]

Worked, how to make it isolate layers without any polylines?

Thank you

[ВeekeeCZ]

(setq sel (ssget "_X" (list '(0 . "HATCH") (cons 8 lay))))
(> (sslength sel) 1)

; ->

(not (ssget "_X" (list '(0 . "LWPOLYLINE") (cons 8 lay))))

[Anonymous]

Thank you a lot!