Is it possible to select elements within polyline or polygon in AutoCAD?
Do a little Searching. There are multiple topics in this Forum, and maybe also in the basic AutoCAD Forum, about just this subject.
(defun c:sip( / e eo take drop_first_n points2d nthcdr coords)
(defun take (amount lst / ret) (repeat amount (setq ret (cons (car lst) (take (1- amount) (cdr lst))))))
(defun drop_first_n (n alist) (nthcdr n alist))
(defun points2d (lst / ret) (while lst (setq ret (cons (take 2 lst) ret) lst (drop_first_n 2 lst))) (reverse ret))
(defun nthcdr (arg lst / ret) (setq ret lst) (if (> arg 0)(repeat arg (setq ret (cdr ret)))))
(setq e (car (entsel "\nSelect selection set bounding polyline >")))
(cond
((and e)
(setq eo (vlax-ename->vla-object e))
(cond
((= (vlax-get eo 'ObjectName) "AcDbPolyline")
(setq coords (points2d (vlax-get eo 'Coordinates)))
(setq ss (ssget "_wp" coords))
(cond
((and coords)
(sssetfirst nil (ssget "_wp" coords))
)
)
)
)
)
)
(princ)
)Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Just be aware of the potential for incorrect results if the Polyline contains any arc segments. Depending on the configuration, the routines here so far could see some things that are not within the Polyline, and/or miss some that are within it, because the Window-Polygon that it builds goes straight between all vertices. The results of Searching will contain some topics in which there is some accounting for the possibility.
Selected object are stored to global variable ss, so you can use them when needed (if not overwritten or erased).
command : Move
!ss
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@BriamR wrote:
....
It would be great if there was a routine that could do the same but in addition to this that would select only the desired layers.
You can add a Layer filter in the (ssget) function, with multiple Layer names comma-separated, for example in @hak_vz 's suggestion:
....
(setq ss (ssget "_wp" coords '((8 . "Your,Desired,Layer,Names"))))
....
@BriamR wrote:
@Kent1Cooper Apparently I am doing something wrong since it does not select the specific layer that I include in the lines in this case "SEN_BASE_DEM".
Note: The selection of the layer can be variable? that is, when you run the lisp it asks which layers it should select within the polyline. @hak_vz
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@hak_vz wrote:
@BriamR wrote:
@Kent1Cooper Apparently I am doing something wrong since it does not select the specific layer that I include in the lines in this case "SEN_BASE_DEM".
This select all entities inside bounding polyline in layer SEN_BASE_DEM
(defun c:sips( / e eo take drop_first_n points2d nthcdr coords)
(defun take (amount lst / ret) (repeat amount (setq ret (cons (car lst) (take (1- amount) (cdr lst))))))
(defun drop_first_n (n alist) (nthcdr n alist))
(defun points2d (lst / ret) (while lst (setq ret (cons (take 2 lst) ret) lst (drop_first_n 2 lst))) (reverse ret))
(defun nthcdr (arg lst / ret) (setq ret lst) (if (> arg 0)(repeat arg (setq ret (cdr ret)))))
(setq e (car (entsel "\nSelect selection set bounding polyline >")))
(cond
((and e)
(setq eo (vlax-ename->vla-object e))
(cond
((= (vlax-get eo 'ObjectName) "AcDbPolyline")
(setq coords (points2d (vlax-get eo 'Coordinates)))
(setq ss (ssget "_wp" coords '((8 . "SEN_BASE_DEM"))))
(cond
((and coords)
(sssetfirst nil (ssget "_wp" coords '((8 . "SEN_BASE_DEM"))))
)
)
)
)
)
)
(princ)
)
This version enables to select one or more layer so be included in creating selection set
(defun c:sipp( / e eo take drop_first_n points2d nthcdr coords collectLayerObjects getlayernames laylist LM:listbox LM:lst->str)
(defun take (amount lst / ret) (repeat amount (setq ret (cons (car lst) (take (1- amount) (cdr lst))))))
(defun drop_first_n (n alist) (nthcdr n alist))
(defun points2d (lst / ret) (while lst (setq ret (cons (take 2 lst) ret) lst (drop_first_n 2 lst))) (reverse ret))
(defun nthcdr (arg lst / ret) (setq ret lst) (if (> arg 0)(repeat arg (setq ret (cdr ret)))))
(defun collectLayerObjects ( / ret) (reverse (vlax-for lay (vlax-get (vla-get-activedocument (vlax-get-acad-object)) 'Layers) (setq ret (cons (cons (vlax-get lay 'Name) lay)ret)))))
(defun getlayernames nil (mapcar 'car (collectLayerObjects)))
;; List Box - Lee Mac
;; Displays a DCL list box allowing the user to make a selection from the supplied data.
;; msg - [str] Dialog label
;; lst - [lst] List of strings to display
;; bit - [int] 1=allow multiple; 2=return indexes
;; Returns: [lst] List of selected items/indexes, else nil
(defun LM:listbox ( msg lst bit / dch des tmp rtn )
(cond
( (not
(and
(setq tmp (vl-filename-mktemp nil nil ".dcl"))
(setq des (open tmp "w"))
(write-line
(strcat "listbox:dialog{label=\"" msg "\";spacer;:list_box{key=\"list\";multiple_select="
(if (= 1 (logand 1 bit)) "true" "false") ";width=50;height=15;}spacer;ok_cancel;}"
)
des
)
(not (close des))
(< 0 (setq dch (load_dialog tmp)))
(new_dialog "listbox" dch)
)
)
(prompt "\nError Loading List Box Dialog.")
)
( t
(start_list "list")
(foreach itm lst (add_list itm))
(end_list)
(setq rtn (set_tile "list" "0"))
(action_tile "list" "(setq rtn $value)")
(setq rtn
(if (= 1 (start_dialog))
(if (= 2 (logand 2 bit))
(read (strcat "(" rtn ")"))
(mapcar '(lambda ( x ) (nth x lst)) (read (strcat "(" rtn ")")))
)
)
)
)
)
(if (< 0 dch)
(unload_dialog dch)
)
(if (and tmp (setq tmp (findfile tmp)))
(vl-file-delete tmp)
)
rtn
)
;; List to String - Lee Mac
;; Concatenates each string in a supplied list, separated by a given delimiter
;; lst - [lst] List of strings to concatenate
;; del - [str] Delimiter string to separate each item
(defun LM:lst->str ( lst del )
(if (cdr lst)
(strcat (car lst) del (LM:lst->str (cdr lst) del))
(car lst)
)
)
(setq e (car (entsel "\nSelect selection set bounding polyline >")))
(setq laylist (LM:lst->str (LM:listbox "Select one or more layers to include in selection" (getlayernames) 1) ","))
(cond
((and e)
(setq eo (vlax-ename->vla-object e))
(cond
((= (vlax-get eo 'ObjectName) "AcDbPolyline")
(setq coords (points2d (vlax-get eo 'Coordinates)))
(setq ss (ssget "_wp" coords (list (cons 8 laylist))))
(cond
((and coords)
(sssetfirst nil (setq ss (ssget "_wp" coords (list (cons 8 laylist)))))
)
)
)
)
)
)
(princ)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@BriamR wrote:
.... Apparently I am doing something wrong since it does not select the specific layer that I include in the lines in this case "SEN_BASE_DEM".
Note: The selection of the layer can be variable? that is, when you run the lisp it asks which layers it should select within the polyline.
Assuming you've double-checked spelling and that isn't the issue, show us how you incorporated the Layer name. For example, did you perhaps lose the space on one side or the other of the period [it needs both]?
For variable ones, you would need something to ask the User earlier, for example:
(setq laynames (getstring "\nLayer name(s) to select, comma-separated if multiple: "))
and then in the routine, the "quoted" list with the apostrophe prefix and the dotted-pair of 8 with names can't be used, but you need the explicit (list) and (cons) functions:
(setq ss (ssget "_wp" coords (list (cons 8 laynames))))
Try to replace "_wp" with "_cp" switch in my function . I guess it will work correctly. I'll test it tomorrow to see if it works.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
