Lisp to Change Mtext Format

[hythamthelove]

Hello everyone,

I am looking for a lisp to change the format of the Mtext in white to the Mtext in blue, of course i am not talking about the colour but about the format itself. The green clouds shows the parts that are common between both of them and the red clouds shows the diffirences between the two formats. Btw the numbers and texts of the white Mtext can change but generaly the format will be the same for example T12 can be T16 or B can be T or @150 can be @Anonymous and so on but generally they will have the same format. Is there is a lisp that changes the format of the Mtext to white to match the one on blue and make the needed changes ?

Thanks in advance

[ronjonp]

Can you simply put those items on another layer that is blue?

[hythamthelove]

yes sure the color of the mtext is not a problem i will match them easily but the format it self is what i am asking about. Btw i am a huge fan of your work i see your replies to people you are really great and your replies to others helped me alot

[ronjonp]

Thanks for the kind words :). Can you post a sample drawing? If there is internal formatting on MTEXT, this causes other hurdles.

[hythamthelove]

To give you a wider vision, i actually have the orange text, but i can simply use the match order to make it match with the blue text, but just the formatting and the arrangement of the text is what i care about as explained in the post 

[ronjonp · Accepted solution]

Here's a quick one to help with the formatting:

(defun c:foo (/ a b o s st)
  (if (setq s (ssget "_:L" '((0 . "*TEXT") (1 . "*x*`@*"))))
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (setq st (vla-get-textstring (setq o (vlax-ename->vla-object e))))
      (setq a (substr st 1 (vl-string-position (ascii "x") st)))
      (setq b (substr st (1+ (vl-string-position (ascii "@") st))))
      (vla-put-textstring
	o
	(strcat a (substr b 1 (1- (strlen b))) " (" (substr b (strlen b)) ")\\PL= 6000mm")
      )
    )
  )
  (princ)
)

[hythamthelove · Accepted solution]

This is really great you are brilliant, but there is a case that does not work like the attached photo. because the number is not 1 digit ( it is 2.55 instead of 6 in the previous example) so it does not work. can you make changes so that the lisp takes any number between "x" and "@" and this number to be multiplied by 1000 and be put in the proper format ? i don't know if that is possible but you are really graeat and really i appreciate your efforts 

[ronjonp]

Use the code above again .. it just needed the mtext filter to be updated.

[hythamthelove]

ok i did, but it should give L=2550 (like the one i green) instead of L=6000 . i am really sorry for bothering you that much but i really appreciate your efforts.

[ronjonp · Accepted solution]

I gotcha ... try this:

(defun c:foo (/ a b c o s st)
  (if (setq s (ssget "_:L" '((0 . "*TEXT") (1 . "*x*`@*"))))
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (setq st (vla-get-textstring (setq o (vlax-ename->vla-object e))))
      (setq a (substr st 1 (setq c (vl-string-position (ascii "x") st))))
      (setq b (substr st (setq d (1+ (vl-string-position (ascii "@") st)))))
      (setq c (substr st (+ 2 c)))
      (if (numberp (setq c (read (substr c 1 (vl-string-position (ascii "@") c)))))
	(vla-put-textstring
	  o
	  (strcat a
		  (substr b 1 (1- (strlen b)))
		  " ("
		  (substr b (strlen b))
		  ")\\PL= "
		  (itoa (fix (* 1000 c)))
		  "mm"
	  )
	)
      )
    )
  )
  (princ)
)

[hythamthelove]

This is really brilliant. You are the best. Thank you so much 😍

[ronjonp]

---

@hythamthelove wrote:

This is really brilliant. You are the best. Thank you so much 😍

---

Glad to help. 🍻