Change all Hatch on a Layer
@Anonymous Run command Hatchedit and try to select more then one entity. Does it work? Probably not.
What you have to do is run command for each object in selection set.
(setq i -1 a (ssget "X" '((8 . "Test1"))))
(while (< (setq i (1+ i)) (sslength a ))
(command "-hatchedit" (ssname ss i a) "p" "ANSI31" "1" "0")
)
;.....
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@Anonymous
What have you tested? My example works fine.
If you are using some older version using initcommandversion may help.
Command hatch edit works with single entity and not entire selection set. If used with selection set that contains more then one entity, changes will apply only to first element. That was idea of my first post.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@Anonymous wrote:
Thanks, but is still not working.
[That Message shows as being in response to yourself, so we can't tell whose suggestion is not working. Make sure you pick on the Reply button in an individual Message, not in the "Reply-to-the-topic" slot at the bottom, which is always listed as being in Reply to the original post. It also helps to quote at least a small part of what you're Replying to.]
Kent Cooper, AIA 
Also, your selection set creation is a problem. You have to filter only hatch entities at particular layer i.e
(setq a (ssget "X" '((0 . "HATCH")(8 . "Test1"))))
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
How about pairing Layer names with their intended pattern names, and having one selection set of all Hatch patterns on Layers with appropriate names, and substituting patterns and scale and angle into each one's entity data, pulling the pattern from the list of pairings, rather than using a Hatchedit command? Then you don't need a separate selection for each Layer, with its separate (if) function in case there are no Hatch patterns on that Layer, or if that Layer doesn't exist. It doesn't need to handle SOLID differently from other patterns.
Does this work [untested]?
(defun C:H-C (/ pairs ss n hatch edata)
(setq pairs '(("TEST1" "ANSI31") ("TEST2" "SOLID") ("TEST3" "ANSI33") ("TEST4" "DASH") ("TEST5" "ANSI33") ("TEST6" "ANSI31")))
(if (setq ss (ssget "_X" '((0 . "HATCH") (8 . "TEST#*")))); all Hatch patterns on Layers with such names
(repeat (setq n (sslength ss)); then
(setq
hatch (ssname ss (setq n (1- n))); the Hatch object
edata (entget hatch); its entity data
edata (subst (cons 2 (cadr (strcase (assoc 8 edata)) pairs)) (assoc 2 edata) edata); pattern
edata (subst '(41 . 1.0) (assoc 41 edata) edata); scale
edata (subst '(52 . 0.0) (assoc 52 edata) edata); angle
); setq
(entmod edata)
); repeat
); if
(princ)
); defun
[I used all-capitals Layer names in the 'pairs' list, and (strcase) in pulling the Layer names from entity data, because there it's case-sensitive. The (8 . "TEST#*") Layer filter in the (ssget) function is not case-sensitive. It uses "TEST#*" to allow for Layer names into more than one digit at the end. Using "TEST##" would not see those with only one digit, or three if it comes to that, but "TEST#*" would see something like "TEST7demo". If there's any need to avoid complications like that, they can be accounted for.
But maybe that's all moot, assuming those Layer names are not what you will really have. You can use:
(8 . "ThisLayer,ThatLayer,LayerA,LayerB,Whatever")
with all "real" Layer names comma-delimited in one string.]
EDIT: And it wouldn't be much work to have different scale factors and/or angles for the patterns on each Layer if needed -- they can be added to the 'pairs' sub-lists, and pulled in a similar way as the pattern name for substituting into entity data.
Kent Cooper, AIA
Sorry: this line:
edata (subst (cons 2 (cadr (strcase (assoc 8 edata)) pairs)) (assoc 2 edata) edata); pattern
should be:
edata (subst (cons 2 (cadr (assoc (strcase (cdr (assoc 8 edata))) pairs))) (assoc 2 edata) edata); pattern
Kent Cooper, AIA
@Sea-Haven wrote:
For kent. When will the forum allow editing of a post classic example of a simple 1 line mistake that could be fixed all other forums allow this. I am guilty of typos.
You can edit posts, but only within a time limit [I think it's 30 minutes] -- in fact, I did edit that one more than once before I let it be, and I didn't look it over again closely to notice the error until after the time limit.
The place to suggest such a change is in the >Community Feedback Forum<, but before you do, do a Search and read the numerous threads already there that ask the same question.
Kent Cooper, AIA
Accepted solution
@Anonymous wrote:
Unfortunately it doesn't work yet. Can it be due to the layer name? Inventory_Konstr_N-1_Bestand_Hatch, inventory_Konstr_N-1_Bestand_Hatch ??
I wouldn't think that would matter, as long as the Layers are all spelled correctly in the pairing list, and in the (ssget) filter comma-delimited Layer name string [which must not have spaces on either side of the commas].
In case there was anything about doing the "repair," here's my edit, which worked for me using your Test# Layer names:
(defun C:H-C (/ pairs ss n hatch edata)
(setq pairs '(("TEST1" "ANSI31") ("TEST2" "SOLID") ("TEST3" "ANSI33") ("TEST4" "DASH") ("TEST5" "ANSI33") ("TEST6" "ANSI31")))
(if (setq ss (ssget "_X" '((0 . "HATCH") (8 . "TEST#*")))); all Hatch patterns on Layers with such names
(repeat (setq n (sslength ss)); then
(setq
hatch (ssname ss (setq n (1- n))); the Hatch object
edata (entget hatch); its entity data
edata (subst (cons 2 (cadr (assoc (strcase (cdr (assoc 8 edata))) pairs))) (assoc 2 edata) edata); pattern
edata (subst '(41 . 1.0) (assoc 41 edata) edata); scale
edata (subst '(52 . 0.0) (assoc 52 edata) edata); angle
); setq
(entmod edata)
); repeat
); if
(princ)
); defun
The left one is a User-defined pattern, and the rest were all the same but on different Layers, with the color being the same as the number at the end of the Layer name. The routine changed all those pattern names.
Kent Cooper, AIA
@Anonymous wrote:
Can I also search a little differently (8. "TEST # *")? so that only the last part is always the same (_hatch)?
Layer name is:
Konstr_N-1_Bestand_Hatch
N-1_Bestand_Hatch
The asterisk is a wildcard for any number of characters. You can put it before the known/fixed characters. Try:
(8 . "*_Hatch")
[and note that you need a space between the 8 and the period/decimal.]
Kent Cooper, AIA