Community
Thanks for the sample file: your drawing is not to scale, is this a manufacturer supplied generic detail or a from-PDF conversion? You are going to open up a can of worms when you replace those text objects with actual dimensions.
Looks like your content was deliberately drawn out of scale.
@Anonymous wrote:
.... pick the existing dimension text, then place my new dimension and after i have made my final click the actual dimesion will be replace with the text i picked from the old exploded text. ....
For that assign-the-text-content part alone, in barest-bones terms, and involving User selection:
(defun C:TEST (/ txt dim)
(setq
txt (vlax-ename->vla-object (car (entsel "\nText: ")))
dim (vlax-ename->vla-object (car (entsel "\nDimension: ")))
)
(vla-put-TextOverride dim (vla-get-TextString txt))
)
It can have the User selection of the Dimension replaced by (entlast) after drawing the Dimension, easily enough, but otherwise, first I have questions:
You talk about selecting the pieces left over from what was a Dimension, to Erase them. Is the idea that the routine would find the Text object from among those pieces for you? A routine could figure that out if there's one Text object for it to find, but will run into trouble in your lower example in the sample drawing, which involves two Text objects. How should such a situation be handled?
In Message 1, you describe the process in terms of an Aligned Dimension, but have a Linear one in the code. From the sample drawing, the latter seems like the appropriate type, but please confirm that.
[As an aside, I would not use the OSMODE value in Message 1's code. That includes the NEArest mode, which will almost always "win out" over the rest of them, so the others will be pointless. And you could easily get it Dimensioned to incorrect places.]
EDIT:
For one with only one piece of Text, try this:
(defun C:DimReplace (/ parts txtss)
(command
"_.LAYER" "_make" "DIM" "_color" "6" "" ""
"dimstyle" "r" "AA DIM I"
); command
(prompt "\nTo delete exploded-Dimension pieces for replacement with Dimension,")
(setq
parts (ssget "_:L" '((0 . "LINE,TEXT,SOLID")))
txtss (ssget "_P" '((0 . "TEXT")))
); setq
(setvar 'osmode 247)
(command-s "_.dimlinear")
(vla-put-TextOverride
(vlax-ename->vla-object (entlast))
(vla-get-TextString (vlax-ename->vla-object (ssname txtss 0)))
); ...put...Override
(command "_.erase" parts "")
(princ)
)
It assumes the Dimension Style exists, and is of appropriate characteristics [e.g. Text size] to replace the exploded pieces.
If the selection before making the Dimension includes more than one piece of Text, it will use one of them as the source for the override, but you will have no control over which one.
Kent Cooper, AIA 
@Anonymous wrote:
... I didnt see that last lisp you build. It works perfect. The only thing that would make it better is if i could pick more that one line of text. ....
Something like this:
(defun C:DimReplace (/ parts txtss)
(command
"_.LAYER" "_make" "DIM" "_color" "6" "" ""
"dimstyle" "r" "AA DIM I"
); command
(prompt "\nTo delete exploded-Dimension pieces for replacement with Dimension,")
(setq
parts (ssget "_:L" '((0 . "LINE,TEXT,SOLID")))
txtss (ssget "_P" '((0 . "TEXT")))
); setq
(if (> (sslength txtss) 1); more than 1 Text object in selection
(progn ; then
(command "_.txt2mtxt" txtss "")
(setq txtss (ssadd (entlast))); Mtext-converted object only
(ssadd (entlast) parts); put back in for Erasing later
); progn
); if
(setvar 'osmode 247); [omitting NEArest]
(command-s "_.dimlinear")
(vla-put-TextOverride
(vlax-ename->vla-object (entlast))
(vla-get-TextString (vlax-ename->vla-object (ssname txtss 0)))
); ...put...Override
(command "_.erase" parts "")
(princ)
)
But depending on the relationships, you will sometimes need to edit the resulting Dimension text content for line-break location, etc. And it needs those multiple Text objects to be plain Text, not already Mtext. Minimally tested -- other peculiar circumstances [such as override formatting, maybe] could cause unexpected results.
Kent Cooper, AIA
@dani-perez wrote:
Hello Kent1Cooper, Recreating all types of dimensions would be very difficut, wouldnt it? it's just a question. Thanks.
It might not be too difficult, but it would need to be done separately for every variety, or possibly with separate options for every variety if within one command. A routine wouldn't have any way of determining what kind of Dimension the exploded pieces came from. It might be built to at least narrow down the possibilities from the selection, if the User can be counted on to be careful in picking all the pieces and only pieces that came from a single exploded Dimension. If the selection includes any Arcs, it was probably an Angular or Arc-length Dimension; if it includes any non-orthogonal Lines, it probably wasn't a "plain" Linear one, but could have been an Aligned or Rotated or Angular or Radius or Diameter or even Ordinate one, so that doesn't narrow it down much. The User would still need to know the available types and which is appropriate to replace those pieces.
Kent Cooper, AIA
@dani-perez wrote:
Could you help me with that?
In the offer-options-in-one-command approach [minimally tested]:
(defun C:DimReplace (/ parts txtss dimtype)
(command
"_.LAYER" "_make" "YourDimensionLayerName" "_color" YourDimensionLayerColor "" ""
"_.dimstyle" "_restore" "YourDimensionStyleName"
); command
(prompt "\nTo delete exploded-Dimension pieces for replacement with Dimension,")
(setq
parts (ssget "_:L" '((0 . "LINE,*TEXT,SOLID")))
txtss (ssget "_P" '((0 . "*TEXT")))
); setq
(if (> (sslength txtss) 1); more than 1 Text object in selection
(progn ; then
(command "_.txt2mtxt" txtss "")
(setq txtss (ssadd (entlast))); Mtext-converted object only
(ssadd (entlast) parts); put back in for Erasing later
); progn
); if
(setvar 'osmode 247); <--- EDIT for your preferred combination
(initget 1 "ALigned ANgular ARc Diameter Horizontal Linear Ordinate RAdius ROtated Vertical")
(setq dimtype (getkword "\nType of Dimension [ANgular/ARc/Diameter/Horizontal/Linear/Ordinate/RAdius/ROtated/Vertical]: "))
(command-s (strcat "_.dim" dimtype))
(vla-put-TextOverride
(vlax-ename->vla-object (entlast))
(vla-get-TextString (vlax-ename->vla-object (ssname txtss 0)))
); ...put...Override
(command "_.erase" parts "")
(princ)
)
I find that unlike some older versions, in Acad2019 the text piece left over from an Exploded Dimension is Mtext, not plain Text as assumed in the earlier routine -- hence the *TEXT in the (ssget) filter lists. But if it's multi-line, it's still one Mtext object, so it doesn't run up against the TXT2MTXT command not liking to be given Mtext.
I included Horizontal and Vertical options, because those commands are still accepted, even though Help doesn't include them in the Commands list. If you would always just use the Linear option in either case, you can shorten the (initget) string and the prompt by removing those two.
Same caveats as before [e.g. it assumes the Style exists and is at appropriate sizing].
Kent Cooper, AIA
Forums Links
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
