Blocks in nodes with more than 2 lines
@Dan-Rod wrote:
.... another for more than 4 lines ....
I think, from the drawing, that the wording above should really be "... another for 4 or more lines ..." -- is that correct?
So what would be your process? The command asks you to select a bunch of Lines? It finds all Lines in the drawing itself, without User selection? Something else? Restricted to [a] particular Layer[s]? All Blocks at scale of 1, or affected by the drawing scale? All at rotation of 0, or affected somehow by the directions of the Lines? Some other criteria? Etc.
@Dan-Rod Your block insertion points are not it in the center of the circles?
Here's a quick one to place text that denotes how many common points are found.
(defun c:foo (/ i m p r s)
(cond ((setq s (ssget '((0 . "LINE"))))
(foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
(setq r (cons (list (vlax-curve-getstartpoint e) (vlax-curve-getendpoint e)) r))
)
(setq r (apply 'append r))
(while (setq p (car r))
(setq r (cdr r))
(setq m (vl-remove-if-not '(lambda (x) (equal p x 1e-4)) r))
(if (> (setq i (1+ (length m))) 2)
(progn (entmake (list '(0 . "TEXT")
'(100 . "AcDbEntity")
'(67 . 0)
'(8 . "Junction_Label")
'(100 . "AcDbText")
(cons 10 p)
'(40 . 7.5)
(cons 1 (strcat (itoa i) "R"))
'(50 . 0.)
'(41 . 1.)
'(51 . 0.)
'(71 . 0)
'(72 . 1)
(cons 11 p)
'(100 . "AcDbText")
'(73 . 2)
)
)
(foreach x m (setq r (vl-remove x r)))
)
)
)
)
)
(princ)
)
You need to redefine the Blocks for the correct scale [they're inserted at scales of 0.0394 in the sample drawing, not 1], and to have their insertion points at their centers [they're wacky off in the sample drawing]. But given those corrections, this is one way to do it [minimally tested]:
(defun C:TEST (/ liness n ldata ptlist thispt thisss)
(if (setq liness (ssget "_X" '((0 . "LINE")))); add Layer filter if desired
(progn ; then
(repeat (setq n (sslength liness)); make list of all Line endpoints
(setq
ldata (entget (ssname liness (setq n (1- n))))
ptlist (cons (cdr (assoc 10 ldata)) ptlist); add start point
ptlist (cons (cdr (assoc 11 ldata)) ptlist); add end point
); setq
); repeat
(while ptlist
(setq
thispt (car ptlist); first remaining
thisss (ssget "_C" (polar thispt (/ pi 4) 2) (polar thispt (* pi 1.25) 2) '((0 . "LINE,INSERT")))
;; 2 argument based on sample drawing AS CORRECTED, to find Block as well as Lines if present
); setq
(if
(and
(not (ssget "_P" '((0 . "INSERT") (2 . "3R,4R")))); not already a Block there
(> (sslength thisss) 2); more than 2 Lines meet there
); and
(command "_.insert" (if (= (sslength thisss) 3) "3R" "4R") "_non" thispt "" "" ""); then
); if
(setq ptlist (vl-remove thispt ptlist)); remove all same point from list
;; will not remove if not exactly meeting; some may remain in list,
;; which is why above checks whether already a Block there
); while
); progn
); if
(prin1)
)
@ronjonp wrote:
....
Here's a quick one to place text that denotes how many common points are found.
Maybe you didn't notice the two black Circles [really black, not index color 7 white/black, but TrueColor 0,0,0] that are part of the Blocks. I assume if it's done with Text, it should also draw those Circles. @Dan-Rod would need to say whether that would suffice, rather than having actual Block insertions.
EDIT: It also "violates" the original description, and Message 5 elaboration, involving 4 or more always getting the 4R Block, no matter how many Lines meet there.
I did notice the faint circles on my screen but since the insertions points of the blocks are in the middle of nowhere, I decided to use text as a quick example. Plus it will work with an infinite number of common points. 🙂
adds the blocks but stops, only inserts 2 blocks (at the points where they appear in example 2), apparently there is an error, I attach file with correct scale and block center at 0,0,0
Nothing attached. It worked for me in the original drawing. Is this one different [for example, Polylines instead of some of the Lines]?
The failure is because there is no 4R Block defined in the new drawing. EDIT: Try mine [attached].
