i need lisp to get( point) center of lines or Polylines

[Mohamed32Samy]

plz help me
i need lisp or solution to get points of (center) lines or polyliens 

plz check attache file

[komondormrex · Accepted solution]

check this.

(defun c:point_middle_line nil
	(foreach line_object (mapcar 'vlax-ename->vla-object (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "line")))))))
		(vla-addpoint (vla-get-block (vla-get-activelayout (vla-get-activedocument (vlax-get-acad-object)))) 
					  (vlax-3d-point (polar (vlax-get line_object 'startpoint)
									 		(angle (vlax-get line_object 'startpoint) (vlax-get line_object 'endpoint))
									 		(* 0.5 (distance (vlax-get line_object 'startpoint) (vlax-get line_object 'endpoint)))
									 )
					  )
		)
	)
)

[Mohamed32Samy]

thanx alot

really great lisp

[Kent1Cooper · Accepted solution]

(defun C:PLM (/ ss n lin); = Points at Line Midpoints
  (if (setq ss (ssget '((0 . "LINE"))))
    (repeat (setq n (sslength ss))
      (setq lin (ssname ss (setq n (1- n))))
      (command "_.point" "_non"
        (mapcar '/
          (mapcar '+ (vlax-curve-getStartPoint lin) (vlax-curve-getEndPoint lin))
          '(2 2 2)
        ); mapcar
      ); command
    ); repeat
  ); if
  (prin1)
)

[Mohamed32Samy]

you made my day

another great lisp
thx