Default choice "enter" returns nil
I agree that you need to be careful about the USER System Variables if you might have more than one routine that uses the same one. Maybe you use a further-along one like UserI5. But if you can control that, the fact that the numerical ones [not the String ones, for some reason] are stored in the drawing is an advantage. However, since the UserI... and UserR... System Variables have a value of zero [not nil] until you set them to something else, on first use in the accepted Solution, you will be offered zero as a default value, and if you hit Enter, you will surely have a problem when that is used as a scale factor.
Here's a way around that, and it also shows a way to offer an initial default on first use when you have not yet set a value, if you have a common value that you are likely to use often. In this case, it offers 100 only if there is no [non-zero] prior value, but you can change that to whatever you prefer. If you type in any integer value, it will use it; if you have a prior value and you hit Enter, it will use that prior value; if you don't have a prior value and you hit Enter, it will use 100.
(setvar 'UserI1
(cond
( (getint ; User input [returns nil on Enter]
(strcat
"\nQuelle sera l'échelle d'impression? 100 pour 1:100 <"
(if (/= (getvar 'UserI1) 0) (itoa (getvar 'UserI1)) "100")
;; offer prior value as default if present; if not, offer 100 as initial default
">: "
); strcat
); getint
); end User-input condition
((/= (getvar 'UserI1) 0) (getvar 'UserI1)); on Enter if prior non-zero value exists
(100); on Enter if no prior value exists [i.e. UserI1 = 0]
); cond
); setvar
Others have already done so, but note the use of (itoa) instead of (rtos) with no decimal places, when the value is an integer.
Also [a small thing], you can use the double-quotes-at-both-ends approach with System Variable names in (getvar ) and (setvar), but the apostrophe-at-the-front-only approach also works in both functions.
Kent Cooper, AIA 
@Anonymous wrote:
....
I was using the userI1 var .... Now, I know this is not the best way and I have some other choices.
....
The same approach can be used with a variable name:
(setq ech
(cond
( (getint ; User input [returns nil on Enter]
(strcat
"\nQuelle sera l'échelle d'impression? 100 pour 1:100 <"
(if ech (itoa ech) "100")
;; offer prior value as default if present; if not, offer 100 as initial default
">: "
); strcat
); getint
); end User-input condition
(ech); on Enter if prior non-zero value exists
(100); on Enter if no prior value exists
); cond
); setvarand in some ways is a little easier, because that variable would presumably never be set to zero [as UserI1 will be if not set to something else], so you don't need to evaluate whether it's zero, but simply whether it exists.
But yes, if you want it stored in the drawing, you need to do something more complicated like a dictionary.
Kent Cooper, AIA
