custom user input at command line to exit from while
The problem is that you're still in the (while) loop inside the (gpts) sub-routine, and there's nothing inside that to stop it so the CL command can get back out to its (while) loop to check on the 'cont' variable. But since the (gpts) function contains only one internal function, it may as well be folded into the command directly, rather than be a sub-routine, so there can be only one (while) loop.
And you can do it in a way that doesn't require you to answer the question about whether to do more. You can just have exiting be the default when it's asking for points, and you can keep picking more without answering the question, or hit Enter to stop. One way:
;Shorten pline start and end points by set value
(defun c:cl (/ cont pt1 pt2 d1 npt1 npt2 a1)
(setq cont "Y")
(while (= cont "Y")
(if
(and
(setq pt1 (getpoint "\nPick first point [or <exit>]: ")); returns nil on Enter/space
(setq pt2 (getpoint pt1 "\nPick second point [or <exit>]: ")); returns nil on Enter/space
); and
(if (> (setq d1 (distance pt1 pt2)) 0.15); then -- picked points for both -- draw it if long enough
(progn
(setq npt1 (polar pt1 (setq a1 (angle pt1 pt2)) (+ 0.05)))
(setq npt2 (polar pt1 a1 (- d1 0.05)))
(command "_pline" npt1 npt2 "")
); progn
); if
(setq cont nil); else -- hit Enter/space for either point -- exit
); if
); while
(princ)
); defun
[I also altered it slightly in a way that saves a little code by using the 'a1' variable, which was never used in the original.]
BeekeeCZ is right [second suggestion] that it can also be done without the 'cont' variable. It can, in fact, be done with considerably fewer variables, since many are used only once and can just be calculated where they're used, without the variable middle-man:
;Shorten pline start and end points by set value
(defun c:cl (/ pt1 pt2)
(while
(and
(setq pt1 (getpoint "\nPick first point [or <exit>]: "))
(setq pt2 (getpoint pt1 "\nPick second point [or <exit>]: "))
); and
(if (> (distance pt1 pt2) 0.15)
(command
"_pline"
"_none" (polar pt1 (angle pt1 pt2) 0.05)
"_none" (polar pt2 (angle pt2 pt1) 0.05)
""
); command
); if
); while
(princ)
); defun
I also added the "_none" Osnap calls. Without them, it would be advisable to set OSMODE to 0, which would also ideally mean saving its current value first and resetting it later, and an error handler that resets it on Escape -- none of the suggestions yet includes those.
BeekeeCZ's inclusion of an error handler is not a bad idea, though I think the only time it would suppress an error message is if the User stops the command with the Escape key. You can decide whether it's worth suppressing a "Function cancelled" message, when that's not going to alarm anyone -- they knew that when they hit Esc.
@christopher.l.evans wrote:
....
Kent for the most part the point will be selected using an osnap setting so I'm not certain that will work for me.
If you would have running Osnap modes on for point selection, it's all the more important to have the routine "none"-ify the points it calculates to draw to. Otherwise, depending on the relationship between the hold-back-the-ends size, the Zoom level, and the Osnap modes that are on, the ends might not be held back because they could Snap to the same points selected. My latest one works great with Osnap used for selecting your reference locations, drawing the Plines with ends appropriately held back from them, whether the Osnap is in running modes that are on, or an individually-called-for mode at the time of a point selection.
@christopher.l.evans wrote:
..., I was thinking of none by its actual definaition, sorry. What does it do though? ... the only referance to _none in developers help is the DIMBLK system varible.
It disables any "running" Object Snap mode(s) for just the immediately-next point. Read about it in Help for the OSNAP command. [It isn't listed among the modes under the OSMODE System Variable, because there's no point in having None as a "running" Osnap mode -- turning Osnap off does that. And it would be kind of meaningless to have it combined with any other mode(s).]
