Community
@Anonymous wrote:Nobody wants to help me?
Not quite septimiu1985, we all are in this discussion group, to get help, give help and learn.
If nobody has helped yet, I think it is due to the difficulty in access to 3DSOLID data, because it is encrypted, and it is not easy to accessed via LISP.
A few years ago, I did some things similar to what you need, I need to dig through my old files trying to find these routines, but at this moment I am on vacation, and dont have those files with me...
If no one else jump in to assist, when I find those files, I'll come back to give some help...
Henrique
If they're always running in orthogonal directions as it looks like they do in your sample, you could get their length and cross-sectional dimension [whether the side length of a square section or the diameter of a round one] from the differences in XYZ coordinates of the corners of their bounding boxes. But A) that might not be reliable if any are shorter in length than in width/diameter, and B) I haven't found any way to determine whether a given one is a cylinder or a rectangular prism, from entity data or VLA properties, and C) all bets are off if any of them run in non-orthogonal directions.
Kent Cooper, AIA 
septimiu1985,
here is a demo, only for the cylinders (boxes, requires a different type of approach, in my old files...), will create a .csv file.
(defun c:test (/ fname itm num obj ht rad str fl)
(if (and (setq fname (getfiled "Output File" "" "csv" 1))
(setq ss (ssget '((0 . "3DSOLID"))))
)
(progn
(setq itm 0
num (sslength ss)
)
(while (< itm num)
(setq obj (vlax-ename->vla-object
(ssname ss
itm
)
)
)
(If (= (vl-catch-all-apply 'vla-get-SolidType (list obj))
"Cylinder"
)
(setq
ht (read (rtos (* 2
(distance (vlax-get obj 'Position)
(vlax-get obj 'centroid)
)
)
2
2
)
)
rad (read (rtos (sqrt (/ (vla-get-Volume obj) (* pi ht))) 2 2))
lst (cons
(list rad
ht
)
lst
)
)
)
(setq itm (1+ itm))
);; while
(setq lst (vl-sort lst
'(lambda (a b)
(if (equal (car a) (car b))
(< (cadr a) (cadr b))
(< (car a) (car b))
)
)
)
)
(setq fl (open fname "w"))
(foreach n lst
(setq str (strcat (rtos (car n) 2 2) "\t" (rtos (cadr n) 2 2)))
(setq str (vl-string-translate "." "," str))
(write-line str fl)
);; foreach
(close fl)
(setq ss nil
lst nil
)
);; progn
);; if
(princ)
);; testHope that helps
Henrique
septimiu1985,
my fault, I have "vl-load-com" function in my acaddoc.lsp, so all the extended AutoLISP functions are loaded at startup.
you'll have to add
(defun c:test (/ fname itm num obj ht rad str fl)
(vl-load-com);; to load the extended AutoLISP functions
(if (and (setq fname (getfiled "Output File" "" "csv" 1))
...
Henrique
septimiu1985,
for accuracy reasons, this routine only works with PRIMITIVE SOLIDS, with EXTRUSIONS, is difficult to know if the original object was a CIRCLE, a ELLIPSE, or a POLYLINE, or even know if the object top is beveled.
This code works with BOX and CILINDER objects, and writes the result to a .csv file, is not a fast code, because it have to dig down through various sub-entities to get entity I need, but will do the trick...
(defun c:test (/ BLST CLST DATA DEP DIA FL FNAME ITM LEN NUM SS STR WID)
(vl-load-com)
(if (and (setq fname (getfiled "Output File" "" "csv" 1))
(setq ss (ssget '((0 . "3DSOLID"))))
)
(progn
(setq itm 0
num (sslength ss)
);; setq
(while (< itm num)
(setq data
(entget
(cdr
(assoc
360
(member
'(100 . "AcDbEvalGraph")
(entget
(cdr (assoc
360
(member
'(100 . "AcDbShHistory")
(entget (cdr (assoc 350
(member '(100 . "AcDb3dSolid")
(entget (ssname ss
itm
)
)
)
)
)
)
)
)
)
)
)
)
)
)
);; setq
(if (eq (cdr (nth 1 (member '(100 . "AcDbShPrimitive") data)))
"AcDbShBox"
)
(setq wid (cdr (assoc 40 (member '(100 . "AcDbShPrimitive") data)))
dep (cdr (assoc 41 (member '(100 . "AcDbShPrimitive") data)))
len (cdr (assoc 42 (member '(100 . "AcDbShPrimitive") data)))
blst (cons (list wid dep len) blst)
);; setq
);; if
(if (eq (cdr (nth 1 (member '(100 . "AcDbShPrimitive") data)))
"AcDbShCylinder"
)
(setq dia (* 2
(cdr (assoc 41 (member '(100 . "AcDbShPrimitive") data)))
)
len (cdr (assoc 40 (member '(100 . "AcDbShPrimitive") data)))
clst (cons (list dia len) clst)
);; setq
);; if
(setq itm (1+ itm))
);; while
(if (or clst
blst
)
(progn
(setq fl (open fname "w"))
(if blst
(progn
(setq blst (vl-sort blst
'(lambda (a b)
(if (= (cadr a) (cadr b))
(< (car a) (car b))
(< (cadr a) (cadr b))
)
)
)
);; setq
(write-line "Width\tDepth\tLength" fl)
(foreach n blst
(setq str (strcat (rtos (car n) 2 2)
"\t"
(rtos (cadr n) 2 2)
"\t"
(rtos (caddr n) 2 2)
)
)
(setq str (vl-string-translate "." "," str))
(write-line str fl)
);; foreach
);; progn
);; if
(if clst
(progn
(setq clst (vl-sort clst
'(lambda (a b)
(if (= (car a) (car b))
(< (cadr a) (cadr b))
(< (car a) (car b))
)
)
)
)
(write-line "Diameter\tLength" fl)
(foreach n clst
(setq
str (strcat (rtos (car n) 2 2) "\t" (rtos (cadr n) 2 2))
)
(setq str (vl-string-translate "." "," str))
(write-line str fl)
);; foreach
);; progn
);; if
(close fl)
);; progn
);; if or
);; progn
);; If
(princ)
);; test
Hope that helps
Henrique
@Anonymous wrote:Hello,
This one is perfect, thank you very much Henrique!
Just one more thing, I have test it and is working perfect, but it is possible somehow to calculate also the sum from every cylinders which have the same diameter, and the sum for boxes which have the same width&depth, because I saw that the elements are placed in order according to the diameter size, or by the width and length for the boxes.
...
You're welcome, septimiu1985,
can be made, but like I said before, I'm on vacation, and I'm too lazy, so, you have to do something... 
One way:
1-Open the .csv file with the notepad (or other text editor)
2-Ctrl+T (to select all), Ctrl+C (to copy all)
3-Open Excel (or other spreadsheet)
4-select a cell and Ctrl+V
Now it is easy to obtain the total length of all elements with the same characteristics...
Henrique
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
