Erase all dimensions with specific measurement

[Tallans422]

Hello,

I thought there was a LISP routine floating around that would delete all dimensions from your drawing that have a specific measurement value that you can specify within the routine.  Anyone familiar?

Thanks

[Kent1Cooper]

You can specify the Measurement value in QSELECT to find them for you, to Erase.

[and similarly with the other varieties of Dimensions].

But I think that would require really exact same-ness.  Two Dimensions that display as the same measurement because of the precision setting in the Dimension Style could be different a few more decimal places down, and therefore not found in the same QSELECT operation.  If that's a possibility, it is probably necessary to find more Dimensions than you want, and step through them to check their Measurement values for being what you're aiming for but with a fuzz factor.

[Tallans422]

I know about the option in qselect.  Trying to find a way to automate it for many users in a LISP routine.

Thanks

[komondormrex]

hi,

maybe like this

(command "_erase" (ssget "_x" (list '(0 . "dimension") (cons 42 <number - your dim value>))) "")
;eg
(command "_erase" (ssget "_x" (list '(0 . "dimension") (cons 42 37))) "")

also may be tuned using -4 group codes. 

[ВeekeeCZ · Accepted solution]

Possibly something like this. You can adjust the value of fuzz.

(defun c:DimEraseMeasurement (/ f s r e i)

  (if (and (setq f 0.01) ; fuzzy
	   (setq s (ssget "_X" (list '(0 . "DIMENSION") (cons 410 (getvar 'ctab)))))
	   (or (setq r (getdist "\nSpecify measurement of dims to be removed <select example>: "))
	       (and (setq r (car (entsel "\nSelect dimension: ")))
		    (or (= "DIMENSION" (cdr (assoc 0 (entget r))))
			(prompt "\nError: Wrong selection. Selected object isn't DIMENSION."))
		    (setq r (cdr (assoc 42 (entget r)))))))
    (repeat (setq i (sslength s))
      (setq e (ssname s (setq i (1- i))))
      (if (not (equal r (cdr (assoc 42 (entget e))) f))
	(ssdel e s))))
  (if (and s (/= 0 (sslength s)))
    (command "_.erase" s ""))
  (princ)
  )

[Tallans422]

That's the ticket BeekeeCZ, thanks!