Layer Change ( only Text )

[k005]

Hello guys;

I want to change the layer named DOOR-WINDOW. But only text objects should be processed.

sample:

KAPI-PENCERE -----> Kapi-Ebat....bylayer...bylayer...bylayer
Color: 7

When I select the text object with the window, it performs the operation. Thanks in advance to the helper.

[ВeekeeCZ]

You start... 

[pendean]

How about -LAYER command as explained in HELP https://knowledge.autodesk.com/support/autocad/learn-explore/caas/CloudHelp/cloudhelp/2021/ENU/AutoC...

[Kent1Cooper]

---

@k005 wrote:

....

I want to change the layer named DOOR-WINDOW. But only text objects should be processed.

sample:

KAPI-PENCERE -----> Kapi-Ebat....bylayer...bylayer...bylayer
Color: 7

When I select the text object with the window, it performs the operation. Thanks in advance to the helper.

---

Do you want to change the Layer itself [your first phrase] or Text object(s)?  Do you want to move Text objects on that Layer into a different Layer ["change the layer" meaning change the layer of the Text, not the layer itself]?  Or do you only want to change their color?

KAPI-PENCERE means DOOR-WINDOW in English, so I assume that's the Layer name.  What is Kapi-Ebat [which means Door-Size] for?  Is that the text content of a Text object?  Do you want only Text with that content changed, or all Text on that Layer?

Etc.

[k005]

I already started... 🙂

[k005]

Thanks

[k005]

I'm adding a sample dwg right away... wait a minute..

-- added

[hak_vz]

(defun c:foo (/ ss)
	(setq ss (ssget '((0 . "TEXT")(8 . "KAPI-PENCERE"))))
	(cond 
		((and ss)
			(command "_.chprop" ss "" "LA" "Kapi-Ebat" "")
		)
	)
	(princ)
)

Sorry @k005  but you should be able to write this simple scripts by yourself. Creating selection set with filtering and applying  command function upon selected entities are the basics that any CAD user should know.

[k005]

@hak_vz 

This code was partially... But not complete..

The reason : Lisp code crashes if there is no Kapi-Ebat layer... Otherwise it should create it.

Thank you.

[hak_vz]

---

@k005 wrote:

@hak_vz 

This code was partially... But not complete..

The reason : Lisp code crashes if there is no Kapi-Ebat layer... Otherwise it should create it.

---

True. But you should be able to add a line of code that would test if layer exist, and create if it not. Add command line for "-layer" command with option make. Check other consequences of running this command. Attach your code. 

[ronjonp · Accepted solution]

Give this a try:

(defun c:foo (/ s)
  (if (setq s (ssget ":L" '((0 . "TEXT") (8 . "KAPI-PENCERE"))))
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (entmod (append (entget e) '((8 . "Kapi-Ebat"))))
    )
  )
  (princ)
)

[Kent1Cooper]

---

@ronjonp wrote:

....

....
      (entmod (append (entget e) '((8 . "Kapi-Ebat"))))
....

---

Advantage of appending the Layer name to the object's entity data:  It doesn't matter whether the Layer exists -- it will make it if it doesn't [with default color 7 and continuous linetype].

Advantage of CHPROP-command approach:  It can change the Layer of all of the selection at once -- no need to step through the selection set one object at a time.  But the Layer needs to exist.

[k005]

Like okay. Since we are working in different dwgs, I will either enter the name of the layer to be searched from the keyboard or select the relevant (in the layer to be searched) text.

[k005]

(defun c:fo1 (/ s lan)
(setq lan (cdr (assoc 8 (entget(car(entsel))))))
 (princ "\nKatman : ")
  (princ lan)
  (if (setq s (ssget "L:" '((0 . "TEXT") (8 . lan))))
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (entmod (append (entget e) '((8 . "Kapi-Ebat")(62 . 7))))
      
    )
  )
  (princ)
)

I get this error

error: bad SSGET list value

[Kent1Cooper]

---

@k005 wrote:

....
  (if (setq s (ssget "L:" '((0 . "TEXT") (8 . lan))))
....

I get this error

error: bad SSGET list value

---

You have the colon after the L.  Put it before.

[ronjonp · Accepted solution]

---

@k005 wrote:

(defun c:fo1 (/ s lan)
(setq lan (cdr (assoc 8 (entget(car(entsel))))))
 (princ "\nKatman : ")
  (princ lan)
  (if (setq s (ssget "L:" '((0 . "TEXT") (8 . lan))))
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (entmod (append (entget e) '((8 . "Kapi-Ebat")(62 . 7))))
      
    )
  )
  (princ)
)

I get this error

error: bad SSGET list value

---

Comments in the code below:

(defun c:fo1 (/ s lan)
  ;; RJP selection check .. entget throws an error on a nil value
  (if (and (setq lan (car (entsel)))
	   (setq lan (cdr (assoc 8 (entget lan))))
      )
    (progn (princ "\nKatman : ")
	   (princ lan)
      ;; RJP reformatted ssget call .. please study the differences
	   (if (setq s (ssget ":L" (list '(0 . "TEXT") (cons 8 lan))))
	     ;;(setq s (ssget "L:" '((0 . "TEXT") (8 . lan))))
	     (foreach e	(vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
	       (entmod (append (entget e) '((8 . "Kapi-Ebat") (62 . 7))))
	     )
	   )
    )
  )
  (princ)
)

[k005]

It was very nice. Thank you. 🤗

[ronjonp]

---

@k005 wrote:

It was very nice. Thank you.

---

You're welcome.

[k005]

Is it possible to add a name to it?

(setq istenen (getstring t "\nLayer adı giriniz : "))
...


...

(entmod (append (entget e) '((8 . istenen) (62 . 7))))

..?

[ronjonp · Accepted solution]

;; Change this
(entmod (append (entget e) '((8 . istenen) (62 . 7))))
;; To this
(entmod (append (entget e) (list (cons 8 istenen) '(62 . 7))))