Given two lines, create two tangent arcs that connect them, with the connections beeing tangent too.
a) Provide dwg sample with before and after state.
@aitorm wrote:
..... I don't like to transform a spline to a polyline because it is not accurate and simple.
If you work with splines then creating whatever you want will be difficult since splines are generated using fit points and internal calculations.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Thank you.
This is basically my input, two separated polylines with different inclination:
And I need a lisp to create two arcs that join them like this (but leaving no constraints):
And then it would be cool if it converts the whole thing into a single polyline.
The aim is to get the simplest still smooth polyline.
I am attaching the file to test. Thank you so much.
@aitorm as I understand your question you would like to create two arcs to connect two lines without modifying the end points of either line. Is this correct?
For example, given two lines the center of a fillet is located on the line bisecting the angle formed by the two lines (green). If we are willing to modify the end point of one of the lines then the fillet radius RF would be determined by which line's endpoint is closest to the intersection of the bisector and a line perpendicular to the line. For example, in the case shown below that would be point B.
You seek to create two arcs to replace the single fillet arc with tangencies at all arc and line endpoints. There may be many solutions to this problem but I think they require one arc to have a radius greater than RF and the other smaller than RF. You could arbitrarily set one arc to 2 or 3 times RF (or something else within limits) and then have the program solve for the other radius and center point. For example, in the image below I set RA to about 3 times RF and solved for RB which is less than RF.
Is this what you want to do?
From my experience, it is hard to create code i.e algorithm that will produce polyline with arc and line segments as you request, that will look acceptable regarding smoothness of a curve and transition from arc to line.
Since you have to retain straight polyline endpoint you can do it easily:
- join straight polyline segments with a polyline
- offset this polyline some delta value
- MOVE this joining polyline for desired distance to the position of straight curve segment
- use command FILLET command to create arc segments on both side
You have to do it this way since for each arc segments there are two possible solutions for fillet and lisp code may have problem to find right one.
Here is a screencast that shows how to do it.
PS If your request is what @leeminardi has shown in post #6, this can be done, but I'm not sure if this will create acceptable (smooth) result.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Dear @aitorm
The geometric solution for the problem of compound curves has a solution; see formulas.
It would not be very complicated to program them, but it is required to specify the input data.
Regards.
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
I am reminded of a similar topic from some years back, but having found >the topic<, I see that the issue is not quite the same. But maybe something about it could be helpful....
@aitorm Here's a lisp program that I think will do what you want. The user interface could be cleaned up a bit. I have not tested it much and the value for d influences the radii of the arcs that are created. Let me know if you have any questions.
The program creates a single polyline and a point at the junction between the two arcs. Depending on the value of "d" you will get different results. For example, d = 2 yields:
Note that the transition point is "outside" the two lines.
While for d = 4 you get:
; Calculates the bi-arc to create a single polyline from
; two lines.
; forumula from https://www.ryanjuckett.com/biarc-interpolation/
; L. Minardi 3/22/2022 v1 edited smooth factor input
; v2-v4 improved user interface,
;
; calculate unit vector from v1 to v2
(defun uvec (v1 v2 / s)
(setq s (distance v1 v2))
(setq s (mapcar '/ (mapcar '- v2 v1) (list s s s)))
)
;;; Compute the dot product of 2 vectors a and b
(defun dot (a b / dd)
(setq dd (mapcar '* a b))
(setq dd (+ (nth 0 dd) (nth 1 dd) (nth 2 dd)))
) ;end of dot
(defun c:biarc (/ p1 p1o p2 p2o qI t1 t2 d1 d2 v dd1 dd2 q1 q2 pm s)
(SETQ TP1 (entsel "\nSelect First Line near end: ")) ; implies which way
(setq tpp1 (entget (car tp1))
p1 (cdr (assoc 10 tpp1))
p1o (cdr (assoc 11 tpp1))
pp (cadr tp1)
)
(setq d1 (distance p1 pp) d2 (distance p1o pp) )
(if (> d1 d2)
(setq temp p1 p1 p1o p1o temp)
)
(SETQ TP1 (entsel "\nSelect Second Line near end: ")) ; implies which way
(setq tpp2 (entget (car tp1))
p2 (cdr (assoc 10 tpp2))
p2o (cdr (assoc 11 tpp2))
pp (cadr tp1)
)
(setq d1 (distance p2 pp) d2 (distance p2o pp) )
(if (> d1 d2)
(setq temp p2 p2 p2o p2o temp)
)
(setq s (getreal "\nEnter smooth factor <4>: "))
(cond
((= s nil) (setq s 4.))
((= s 0) (progn (princ "0 is invalid. Smooth set to 4.") (setq s 4.)))
)
(setq qI (inters p1 p1o p2 p2o nil)
d1 (/ (distance p1 qI) s)
t1 (uvec p1o p1)
t2 (uvec p2 p2o)
)
(setq v (mapcar '- p2 p1))
(setq d2 (/
(- (* 0.5 (dot v v)) (* d1 (dot v t1)))
(- (dot v t2) (* d1 (- (dot t1 t2) 1.)))
)
)
(setq dd1 (/ d2 (+ d1 d2))
dd2 (/ d1 (+ d1 d2))
)
(setq q1 (mapcar '+ p1 (mapcar '* t1 (list d1 d1 d1)))
q2 (mapcar '- p2 (mapcar '* t2 (list d2 d2 d2)))
)
(setq pm (mapcar '+
(mapcar '* q1 (list dd1 dd1 dd1))
(mapcar '* q2 (list dd2 dd2 dd2))
)
)
(command "_point" "_non" pm)
(command "_pline" "_non" p1o "_non" p1 "A" "_non" pm "_non" p2 "L" p2o
"")
(princ)
)
P.S. The vector Voo Doo is for @john.uhden
