Change layer color

[Oh_Snap!]

I've been using this lisp I found somewhere on the internet to change a layer color by picking an object on the layer and the color dialog appears and I select new color.  This dialog only has index colors though. Does anyone know if this could be modified to also include True Colors?

(defun C:xlc (/ lay col)
  (setq
    lay (cdr (assoc 8 (entget (car (nentsel "\nObject on Layer to assign color to: ")))))
    col (acad_colordlg (cdr (assoc 62 (tblsearch "layer" lay))) nil)
  )
  (command "_.layer" "_color" col lay "")
  (princ)
)

[Kent1Cooper · Accepted solution]

....

  col (acad_truecolordlg (assoc 62 (tblsearch "layer" lay)) nil (assoc 62 (tblsearch "layer" lay)))

....

EDIT:  But using  what that returns is another matter....  It won't work to just substitute that line.  I'll have to think about that one.  [And I didn't replace my trial "0" layer name with 'lay' in both places -- fixed now.]

Further EDIT:  Minimally tested:

(defun C:xlc (/ lay col)
  (setq
    lay (cdr (assoc 8 (entget (car (nentsel "\nObject on Layer to assign color to: ")))))
    col (acad_truecolordlg (assoc 62 (tblsearch "layer" lay)) nil (assoc 62 (tblsearch "layer" lay)))
  ); setq
  (entmod (append (entget (tblobjname "layer" lay)) col))
  (princ)
); defun 

[ronjonp · Accepted solution]

Try this:

(defun c:clc (/ c d e n)
  ;; RJP » 2019-03-19
  ;; Set layer color by pick
  (or (getenv "clc") (setenv "clc" "(62 . 1)"))
  (cond	((setq c (acad_truecolordlg (read (getenv "clc"))))
	 (setenv "clc" (vl-prin1-to-string (last c)))
	 (setq d (vla-get-activedocument (vlax-get-acad-object)))
	 (while	(setq e (car (nentsel "\nSelect entity to change layer color: ")))
	   (entmod (append (entget (tblobjname "layer" (cdr (assoc 8 (entget e))))) c))
	   (vla-regen d acactiveviewport)
	 )
	)
  )
  (princ)
)
(vl-load-com)

[Oh_Snap!]

That works great!  Thank you Kent.

[Oh_Snap!]

This also works. Thank you. 

[ronjonp]

@Oh_Snap! 

You might give my code a try .. it has quite a bit more error checking and will remember your last color used 😉

*EDIT .. you did try it! 🙂

[York13]

Is there a way to also have this LISP work with non-xrefed objects too?

Edit: Nevermind.  It appears to work just fine. Thanks.

Double Edit: Now I keep receiving an error Application ERROR: Bad arguments.