Grab multiple pieces of text - numbers and add together
Use "find" command and delete the ' mark, then delete the comma thousands mark.
Use the add autolisp posted all over the internet then you can get the total.
I wouldn't alter the Text objects in the drawing in order to add them up, as suggested in Message 4. You can leave them alone [other than to select them], if you build the proper alteration into the code for a routine. If you pull the text string content from such a Text object in a selection set, you can apply this to it to make it usable in an addition:
(atof (vl-string-right-trim "'" (vl-string-subst "" "," "12,345.67'")))
which returns the number that can be put into a list for addition, or just added to an accumulating total:
12345.7
[Of course that would use a variable that the text string content is put in, not the specific value above. And don't worry about the .67 vs. .7 -- it actually knows it's .67, and the .7 is just in display.]
A routine could be made to restrict your selection to Text objects that end with a foot mark, or with a decimal point plus two numerical characters plus a foot mark, etc, depending on whether such characteristic vary and how responsible you want to be to select the right kinds of things. It could even find all qualifying objects for you, without User selection, if you can rely on them to all have the right characteristics, and on there being no qualifying other objects that you don't want selected.
@zach6CTLG Try this
Edited to work with text and mtext string number. I've overseen that you are having mtext objects.
(defun c:add_dist(/ *error* ss i sum LM:StringSubst)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
(princ)
)
(defun LM:StringSubst ( new old str / inc len )
(setq len (strlen new)
inc 0
)
(while (setq inc (vl-string-search old str inc))
(setq str (vl-string-subst new old str inc)
inc (+ inc len)
)
)
str
)
(setq ss (ssget '((0 . "*TEXT"))) i -1 sum 0)
(cond
((and ss (> (sslength ss) 0))
(while (< (setq i (1+ i)) (sslength ss))
(setq sum (+ sum (atof (LM:StringSubst "" ","(cdr (assoc 1 (entget(ssname ss i))))))))
)
(princ (strcat "\nSum of selected distance is = " (rtos sum 2 5)))
)
(T (princ "\nNothing selected!"))
)
(princ)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@Kent1Cooper wrote:
....
A routine could be made to restrict your selection to Text objects that end with ... a decimal point plus two numerical characters plus a foot mark....
For that particular restriction, if they're always in that format, for example:
(defun C:AddFeetText (/ ss n)
(if (setq total 0 ss (ssget '((1 . "*.##'")))); only in feet to two decimal places
(repeat (setq n (sslength ss)); then
(setq total
(+
total
(atof (vl-string-right-trim "'" (vl-string-subst "" "," (cdr (assoc 1 (entget (ssname ss (setq n (1- n)))))))))
); +
); setq
); repeat
); if
(prompt (strcat "\nTotal: " (rtos total 2 2) "'."))
(prin1)
)
That leaves the numerical total [not the text-string equivalent] in the 'total' variable, to do with what you will. It could be made to re-insert a comma into the text string if appropriate. Which raises the question -- would you ever get into millions? That is, would there ever be more than one comma? [It doesn't seem likely -- a million feet is around 189 miles.]
It works with Mtext as well as Text, provided the Mtext is in a separate one for each distance, and they don't have internal formatting.
In this particular case, I do need to edit the text!
When I paste these values over to the right from my template, I don't need that symbol. Below this there is a "total feet" value, and that is why I was trying to delete all the ' symbols and add up at the same time.
@zach6CTLG wrote:
This works for the addition! Thanks mate. Now if I could only get the ' symbol deleted for all the selected texts??
Like this?
(defun c:add_dist(/ *error* ss i sum LM:StringSubst ent)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
(princ)
)
(defun LM:StringSubst ( new old str / inc len )
(setq len (strlen new)
inc 0
)
(while (setq inc (vl-string-search old str inc))
(setq str (vl-string-subst new old str inc)
inc (+ inc len)
)
)
str
)
(setq ss (ssget '((0 . "*TEXT"))) i -1 sum 0)
(cond
((and ss (> (sslength ss) 0))
(while (< (setq i (1+ i)) (sslength ss))
(setq ent (entget(ssname ss i)))
(setq sum (+ sum (atof (LM:StringSubst "" ","(cdr (assoc 1 ent))))))
(setq ent(subst (cons 1 (LM:StringSubst "" "'"(cdr (assoc 1 (entget(ssname ss i)))))) (assoc 1 ent) ent))
(entmod ent)
)
(princ (strcat "\nSum of selected distance is = " (rtos sum 2 5)))
)
(T (princ "\nNothing selected!"))
)
(princ)
)Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@zach6CTLG wrote:
This nailed it. Thank you!
You're welcome!
Next time attach sample dwg with your initial request and try to summarize all your wishes.
That helps us to speed up writing requested lisp script.
Bye!
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
.... and my ADDFEETTEXT reports the total of 1191.32' from the sample drawing's chart. You can use it for content in another Text object, or whatever.
Regards @zach6CTLG
Try this code, ..., it was edited to remove the feet symbol.
;;;___
(defun c:sum_tx (/ stx i txn txi ltx)
(setq stx (ssget '((0 . "*text"))))
(repeat (setq i (sslength stx))
(setq txn (entget (ssname stx (setq i (1- i))))
txi (atof (vl-list->string
(vl-remove-if
'(lambda (x) (or (= x 39) (= x 44)))
(vl-string->list
(cdr (assoc 1 txn))
)
)
)
)
ltx (cons txi ltx)
)
(entmod (subst (cons 1 (rtos txi 2 2)) (assoc 1 txn) txn))
)
(apply '+ ltx)
)
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
