LISP Advice

[mjshaffer117]

(defun c:divline ( / pt1 pt2 div ang maths ent)
  (setq pt1 (getpoint "Select first point: "))
  (setq pt2 (getpoint "Select end point: "))
  (setq div (getint "Enter number of segments to divide line: "))
  (setq ang (angle pt1 pt2))
  (entmake (list
	     '(0 . "LINE")
	     '(8 . "0")
	     (cons 10 (polar pt1 (angle pt1 pt2) 0))
	     (cons 11 (polar pt2 (angle pt1 pt2) 0))
	     )
	   )
  (setq maths (/ (distance pt1 pt2) div))
  (entmake (list
	     '(0 . "LINE")
	     '(8 . "CX-TEXT")
	     (cons 10 (polar pt1 (+ ang (/ pi 2)) 0.25))
	     (cons 11 (polar pt1 (- ang (/ pi 2)) 0.25))
	     )
	   )
  (repeat div
    (setq ent (entlast))
    (command "._offset" maths ent pt2 "")
    )
(princ)
  )

Hello all!

I'm still learning LISP and I'm looking to try and take more advance approaches on my writing. The attached code works fine, but I'm curious to see if there is a more logical approach that I may not be thinking of. Any advice on how I can write more logically or any outside of the box approaches using different functions would be great! Looking forward to continuously improving!

Thanks in advance! 😁

[Kent1Cooper · Accepted solution]

I suggest you go to the >Customization Forum< where AutoLisp is the lingua franca.

[ВeekeeCZ · Accepted solution]

Check the user input. Can the code handle if div is zero, neg or nil without crash?

(defun c:divline ( / pt1 pt2 div ang maths ent)
  
  (if (and (setq pt1 (getpoint "Select first point: "))
	   (setq pt2 (getpoint "Select end point: "))
	   (or (not (equal pt1 pt2))
	       (prompt "Error: Wrong input. Points can't be equal."))
	   (not (initget (+ 1 2 3)))
	   (setq div (getint "Enter number of segments to divide line: "))
	   )
    (progn
      (setq ang (angle pt1 pt2))
      (entmake (list
		 '(0 . "LINE")
		 '(8 . "0")
		 (cons 10 (polar pt1 (angle pt1 pt2) 0))
		 (cons 11 (polar pt2 (angle pt1 pt2) 0))
		 )
	       )
      (setq maths (/ (distance pt1 pt2) div))
      (entmake (list
		 '(0 . "LINE")
		 '(8 . "CX-TEXT")
		 (cons 10 (polar pt1 (+ ang (/ pi 2)) 0.25))
		 (cons 11 (polar pt1 (- ang (/ pi 2)) 0.25))
		 )
	       )
      (repeat div
	(setq ent (entlast))
	(command "._offset" maths ent "_non" pt2 "") ; make sure that OSNAPS are OFF when you supply a point within the commmand func.
	)
      ))
  (princ)
  )

[CodeDing]

@mjshaffer117 ,

How do you feel about (command ...) calls? Lol

(defun c:DIVLINE ( / )
  (command "_.LINE" pause pause "")
  (command "_.DIVIDE" (entlast) pause)
  (princ)
);defun

Best,

~DD

[pbejse · Accepted solution]

---

@mjshaffer117 wrote:

I'm still learning LISP..

Good for you.

Here's another

(defun c:divline ( / pt1 pt2 _line div ang maths )
(defun _line (p1 p2 lay)
  (entmake (list
	     (cons 0 "LINE") (cons 8  lay )
	     (cons 10 p1) (cons 11 p2)
	     		)
		)	   
	)
(initget 6)  
(if
  (and
        (setq div (getint "Enter number of segments to divide line: "))
  	(setq pt1 (getpoint "Select first point: "))
  	(setq pt2 (getpoint pt1 "Select end point: "))	  	
	)
	(progn
  		(setq ang (angle pt1 pt2))
	        (setq maths (/ (distance pt1 pt2) div))	  	
	        (_line pt1 pt2 "0")
	  	(setq pt1 (polar pt1 (+ ang (/ pi 2)) 0.25))
	        (setq pt2 (polar pt1 (- ang (/ pi 2)) 0.50))
	  	(repeat (1+ div)
		  (_line pt1 pt2 "CX-TEXT")
		  (setq pt1 (polar pt1 ang maths))
		  (setq pt2 (polar pt2 ang maths))
		 )
	  )
	  (princ (strcat "\nInvalid or null"
	    (cond
	      ((null div) " number of segments")
	      ((or (null pt1)(null pt2)) " point value")
	      		)
		)	    
	  )
  )
(princ)
  )

You may also want to ask for the length of the divider.

[john.uhden · Accepted solution]

Along with the required improvements that @ВeekeeCZ and @pbejse showed you, rather than

(if
  (and ...)
  (progn ...)
)

the long (and ...), as taught to me by Stephan Koster, might condense the code...

(and
  (setq ...)
  (setq ...)
  (entmakex ...)
  (not (initget ...))
  ;; etc.
)

It works because AutoCAD will continue evaluating each expression until one returns nil, then it stops evaluating what's inside the (and).

[ВeekeeCZ]

I've missed this one.... what's the logic of these again?

		 (cons 10 (polar pt1 (angle pt1 pt2) 0))
		 (cons 11 (polar pt2 (angle pt1 pt2) 0))

Which reminds me... consider that (getpoint) returns coordinates in UCS while (entmake) needs coords in WCS.

[Kent1Cooper]

---

@ВeekeeCZ wrote:

....
	   (not (initget (+ 1 2 3)))
....

---

That should be:

  (not (initget (+ 1 2 4)))

[The 1 prevents the User from pressing Enter, the 2 forbids zero, the 4 forbids negative input.]

[john.uhden]

It appears to be an exercise to be sure that pt1 is exactly at pt1 and that
pt2 is exactly at pt2. Sorta like (setq T (not nil)).☺
Then again there may be a difference for large values of 0.😂

[Kent1Cooper]

---

@CodeDing wrote:

....

(defun c:DIVLINE ( / )
  (command "_.LINE" pause pause "")
  (command "_.DIVIDE" (entlast) pause)
  (princ)
);defun

....

---

That would put POINT objects along the Line, rather than the perpendicular LINE markers they apparently want [I haven't tried it].  And it would not put them at the ends as they apparently want.

[CodeDing]

@Kent1Cooper ,

Ahhhh, yes I was zoomed out VERY far hahah, I assumed they were 0 length lines. Didn't look into it as far as I should have. Shame

Thanks

[Sea-Haven]

Ucs ob line, array perp line ?? Not sure how much code saved. Just a different way to do it.

[mjshaffer117]

Sorry for the late reply! Thanks all for the advice and feedback! This was more of a practice kind of thing to get better with LISP.

@ВeekeeCZ & @john.uhden I tend to forget having error handlers in stuff like this, thanks for the reminder! I'll be sure to be more mindful when writing my future routines!

@pbejse I appreciate the route using a function within a function! Definitely would like to get more familiar with implementing that as much as possible since it's a frequent thing! Seems like the next step for me!