Click point within boundary with selection enclosing object

[martin_leiter]

Hello, I have the following problem: I have a rectangle that also belongs to an Autocad group. How do I manage to select the rectangle and autocad group just by clicking in the empty area inside the rectangle without selecting an object. The click point is already stored in a variable. Ask for your help. Thank you!

[Moshe-A]

@martin_leiter hi,

well it depends on what do you want to do with the rectangle. if you want to know is the coordinates of it?

use -BOUNDARY command, the result is a copy of your rectangle.

(to modify it, you have to iterate the group)

moshe

[martin_leiter]

Hello Moshe, I need the Autocad group in a selection set so that I can pass the selection set at the command "Group select" with the command "Groupedit".

Thank you

[Moshe-A]

take a look at this link

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/lisp-routine-to-get-quot-group-name-...

[martin_leiter]

Hello Moshe, thanks for your help. I do not need the group name. I am looking for a possibility without directly choosing the object to get the group into a selection set. Thank you

[ВeekeeCZ · Accepted solution]

This selects everything that is closing the picked area. A group selection is applied. 

(vl-load-com)

(defun c:ClickInsideToSelect ( / ops enl pts sel)

  (and (setq ops (getvar 'pickstyle))
       (setvar 'pickstyle 1) ; make sure group selection is active
       (setq enl (entlast))
       (setvar 'cmdecho 0)
       (princ "\nPick inside a group: ")
       (vl-cmdf "_.BOUNDARY" pause "")
       (not (equal enl (setq enl (entlast))))
       (setq pts (mapcar 'cdr (vl-remove-if '(lambda (x) (/= (car x) 10)) (entget enl))))
       (vl-cmdf "_.ERASE" enl "")
       (setvar 'cmdecho 1)
       (setq sel (ssget "_CP" pts))
       (sssetfirst nil sel)
       )
  (setvar 'pickstyle ops)
  (princ)
  )

[martin_leiter]

Hello BeekeeCZ, thank you very much for your help. I do not have access to my autocad at the moment. But that looks very good! I will report on Monday as soon as I have tested it. Thank you!

[martin_leiter]

Hello BeekeeCZ, Thank you! It works perfectly! That's exactly what I missed!