Good morning all,
I'm trying to get points along a zigzag polyline. This is hard to explain... See image beow...
I've found ways to select all verticies of polyline but to get these points only seems to be more difficult.
Thanks in advance for any input.
Would it always be every other vertex through the entire length of a Polyline, or might you sometimes want a limited range, such as the even-numbered ones from the 6th through 12th vertices of a 20-vertex Polyline? And would it always be the even-numbered ones as in your image, or might you sometimes want the odd-numbered ones from the 11th through 19th vertices?
@Kent1Cooper wrote:
…. every other vertex through the entire length of a Polyline...? ….
If that's the idea, here is one way to get two lists from a [lightweight only] Polyline, one of all the odd-numbered vertices (1st, 3rd, 5th, etc.) in a variable called "odds," and another of all the even-numbered ones in a variable called [as you might expect] "evens":
(defun C:PVEO ; = Polyline Vertices Every Other
(/ pl verts n which)
(setq
pl (car (entsel "\nPolyline to get alternate-vertices list: "))
verts (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) (entget pl)))
n 0 ; counter
); setq
(while verts
(setq which (read (if (= (rem (setq n (1+ n)) 2) 1) "odds" "evens")))
(set which (cons (car verts) (eval which)))
(setq verts (cdr verts)); remove point
); while
(setq odds (reverse odds)); if direction-order matters
(setq evens (reverse evens)); if direction-order matters
(princ)
); defunYou can then apply whatever you want to do to whichever of those lists is appropriate, using (foreach).
Hi Kent,
Thanks as always.
It seems that it is always the "evens" that I require. Maybe this would be easier to just show you what I'm trying to do.
@DC-MWA As I suppose, it is a stair profile , why not copy it and get down 1" 1/2 , I do in mm 38.1
(DEFUN MOVE-DOWN (/ (acMagenta NEW POLY POLY-OBJ PT-1 PT-3 STEP))
(VL-LOAD-COM)
(SETQ POLY (SSNAME (SSGET ":s" '((0 . "*line"))) 0))
(SETQ POLY-OBJ (VLAX-ENAME->VLA-OBJECT POLY))
(SETQ NEW (VLA-COPY POLY-OBJ))
(SETQ PT-1 (GETPOINT "\nPICK THE FIRST point "))
(SETQ STEP 38.1) ; 1 and half inch
(SETQ PT-3 (POLAR PT-1 (/ PI -2.0) STEP))
(VLA-MOVE NEW (VLAX-3D-POINT PT-1) (VLAX-3D-POINT PT-3))
(VLA-PUT-COLOR NEW ACMAGENTA)
)
@DC-MWA wrote:
Points in between 1st and 2nd pick
(Defun c:STW (/ fp sp pl verts thistwopoints n) ; Show These points
;; pBe May 2020 ;;;
(defun xy (p)(list (Car p)(cadr p)))
(if
(and
(setq fp (getpoint "\nPick first reference point"))
(setq sp (getpoint fp "\nPick next point"))
(setq pl (car (nentselp fp)))
)
(progn
(setq verts (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) (entget pl))))
(setq thistwopoints (vl-sort (mapcar '(lambda (w)
(vl-position (xy w) verts))(list fp sp)) '<))
((lambda (n)
(repeat (1- (/ (abs (apply '- thistwopoints)) 2))
;; repeated function here
(entmake (list (cons 0 "POINT") (cons 10 (nth (setq n (+ 2 n)) verts))))
)
)
(car thistwopoints)
)
)
)
(princ)
)If you want to include all points including 1st and second pick
((lambda (n)
(repeat (1+ (/ (abs (apply '- thistwopoints)) 2))
;; repeated function here
(entmake (list (cons 0 "POINT") (cons 10 (nth n verts))))
(setq n (+ 2 n))
)
)
(car thistwopoints)
)If you only want to include ONLY the first pick [ the direction of the polyline plays a role here, you can add check for polylline direction ]
((lambda (n)
(repeat (/ (abs (apply '- thistwopoints)) 2)
;; repeated function here
(entmake (list (cons 0 "POINT") (cons 10 (nth (setq n (+ 2 n)) verts))))
)
)
(car thistwopoints)
)
HTH
@devitg wrote:
…. it is a stair ....
You may be interested in STAIRS.lsp, with its StairSec command, available >here<. The topic is mis-named -- it also does Stairs in Section. It doesn't do the underside of treads as in your image, but you may find aspects of it that you can use, and such a thing could probably be added. It's built for Imperial units and US standards, but could easily be modified for other base options. Read the comments/instructions at the top of the file, and follow the prompts in the command.
If you're really permitted by applicable codes or regulations to do a stair with a straight plain vertical riser [not allowed under the most common Building Code around here], you can do that by choosing the Steel-pan stair option and calling for 0 nosing projection. But it's built to do either a canted riser that is typical of Steel-pan stairs or a projecting-tread-board rounded nosing that is typical of Wood stairs.
Change this line near the top:
(command ".undo" "e")
to this:
(command-s ".undo" "e")
[it was written before plain (command) in an *error* handler was problematic].
