Drawing an line that changes colour depending on angle.
When you say "lines," does that mean you draw these in some kind of multiples in series, such as this kind of thing, as in a time-line graph of some kind?
Or is it only one at a time?
I made them Polylines here for width for visual clarity, but you mention both Polylines and Lines -- which would it be?
If they would be Polylines, and if they would be in series like the image above, they would have to be separate Polylines -- a single one with multiple segments can't have the segments in different colors.
Something like this, perhaps [minimally tested]?
(defun C:SLC (/ p1 p2 drop p3 dropang); = Sloped Lines Color-coded
(setq
p1 (getpoint "\nStart/left end of Line: ")
p2 (getpoint p1 "\nPoint with X coordinate of right end of Line: ")
drop (getdist p2 "\nDrop distance from left to right: ")
p3 (list (car p2) (- (cadr p1) drop))
dropang (angle p1 p3)
); setq
(command
"_.line" p1 p3 ""
"_.chprop" "_last" "" "_color"
(cond
((> dropang (* pi 1.95)) 90); green ;;; EDIT multipliers & color numbers as desired
((> dropang (* pi 1.9)) 50); yellow
((> dropang (* pi 1.8)) 40); orange
(10); red [anything steeper]
); cond
""
); command
(princ)
); defun
It asks for the start and X-position-of-end for one Line, but could be made to repeatedly ask for the next X-of-end pick in a series such as in my earlier image, if that's what you need. That is, as written, to do that kind of series, you have to pick on the right end of the previous Line for the left start of the next one, but it could be made to use that previous-Line right end for the next-Line left end automatically.
And note that though it uses rubber-banding for the 'p2' and 'drop' settings, it does not just use the picked points, but operates as I think your description indicates -- it uses only the X coordinate of the 'p2' pick location, and it takes the 'drop' distance, however specified [picked relative to p2, or typed in] off the Y coordinate of 'p1' , not off p2 that it's rubber-banding from. If that's confusing, the rubber-banding can be eliminated.
It also does not check for other things that it could, for example that the second point is actually to the right of the first one, but such things could be added easily enough. Consider other optional approaches, such as putting the Lines on different Layers with those colors, depending on their slopes, rather than forcing a color override on them.
@JanTol82 wrote:
... is it also possible to make it so that he picks the last point for the next line and make it an active command in which you can insert multiple points?
Try this variation:
(defun C:SLC (/ p1 p2 drop p3 dropang); = Sloped Lines Color-coded
(setq p1 (getpoint "\nStart/left end of Line: "))
(while (setq p2 (getpoint p1 "\nPoint with X coordinate of right end of Line <exit>: "))
(setq
drop (getdist p2 "\nDrop distance from left to right: ")
p3 (list (car p2) (- (cadr p1) drop))
dropang (angle p1 p3)
); setq
(command
"_.line" p1 p3 ""
"_.chprop" "_last" "" "_color"
(cond
((> dropang (* pi 1.95)) 90); green ;;; EDIT multipliers & color numbers as desired
((> dropang (* pi 1.9)) 50); yellow
((> dropang (* pi 1.8)) 40); orange
(10); red [anything steeper]
); cond
""
); command
(setq p1 p3); set end as beginning of next Line
); while
(princ)
); defun
@JanTol82 wrote:
Thank you Kent, that is what we want. Is it also possible to make it that works in two direction with the angel? ....
.
This seems to do that [in very limited testing]. I changed it to ask for the Difference rather than the Drop, and added that to the Y component rather than subtract it, because if left in "drop" terms, you would have had to enter a negative value to go up, which seemed counterintuitive. So enter a negative value for a drop, positive for a rise.
(defun C:SLC (/ p1 p2 diff p3 diffang); = Sloped Lines Color-coded
(setq p1 (getpoint "\nStart/left end of Line: "))
(while (setq p2 (getpoint p1 "\nPoint with X coordinate of right end of Line <exit>: "))
(setq
diff (getdist p2 "\nDifference from left to right: ")
p3 (list (car p2) (+ (cadr p1) diff))
diffang (angle p1 p3)
); setq
(command
"_.line" p1 p3 ""
"_.chprop" "_last" "" "_color"
(cond
((or (< diffang (* pi 0.05)) (> diffang (* pi 1.95))) 90); green ;;; EDIT multipliers & color numbers as desired
((or (< diffang (* pi 0.1)) (> diffang (* pi 1.9))) 50); yellow
((or (< diffang (* pi 0.2)) (> diffang (* pi 1.8))) 40); orange
(10); red [anything steeper]
); cond
""
); command
(setq p1 p3); set end as beginning of next Line
); while
(princ)
); defun
