Create diagram with Lisp
I agree that the Customization Forum is the better place for this. But when you post the question there, add more detail, and better yet, include a small sample drawing.
What are the red dots? Donuts with zero inside radius [i.e. closed two-arc-segment Polylines with width]? Blocks? Solid Hatch patterns? If Hatch patterns, is the presumed Circle that was Hatched still there?
It looks to me as though the red lines are irrelevant, but since they are mentioned in the description, I wonder whether that's true. If they are relevant, what is their part in the process?
@karfung wrote:
I have copy paste in the autocad, it not working. Could you review it?
[Add the missing closing right parenthesis at line 95.]
Are they always aligned horizontally, never offset like this?
And always the same vertical spacing on both sides?
If so, it should be possible to pick just two dots.
If the rods are horizontally aligned, here's my take on it:
(defun C:RodX(/ *error* doc svn svv ctr1 ctr2 ctr3 ctr4 rad)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(prompt (strcat "\nError: " errmsg))
); if
(mapcar 'setvar svn svv); reset System Variables
(vla-endundomark doc)
(prin1)
); defun - *error*
(vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
(setq
svn '(osmode cmdecho blipmode clayer); System Variable Names
svv (mapcar 'getvar svn); and current Values
); setq
(setvar 'osmode 4); CENter
(setq
ctr1 (getpoint "\nRod center at first corner of X: ")
ctr3 (getpoint "\nRod center at opposite corner of X: ")
ctr2 (list (car ctr1) (cadr ctr3))
ctr4 (list (car ctr3) (cadr ctr1))
); setq
(initget (if *RodXdia* 6 7)); no zero, no negative, no Enter on first use
(setq *RodXdia*
(cond
( (getdist
(strcat
"\nDiameter of Circles"
(if *RodXdia* (strcat " <" (rtos *RodXdia*) ">") "")
": "
); strcat
); getdist
); User-input condition
(*RodXdia*); prior value if present on Enter when allowed
); cond
rad (/ *RodXdia* 2)
); setq
(mapcar 'setvar svn '(0 0 0)); turn off Osnap, command echo, blips
(command
"_.layer" "_make" "SNA-DIM" "_color" 9 "" ""
"_.circle" ctr1 rad
"_.copy" "_last" "" "_multiple" ctr1 ctr2 ctr3 ctr4 ""
"_.line" (polar ctr1 (angle ctr1 ctr3) rad) (polar ctr3 (angle ctr3 ctr1) rad) ""
"_.line" (polar ctr2 (angle ctr2 ctr4) rad) (polar ctr4 (angle ctr4 ctr2) rad) ""
"_.line" (inters ctr1 ctr3 ctr2 ctr4) (polar (getvar 'lastpoint) 0 (* (abs (- (car ctr1) (car ctr3))) 1.5)) ""
"_.layer" "_make" "SNA-TXT-2" "_color" 4 "" ""
); command
(command-s "_.text" "_style" "ROMANS0.8" "_ml" (polar (getvar 'lastpoint) 0 rad) 80 0)
(mapcar 'setvar svn svv); reset
(vla-endundomark doc)
(prin1)
)You can pick the CENters [Object Snap built in for that] of two rod dots at any two opposite corners of the desired X location, in either order.
It includes the horizontal Line rightward from the X intersection, and the Text, which it leaves you to provide content for [you don't get to see it on-screen as you type, but just type it, answering the prompt in the Command line]. It currently uses the Text Style & height in your sample drawing, but could be made to ask for either or both of those and remember what you give it. It needs the Style to exist in the drawing, without fixed height as in your sample, but could be made to create it, as it does with the Layers.
It remembers your Circle Diameter [once you have given it one], and offers it as default on subsequent use, so you don't need to enter it repeatedly.
Another select 3 points as in a "L". Works if even sloped.
; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/create-diagram-with-lisp/td-p/13938747
; X on reo by AlanH
(defun c:XREO ( / dia mp oldlay oldsnap pt1 pt1a pt2 pt2a pt3 pt3a pt4 pt4a rad)
(defun rtd (a)
(/ (* a 180.0) pi)
)
(setq oldlay (getvar 'clayer))
(setvar 'clayer "SNA-DIM")
(setq oldsnap (getvar 'osmode))
(setvar 'osmode 4)
(if (= (tblsearch "Layer" "SNA-TXT-2") nil)
(command "-layer" "M" "SNA-TXT-2" "")
)
(setq pt1 (getpoint "\nPick 1st point "))
(setq pt2 (getpoint pt1 "\nPick 1st point "))
(setq pt3 (getpoint pt2 "\nPick 1st point "))
(setq pt4 (polar pt3 (angle pt2 pt1) (distance pt1 pt2)))
(setq dia (getreal "\nEnter diameter of circle "))
(if (= dia nil)(setq dia 50))
(setq rad (/ dia 2.0))
(setvar 'osmode 0)
(command "circle" pt1 rad)
(command "circle" pt2 rad)
(command "circle" pt3 rad)
(command "circle" pt4 rad)
(setq pt1a (polar pt1 (angle pt1 pt3) rad))
(setq pt3a (polar pt3 (angle pt3 pt1) rad))
(command "Line" pt1a pt3a "")
(setq pt2a (polar pt2 (angle pt2 pt4) rad))
(setq pt4a (polar pt4 (angle pt4 pt2) rad))
(command "Line" pt2a pt4a "")
(setq mp (mapcar '* (mapcar '+ pt1 pt3) '(0.5 0.5)))
(setq pt2 (polar mp (angle pt2 pt3) 180.0))
(command "line" mp pt2 "")
(setvar 'clayer "SNA-TXT-2")
; (command "text" "J" "ML" pt2 80.0 0.0 (getstring T "\nEnter bar description "))
(command "mtext" pt2 pt2 "T10-200" "")
(setvar 'osmode oldsnap)
(setvar 'clayer oldlay)
(princ)
)
(c:xreo)Not sure what angle for text I used zero.
@karfung wrote:
This is not working; the result shows the circle spacing similar to the circle diameter.
I don't know what to tell you. It works for me [still in re-testing, as it did when I posted it]:
Can you show what you are getting?
[Maybe you're selecting in some way other than Osnapping to centers of diagonally opposite rods, or in a non-orthogonal arrangement.]
