Conversion of multiple LISP files to FAS files (requesting change in lsp code)

[Anonymous]

Dear Experts,

I got a lisp code that can convert SINGLE lisp file to fas file, which is located in same AutoCAD drawing folder path.

But the requirement is to convert MULTIPLE lisp files to fas files, which are existed in so many subfolders in the main folder.

The code should ask user to select the main folder path. Then the code should execute all subfolders and then choose only lisp files from all subfolders and then FAS files to be created in subfolder path respectively.

Please find the code below:

(defun c:LSP2FAS-Help (/)
(alert (strcat
 "\tLisp (LSP) to Fast and Secure (FAS) Help"
 "\n "
 "\nFile dialog begins in the current directory.   "
 "\nIt is suggested to place and open a drawing (DWG)   "
 "\ninside the input folder you wish to batch process.   "
 "\n "
 "\nOutput file will be in the same folder as the file selected.   "
 "\n "
 "\nThere is no provisional check for an existing FAS file of the same name.   "
))
);end LSP2FAS-Help

(defun c:LSP2FAS ( / a )
(vl-load-com)
(prompt " Lisp to Fast and Secure (FAS). LSP2FAS-Help available. ")
(if (wcmatch (strcase (setq a (getfiled "Convert LSP File to FAS" (getvar "DWGPREFIX") "" 16))) "*.LSP")
 (progn
  (c:vlide)(vlisp-compile 'st a)
  (princ (strcat "\n File " (vl-string-subst ".fas" ".lsp" a) " created. "))
 );progn
 (alert "File extension must be \".LSP\"   ")
);if
(princ)
);end LSP2FAS

Thanks a lot in Advance. 

[pbejse]

---

@Anonymous wrote:

The code should ask user to select the main folder path. Then the code should execute all subfolders and then choose only lisp files from all subfolders and then FAS files to be created in subfolder path respectively.

---

;;; Gilles Chanteau ;;;
(defun allfiles	(folder pattern)
  (apply 'append
	 (cons (if (vl-directory-files folder pattern)
		 (mapcar '(lambda (x) (strcat folder "\\" x))
			 (vl-directory-files folder pattern)
		 )
	       )
	       (mapcar '(lambda (x) (allfiles (strcat folder "\\" x) pattern))
		       (vl-remove ".." (vl-remove "." (vl-directory-files folder nil -1)))
	       )
	 )
  )
)

(defun c:LSP2FAS  (/ a lspFiles)
      (vl-load-com)
      (prompt
            " Lisp to Fast and Secure (FAS). LSP2FAS-Help available. ")
      (if
            (and
                  (setq folder
                             (acet-ui-pickdir
                                   "Select Lisp Folder"
                                   (if folder
                                         folder
                                         (getvar 'dwgprefix))
                                   )
                        )
                  (setq lspFiles (allfiles folder "*.lsp"))
                  )
                 (foreach a lspFiles
                       (c:vlide)
                       (vlisp-compile 'st a)
                       (princ (strcat "\n File "
                                      (vl-string-subst
                                            ".fas"
                                            ".lsp"
                                            a)
                                      " created. "))
                       )
             (alert "No  \".LSP\" files selected  ")
            	)
                       
      (princ)
      )  

HTH

[Anonymous]

Dear Sir,

Thanks a lot for responding immediately. The code showing error like below. And the lisp command is not working.

Waiting for a solution from your Side. Thanks a lot in advance Sir.

[pbejse]

copy and paste it again @Anonymous 

Earlier it was missing one variable name, I updated the post afterwards

(setq lspFiles (allfiles folder "*.lsp"))

[Anonymous]

It's working Excellent Sir,

Please look at below snapshot.

Actually the lisp code is able to convert one by one lisp file to fas by CLOSING each Visual lisp Window. Otherwise, the code is not able to generate fas files, without closing the lisp window each time.

Is there any possibility to update the code without user interfere, each time for each file?

Sir, Please try with attached ZIP File, which has some lisp files in each sub folder.

[pbejse · Accepted solution]

---

@Anonymous wrote:

It's working Excellent Sir,

Is there any possibility to update the code without user interfere, each time for each file?

---

You are doing it again @Anonymous , that behaviour is part of the code you posted,

If you dont want to see VLIDE, Remove this line from the code.

 (c:vlide)

And close VLIDE while you're at it.

[Anonymous]

Sir, Working Fabulously.

Thanks a lot, You saved lot of manhours to me.

[pbejse]

---

@Anonymous wrote:

Sir, Working Fabulously.

Thanks a lot, You saved lot of manhours to me.

---

You are welcome, and please dont call me sir. 

Glad i could help

[Sea-Haven]

Just a suggestion you can save the fas to another directory if you want so all fas are in one location much easier to manage for end user distribution.

(vlisp-compile 'st  fname  (strcat "d:\\alan\\compiled\\" fname ".fas"))

[Anonymous]

Dear Sir,

Thanks for your suggestion. Can you please implement in main code?

Thanks a lot in advance Sir.

[Sea-Haven]

Change this line

(vlisp-compile 'st a (strcat "c:\\yourdirectory\\etc\\name" a ".fas" ))