Draw line between insertion point of a block and other point at the same block

[RBernaz]

Hi,

Hope someone can help me since my lisp knowledges are very poor.

I have a dynamic block to insert multiple along a line and I already inserted, but now i would like to draw a line between the insertion point of it to another point of itself. Could be done all together at the same time or by picking one by one.

Example: Have a line and i’ve inserted perpendiculary 10 blocks like balloons which the insertion point is the start of the rope and then we have balloon itself… I would like to automatically draw in each block a line between the start of the rope and the center of the balloon….

Is it possible ???

Hope you understand what I mean

Thanks in advance

Best regards

[devitg]

Please upload a BEFORE and AFTER DWG .

[ВeekeeCZ]

Post the dwg with that block and draw a line where you what to have it.

[RBernaz]

thank you,

There is the example file. The red lines are the those to be drawn, after inserting the blocks

hope it helps

[RBernaz]

and the line where we insert the blocks will not always be horizontal or vertical it can be i irregular path

[devitg]

show as it will be .

[RBernaz]

I've already posted a file example

thanks

[Moshe-A]

@RBernaz  hi,

if the line is drawn from the insertion point to center of balloon then why can't you add it as part of the block?

[RBernaz]

thank you,

Because the lines have to be available to be manipulated independtly after the insertion of the block

[RBernaz]

It´s easy when you have a few but when you have hundres is painfull

[Moshe-A]

yes but we are talking about LINE and the manipulation you want to do is move the first point (assuming the second point must be in center of the balloon) and you can enable this manipulation in dynamic block

also you can add visibility param to turn the line on\off - no?

[RBernaz]

yes, but you cannot do an offset from it or change color or layer independently if it is inside of the block...

[Moshe-A]

that is not true, with dynamic block tools you can simulate even offset and change the line layer and color

[RBernaz]

Well the offset, yes I can do with visibility and manipulate by stretching parameters, but colour by layer, layer and plot style? can I?

[RBernaz]

well i can do a block with the block and the line inside and then explode all of them after inserting them all....

I realized that now maybe it is easier 

thank you all

[Moshe-A]

well if you design the block carefully by laying the rectangle on fixed layer and the line lay on layer '0' plus set it's color 'byblock' than by changing the block layer the line will reflect this layer change and changing the block color the line will reflect that color.

[Moshe-A]

no no no !

there is huge advantage on keeping it as block cause any change will reflect all inserts

[Moshe-A · Accepted solution]

@RBernaz hi,

just for i do not want you to leave with bitter taste, here is the lisp function to do what you want

to control layer + color and ltype you need to set the appropriate fields in (entmake) function:

(cons 8 (getvar 'clayer)) ; set layer

'(6 . "bylayer") ; set ltype bylayer

'(62 . 256) ; set color bylayer

for example:

(cons 8 "wire") ; lay the line on layer wire

'(6 . "dashdot") ; set linertype dashdot

'(62 . 1) ; set line color to red

of course you can change all of these properties afterwards.

enjoy

moshe

(defun c:bwire (/ ss AcDbBlockReference elist dyn_length dyn_angle p0)
 (if (setq ss (ssget '((0 . "insert") (2 . "square,`*U*"))))
  (mapcar
    '(lambda (ename)
      (if (and
	    (setq AcDbBlockReference (vlax-ename->vla-object ename)); allocating memmory
	    (eq (vla-get-isDynamicBlock AcDbBlockReference) :vlax-true)
	    (eq (strcase (vla-get-effectivename AcDbBlockReference)) "SQUARE")
	  )
       (progn
	(setq elist (entget ename))
        (setq dyn_length (getpropertyvalue ename "AcDbDynBlockPropertyImplantação"))
	(setq dyn_angle  (getpropertyvalue ename "AcDbDynBlockPropertyAngle2"))
	(if (= (getpropertyvalue ename "AcDbDynBlockPropertyFlip State1") 1)
	 (setq dyn_angle (+ dyn_angle pi))
	)

	; add line to drawing
	(entmake (list
		  '(0 . "line")
		   (cons 8 (getvar 'clayer))	; set layer
		  '(6  . "bylayer")		; set ltype bylayer
		  '(62 . 256)			; set color bylayer
		   (cons 10 (setq  p0 (cdr (assoc '10 elist))))
		   (cons 11 (polar p0 (+ (cdr (assoc '50 elist)) dyn_angle) dyn_length))
		 )
	); entmake
       ); progn
      ); if

      (vlax-release-object AcDbBlockReference) ; dispose memory
     ); lambda
    (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
  ); mapcar
 ); if

 (princ) 
); c:bwire

[RBernaz]

Fantastic, wonderful, many thanks for the solution.

[devitg]

Hi Moshe-A, I do not know nothing about dynamic block , but could it be a way to edit the block or rename , and the line to be in the dynamic block  with it's length and flip tobe variable??

Maybe I can start learning about dyn Blocks.