Line length round up to nearest 100

[arvhee24]

Is there a LISP to round up the length of line to nearest 100?

it will be lengthen/shorten from both sides, starting from midpoint.

Thanks in advance 🙂

[ВeekeeCZ · Accepted solution]

Easy enough to write it quickly...

(defun c:LineLengthenTo100 ( / i ss ed p1 p2 pm ds)

  (if (setq ss (ssget "_:L" '((0 . "LINE"))))
    (repeat (setq i (sslength ss))
      (setq ed (entget (ssname ss (setq i (1- i))))
            p1 (cdr (assoc 10 ed))
            p2 (cdr (assoc 11 ed))
            pm (mapcar '(lambda (a b) (/ (+ a b) 2.)) p1 p2)
            ds (* 50. (atoi (rtos (/ (distance p1 p2) 100.) 2 0))))
      (entmod (append ed
                      (list (cons 10 (polar pm (angle p2 p1) ds))
                            (cons 11 (polar pm (angle p1 p2) ds)))))))
  (princ)
)

[arvhee24]

Wow that was fast...

Thanks so much BeekeeCZ.

Appreciate it.. Cheers!

🙂

[ВeekeeCZ]

Actually did you meant round UP to 100... or round to 100... ??

[arvhee24]

I meant round off to 100. 🙂

But what I really need is to be rounded to 500 so i change the values of 50. to 250 and the 100 to 500 and fortunately, it works!

[ВeekeeCZ]

OK then, glad to help!
Cheers!

[arvhee24]

BeekeeCZ, if supposed i need it to round up to 500?

I mean if it is 1 then the result will be 500, and 501 will 1000...

I tried to edit it but, i had a very little, almost none, knowledge on writing LISP.

If you get the time, can you modify it?

I can use the first one though, but this will be better if ever.

Sorry, and thanks.

Cheers!

[ВeekeeCZ · Accepted solution]

---

@arvhee24 wrote:

BeekeeCZ, if supposed i need it to round up to 500?

I mean if it is 1 then the result will be 500, and 501 will 1000...

... 

---

Sure, no trouble, I have the code ready to ship out since the morning. 🙂

(defun c:LineLengthenUp500 ( / i ss ed p1 p2 pm ds)

  (if (setq ss (ssget "_:L" '((0 . "LINE"))))
    (repeat (setq i (sslength ss))
      (setq ed (entget (ssname ss (setq i (1- i))))
            p1 (cdr (assoc 10 ed))
            p2 (cdr (assoc 11 ed))
            pm (mapcar '(lambda (a b) (/ (+ a b) 2.)) p1 p2)
            ds (* (1+ (fix (/ (distance p1 p2) 500.))) 250.))
      (entmod (append ed
                      (list (cons 10 (polar pm (angle p2 p1) ds))
                            (cons 11 (polar pm (angle p1 p2) ds)))))))
  (princ)
)

[arvhee24]

Nice!

Thank you so much BeekeeCZ, or is it Děkuji mnohokrát (google translate lol)

Cheers mate!

This is very useful to me.

[ВeekeeCZ]

You're welcome!

Skoro jsem uronil slzu jak mě to dojalo! 😉

[arvhee24]

Hahaha!

Thanks!

[john.uhden]

That's the first time I have ever seen the use of the decimal character only to define a real.  Just think of all the key strokes I have squandered through the years.  

[ВeekeeCZ]

One more version of rounding up function. This one is little more sophisticated, written by Lee Mac, see HERE.

This time lines does not grow to heaven if you apply the function multiple times. 

(defun c:LineLengthenUp500 ( / LM:roundup i ss ed p1 p2 pm ds)

  (defun LM:roundup (n m) ; Lee Mac
    ((lambda (r) (cond ((equal 0.0 r 1e-8) n) ((< n 0) (- n r)) ((+ n (- m r))))) (rem n m)))
  
  (if (setq ss (ssget "_:L" '((0 . "LINE"))))
    (repeat (setq i (sslength ss))
      (setq ed (entget (ssname ss (setq i (1- i))))
            p1 (cdr (assoc 10 ed))
            p2 (cdr (assoc 11 ed))
            pm (mapcar '(lambda (a b) (/ (+ a b) 2.)) p1 p2)
            ds (/ (LM:roundup (distance p1 p2) 500) 2.))
      (entmod (append ed
                      (list (cons 10 (polar pm (angle p2 p1) ds))
                            (cons 11 (polar pm (angle p1 p2) ds)))))))
  (princ)
)

[Kent1Cooper]

---

@john.uhden wrote:

That's the first time I have ever seen the use of the decimal character only to define a real.  Just think of all the key strokes I have squandered through the years.

---

You could save even more!  None of those decimals are actually needed in Posts 2 & 8.  The only time they might be necessary is in divisions, and you get an undesired integer result from a division that doesn't divide exactly only if both  numbers involved are integers.  If either  is a real, the result won't be rounded unnecessarily, so you're covered.  All divisions in those routines involve values that will always  be real numbers already [point coordinates in the 'pm' variable, and the result of a (distance) function in the 'ds' variable], without the need to make those other numbers into reals.

[john.uhden]

Thank you, Kent.

I may be a pea-brain, as Tony T. called me once, but I'm not that dumb.

I wish I could find that thread.  It was really pretty humorous.

BTW, that should be "None of those decimals IS..." since none is singular (not one).

[Anonymous]

where do I need to write this code in AutoCAD, so it will run?

[ВeekeeCZ]

---

@Anonymous wrote:

where do I need to write this code in AutoCAD, so it will run?

---

HERE is short tutorial on how to use LISP.