Change specific Line weight to another depending on Layer.
@Anonymous wrote:
... on Layer 1 with a current weight of 0,5 ...
... in the Layer 2 with a weight of 0,5 ...
... on Layer 3 with a Line Weight of 0,15 or 0,00 to Weight "From Layer" (Or ByLayer).
....
Something like this, perhaps [untested]?
(defun C:FLW (/ pair) ; = Fix LineWeights
(foreach pair '(("1" 50) ("2" 50) ("3" 150) ("3" 0))
(command "_.chprop"
(ssget "_X" (list (cons 8 (car pair)) (cons 370 (cadr pair))))
"" "_lweight" "ByLayer" ""
); command
); foreach
(princ)
); defun
Check the numerical values associated with the lineweights you want in the code-370 entry in entity data [e.g. above, it's 50 there for what shows as 0.5 in Properties].
That will fix only things in the current space. If you need to hit all spaces, (subst)/(entmod) methods could probably be used instead of a CHPROP command. Again, untested, but I hope this would do it:
(defun C:FLW (/ pair ss n edata) ; = Fix LineWeights
(foreach pair '(("1" 50) ("2" 50) ("3" 150) ("3" 0))
(if (setq ss (ssget "_X" (list (cons 8 (car pair)) (cons 370 (cadr pair)))))
(repeat (setq n (sslength ss))
(setq edata (entget (ssname ss (setq n (1- n)))))
(entmod (subst '(370 . -1) (assoc 370 edata) edata))
); repeat
); if
); foreach
(princ)
); defun
[The question also arises: By "script" do you mean a Script in AutoCAD's meaning of the word, that is, a .SCR file invoked by the SCRIPT command? Or do you mean it in the more generic coded-steps way that a lot of people use? If the former, is that because you use LT and can't use an AutoLisp routine?]
Kent Cooper, AIA 
@Anonymous wrote:
....
Your first routine changes all Weights to Bylayer but only Visually (?) and not in the properties itself.
(in the window that opens when u type " Lst " )
Second one doesnt do anything.
....
After correcting the 150 to 15 in the Layer-"3" pairings, I set up the circumstances and tested both commands, and they both work for me [in Model Space -- I didn't go into multiple spaces].
If you mean "LIST" command results not showing the change, when something's lineweight is ByLayer, that is not reported there -- it simply omits that information, just as it omits color and/or linetype if there's no override on those. You should see the difference if you LIST something before [with lineweight reported] and after [not]. Or, look at them in the Properties palette afterwards, where it does show lineweight even when it's ByLayer.
Kent Cooper, AIA
Accepted solution
... and another correction of sorts: The first one should also have a check on whether it found anything of the specified lineweight on the specified Layer, before it tries to change it:
(defun C:FLW (/ pair ss) ; = Fix LineWeights
(foreach pair '(("1" 50) ("2" 50) ("3" 15) ("3" 0))
(if (setq ss (ssget "_X" (list (cons 8 (car pair)) (cons 370 (cadr pair)))))
(command "_.chprop" ss "" "_lweight" "ByLayer" ""); then
); if
); foreach
(princ)
); defun
Kent Cooper, AIA