Get Dialog Box Values in LISP
@isrsol702 wrote:
Pardon my ignorace Kent, .... where do I start to create the dialog box, a lot of terms used, I do not quite understand. ....
I haven't dug into using DCL myself either, so others are better able to help there. You could "climb up the ladder" in the Help hierarchy and find the best starting point. But....
If DCL is too daunting, an approach like @Anonymous's suggestion is something I've done, in which case you just hit Enter through most of the prompts to accept the defaults except where you want a different value. In this case that's a lot of Enters to plow through, so you may want to investigate DCL anyway.
But I like to do that default-offering approach in a way that takes more code, but A) doesn't require temporary variables [their newVariable in addition to their myVariable], and B) prevents invalid responses, and C) won't allow you to hit Enter when there's no default value set yet unless you have a starting default you want to offer.
For something with a common value that you want to offer as an initial default even when you haven't used the routine yet, let's say your slab thickness of 5:
(initget 6); no zero, no negative
(setq *BEslabthk
; global variable [the * is not needed -- just one way of "marking" a global variable]
; using *BE to start all of them to tie them to this & avoid conflict with other routines
(cond
( (getdist ; returns nil on Enter so it will go to next condition
(strcat
"\nSlab thickness <"
(rtos (cond (*BEslabthk) (5.0)))
; offer prior value if present, otherwise 5, shown in current units format/precision
; assuming a real number rather than an integer -- could be 6.5, for instance?
; using (getdist ) means you can pick points on-screen, or enter feet-inches-fractions, etc.
">: "
); strcat
); getdist
); end User-input condition
(*BEslabthk); on Enter above, use prior value if present
(5.0); none-of-the-above -- if no User input or prior value, use initial default
); cond
); setq
For something without a common-enough value to offer as an initial default, let's say your beam depth:
(initget (if *BEbeamd 6 7)); no zero, no negative, no Enter on first use when there's no prior value
(setq *BEbeamd
(cond
( (getdist
(strcat
"\nBeam depth"
(if *BEbeamd (strcat " <" (rtos *BEbeamd) ">") "")
; build offering of prior value only if present, otherwise nothing
": "
); strcat
); getdist
); end User-input condition
(*BEbeamd); on Enter above, use prior value
; [no none-of-the-above value, since Enter is prohibited with no prior value]
); cond
); setq
Similar approaches can be used with (getkword) for limited specific options such as Top/Bottom. For could-be-anything text-string values that can't be done with (initget)/(getkword), such as your "3#8", you have to handle it a little differently, because hitting Enter in response to a (getstring) function doesn't return nil as (getdist) & (getkword) & (getint) etc. do, but an actual text string that just has nothing inside it -- "".
@isrsol702 wrote:
....command prompt default values, I'm not quite sure what's best, all I need is to cut the time to input the values over an over again ;)
As not to disturb your current code too much, we will just add two subfunctions and a default dynamic list for you but you need to do all the dirty work plus I really don't have the time to spare fiddling with the rest of the code 
.....
(or InitVal
(setq InitVal
'(("ST" . 5) ("SJ" . "C") ("BD" . 35) ("BW" . 18) ("TW" . 18) ("DIMTOP" . "T") ("CGS" . 25)
("NA" . "8S") ("COLSHAPE" . "R") ("COLSIZE" . 24) ("EVEN" . "Y") ("COLJUST" . "C")
("BARS" . "3#8") ("SF" . 8) ("COVER" 1.5) ("REBCOV" . 2.0) ("MINOPEN" . 2.5) ("ANCHOUT" . 3))
)
)
(defun _assocvalue (v s / x)
(setq x (cdr (assoc v InitVal)))
(if s x (vl-princ-to-string x))
)
(defun _UpdateList (n v)
(if (/= (_assocvalue n t) v)
(setq InitVal (subst (cons n v)(assoc n InitVal) InitVal)))
v
)
....
And this is the usage. ( getreal ) / ( getkword ) / ( getstring )
....
(setq bd (getreal (strcat "\nEnter beam depth from top of slab in inches < " (_assocvalue "BD" nil)" >: ")))
(setq bd (if (null bd) (_assocvalue "BD" t)(_updatelist "BD" bd )))
(setq bw (getreal (strcat "\nEnter beam width at bottom of beam in inches< " (_assocvalue "BW" nil) " >: " )))
(setq bw (if (null bw) (_assocvalue "BW" t)(_updatelist "BW" bw )))
...
(progn
(initget "T t B b")
(setq dimtop (getkword
(strcat "Enter T if top beam width is at top of slab, B if at bottom of slabs< " (_assocvalue "DIMTOP" nil) " >: " )))
(setq dimtop (if (null dimtop) (_assocvalue "DIMTOP" t)(_updatelist "DIMTOP" dimtop )))
)
...
HTH
Have fun isrsol702, and tell us how it goes.
I'm a retard, I'm making simple things needlessly complicated, and because of that, i will help you build a dialog for your default values. Does this sound good to you?
@pbejse wrote:
.....As not to disturb your current code too much, we will just add two subfunctions and a default dynamic list for you .....
Hang in there.
FWIW;
Command prompt default [ patterned after post #6 of 15 <Kent1Cooper> ]
(defun _default (itm msg n s)
(setq f (cond
( (= n 1) getint)
( (= n 2) getstring)
( (= n 3) getkword))
)
(setq itmstr itm);<
(if (null s)(initget (if itm 2 3)))
(setq itm
(cond
( (f
(strcat
"\n" msg
(if itm (strcat " <" (vl-princ-to-string itm) ">") "")
": "
)
)
)
(itm)
)
)
(if (and (= n 2)(eq itm "")) itmstr itm)
)
HTH
Try the attached modified code.