continou dimension in the layer source

[Anonymous]

i want to continou dimension in the layer source of  the dimension that is being continued

ep

Command:DIMCONTINUE
Specify a second extension line origin or [Undo/Select/Layer] <Select>:L
Enter layer option for dimension that is being continued objects [Current/Source] <Source>:

[m_rogoff]

^C^C-la;s;<YOUR LAYER NAME>;;^C^C_dimlinear;\\\_dimcontinue

I have also modified Dimlinear to  ^C^C-la;s;<YOUR LAYER NAME>;;^C^Cdimlinear

sorry, I have AutoCad 2014 and I do not get the Layer option when I run DIMCONTINUE. Also, do you use the "Select" option?

[Kent1Cooper]

---

@m_rogoff wrote:

.... I do not get the Layer option when I run DIMCONTINUE. ....

---

No one does.  That's what they're looking to add to the command.

Interestingly, I find that in ol' 2004 the new Dimension is always drawn on the current Layer, regardless of the Layer of the Dimension that it's continuing from, whereas in 2015, the new Dimension is always drawn on the same Layer as the Dimension that it's continuing from, regardless of what the current Layer is.

So, majdov24:  I assume from your request that your version always makes it on the current Layer.  Would you be satisfied with a separate command for making a new one on the same Layer as a selected one, rather than as an option in the DIMCONTINUE command?  I think that might be easier to make.  [One could also be made to make it on the current Layer, for those who want to do that but whose versions always make it on the continued Dimension's Layer.]

[dbroad]

In AutoCAD 2016, there is a new dimlayer variable.  

[ВeekeeCZ · Accepted solution]

Something similar I have...

(defun C:DimCon ( / *error* oldCLAYER oldDIMSTYLE sel dimLayer)

  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled, quit / exit abort, console break"))
      (princ (strcat "\nError: " errmsg)))
    
    (setvar 'CLAYER oldCLAYER)
    (command "_.-DIMSTYLE" "_r" oldDIMSTYLE)
    (command "_.UNDO" "_e")
    
    (princ)
  )

  (setq oldCLAYER 	(getvar 'CLAYER))
  (setq oldDIMSTYLE 	(getvar 'DIMSTYLE))
  (command "_.UNDO" "_be")
  
  (while (not (and (setq sel (entsel "\nSelect dimension to be continued: "))
		   (eq "DIMENSION" (cdr (assoc 0 (entget (car sel)))))
		   (setq dimLayer (cdr (assoc 8 (entget (car sel)))))
		   (not (command "_.-DIMSTYLE" "_r" (cdr (assoc 3 (entget (car sel))))))))
    (princ "\nWrong selection, try again!"))

  (if (/= oldCLAYER dimLayer)	   
    (progn
      (initget "Current Source")
      (if (not (eq "Current" (getkword "\nSelect layer to continue with [Current/Source] <Source>: ")))
	(setvar 'CLAYER dimLayer))))	
  
  (command "_.DIMCONTINUE" sel)
  (while (> (getvar 'CMDACTIVE) 0)
    (command PAUSE))

  (command "_.-DIMSTYLE" "_r" oldDIMSTYLE)
  (setvar 'CLAYER oldCLAYER)
  (command "_.UNDO" "_e")
  (princ)
)