Lisp For Automatic Change the Angle
If you don't have defined lengths of segments, I can not help. I've tried to make a lisp to use only your defined angles and lengths along a segment, but if you have to pick a point by mouse my method won't work. Try to play with polar tracking <F10>. Add your angles to additional angles list, and select polar tracking measurement relative to last segment.
My idea was to create set of xlines at the end of each segment when you pick point that is rotated relative to that segment. You would pick a point along a desired xline and provide a segment distance. At each next point previous xlines are erased. If that can help, I'll work when I catch some free time. Hopefully someone will come up with better solution.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@ishaq03 wrote:
.... But I am looking a command which automatically change the angles while I am Creating the polyline. I have a 11.25,22.5,45,&90 Angles for pipes in my project. ....
And 60. Any others? Should zero [continue in the same direction as the last section] be included? Presumably directions can bend in either direction? And the limited angles are not absolute angles but relative to the previous segment [amounts of bend], correct?
Describe what you imagine being the process. You call the command, and pick a starting point, and presumably a second point not limited in angle [since the end segments in the sample drawing are not at any of your specified angles], and --- then what happens? The rubber-band line for the next point pops to only those limited amounts of bend from the previous segment? Or do you answer a prompt for the angle of bend, as in @CADaSchtroumpf 's suggestion? When you pick another point, it uses the distance from the previous one, but locked in angle to the closest of the limited direction-change angles? Do you imagine the option to type in a distance rather than pick a point, as with ortho or polar mode in regular drawing? Something else I haven't thought of?
@ishaq03 Here is my code that don't require selection angles through keyboard entries.
After you create first segments, at each next point a fan of colored helping lines appears inclined to desired angles relative to previous polyline segment. To pick point at desired angle assure you have osnap mode NEAREST turned on.
You can either pick a point along desired inclined line or place a cursor over desired line so that symbol of nearest is active and enter distance to next point. To exit hit <enter>
(defun c:inc_pline ( / *error* adoc pt deg_to_rad make_helplines elist base_angles_list pa pb pe po ptlist coords)
;Author: hak_vz
;Monday, September 20, 2021
;https://forums.autodesk.com/t5/user/viewprofilepage/user-id/5530556
;Posted at
;https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/lisp-for-automatic-change-the-angle/td-p/10632287
;Creates lwpolyline with inclined angles 11.25 22.5 45 60 and 90 degree relative to previous segment
;Important: Assure you have osnap mode NEAREST turned on to enable drawing along helper line
(vl-load-com)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
(if elist (foreach e elist (entdel e)))
(setq elist nil)
(if (and adoc) (vla-endundomark adoc))
(setvar 'cmdecho 1)
(princ)
)
(defun deg_to_rad (deg)(* pi (/ deg 180.0)))
(defun take (amount lst / ret)(repeat amount (setq ret (cons (car lst) (take (1- amount) (cdr lst))))))
(defun make_helplines (p1 ptlist / clist i p2)
(setq clist '(1 3 5 6 30 1 3 5 6 30))
(if elist (foreach e elist (entdel e)))
(progn
(setq elist nil i -1)
(while (< (setq i (1+ i)) (length ptlist))
(setq p2 (nth i ptlist))
(setq elist
(cons
(entmakex
(list
(cons 0 "LINE")
(cons 100 "AcDbEntity")
(cons 100 "AcDbLine")
(cons 10 (trans p1 1 0))
(cons 11 (trans (polar p1 (angle p1 p2) 10000) 1 0))
(cons 62 (nth i clist))
)
)
elist
)
)
)
)
)
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
(vla-endundomark adoc)
(vla-startundomark adoc)
(setq base_angles_list (mapcar 'deg_to_rad '(11.25 22.5 45 60 90 -11.25 -22.5 -45 -60 -90)))
(princ "\nHave you tourned on osnap mode NEAREST? If not, turn it on and start again!")
(princ "\nTo exit function hit <enter>!")
(setq pa (getpoint "\nFirst point of polyline: "))
(setq pb (getpoint pa "\nNext point of polyline: "))
(setvar 'cmdecho 0)
(command "_.pline" pa pb "")
(setq pe (entlast) po (vlax-ename->vla-object pe))
(setq coords (append (take 2 pa) (take 2 pb)))
(setq ptlist nil)
(foreach e base_angles_list (setq ptlist (cons (polar pb (- (angle pa pb) e) 10) ptlist)))
(make_helplines pb ptlist)
(setq ptlist nil)
(while (setq pt (getpoint "\nNext point >"))
(setq pa pb pb pt)
(foreach e base_angles_list (setq ptlist (cons (polar pb (- (angle pa pb) e) 10) ptlist)))
(make_helplines pb ptlist)
(setq ptlist nil)
(command "_.pline" pa pb "")
(setq coords (append coords (take 2 pb)))
(vlax-put po 'Coordinates coords)
(entdel (entlast))
)
(if elist (foreach e elist (entdel e)))
(setq elist nil)
(vla-endundomark adoc)
(setvar 'cmdecho 1)
(princ "\nDone!")
(princ)
)Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
You exeute the programe ":minidump\asm_jc_lda18.lsp" with
You select "1" at install_fedora(1.yes)(0.no)"
You appload the "pp_cadaschtroumpf_makepline_.lsp"
You enter the command C:q2[enter]
Thanks, your command is working fine, but I would like to ask, can we add the vertical bend angles, meaning above and below, of 11.25, 22.5, 45, 60, and 90 degree For your understanding, I am attaching the sample photo on the bottom.
@ishaq.syed7CX2A wrote:
Thanks, your command is working fine, but I would like to ask, can we add the vertical bend angles, meaning above and below, of 11.25, 22.5, 45, 60, and 90 degree.
You can add any angle you want by simply changing angles in list:
(setq base_angles_list (mapcar 'deg_to_rad '(11.25 22.5 45 60 90 -11.25 -22.5 -45 -60 -90)))
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
👉Is it possible to update or enhance this command so that it supports different horizontal and vertical scales?
For example, as shown in the attached screenshot, I want the horizontal scale to remain 1:1000 and the vertical scale to be 1:10. This would allow vertical exaggeration to be applied directly while drafting, similar to how we view profiles in Civil 3D.
This adjustment would make the command more practical for profile drafting and design workflows.
Thank you in advance for your guidance! I attached the lisp previously provided by @hak_vz .
