How to find mleader styles

[Anonymous]

In a drawing, how can i get a list of available mleader styles or see if a particular style is available?  

[dbroad]

This is code from the autodesk knowledge network that should give you all the start you need.  All you need to revise is from the foreach to an assoc.  You could find it here

https://knowledge.autodesk.com/search-result/caas/CloudHelp/cloudhelp/2016/ENU/AutoCAD-AutoLISP/file...

or just google autocad list dictionary entries

(defun c:ListDictionaries ( / ed ed1)
  (prompt "\nDictionaries in current drawing: ")
  (foreach ed (entget (namedobjdict))
    (progn
      (cond ((= (car ed) 3)
        (prompt (strcat "\n" (cdr ed))))
            ((= (car ed) 350)
        (progn
          (foreach ed1 (entget (cdr ed))
            (if (= (car ed1) 3)
              (prompt (strcat "\n  " (cdr ed1)))
            )
          )
        ))
      )
    )
  )
 (princ)
)

[Anonymous · Accepted solution]

(setq Acad_Obj (vla-get-activedocument (vlax-get-acad-object)))
(setq MLeader_Dict (vla-item (vla-get-dictionaries Acad_Obj) "ACAD_MLEADERSTYLE"))
(vlax-for Item MLeader_Dict
(princ "\nMleaderStyle = ")
(princ (vlax-get-property Item 'Name))
)

[Anonymous]

Great this is what i was looking for! 😃

[cschnarr]

@Anonymous 

I found this discussion today. I am trying to make a list of all the non-annotative Multileader styles in the current drawing, to feed the list to a list box for a user selection. Your code makes a list, and prints the list. I want to store the list in a variable, but exclude any annotative Multileader Styles. Do you have any suggestion how to generate this list for use in my code?

[Sea-Haven]

Have a look at this test code and in particular the Annotative property. Should give you the answer you seek.

(setq MLeader_Dict (vla-item (vla-get-dictionaries (vla-get-activedocument (vlax-get-acad-object))) "ACAD_MLEADERSTYLE"))
(vlax-for Item MLeader_Dict
(VLAX-DUMP-OBJECT ITEM)
)

[ronjonp]

Try this:

(vlax-for i (vla-item (vla-get-dictionaries (vla-get-activedocument (vlax-get-acad-object)))
		      "ACAD_MLEADERSTYLE"
	    )
  (if (= 0 (vlax-get i 'annotative))
    (setq r (cons (vla-get-name i) r))
  )
)

[cschnarr]

@ronjonp 

What is the name of the list created? "i" ?

[ronjonp]

---

@cschnarr wrote:

@ronjonp 

What is the name of the list created? "i" ?

---

'r' is the list created.

[cschnarr]

@ronjonp 

Got it working as desired now. Thank you for your insights!

[ronjonp]

---

@cschnarr wrote:

@ronjonp 

Got it working as desired now. Thank you for your insights!

---

Glad to help 🍻