Community
HI @Anonymous,
In playing with your sample, I tried making the blocks annotative so that they would rotate to the view but apparently this does not work with MultiLeaders.
I also tried exploding the Mleader and then redfining the block so that it is annotative and rotates to match the view and this seemed to work the best but does not address the leader part of the Mleader.
I suggest that to go further with this I can move this thread to the Customization forum. I am thinking a lisp routine that can put it a new mleader (maybe on its own layer) to match the existing but with proper orientation might work. Please let me know if you would like me to move the thread for you.
Please select the Accept as Solution button if my post solves your issue or answers your question.
Ok ,
I've had a smidgen of success but there is more to go. Any tips greatly appreciated.
I found a dxf code for the block rotation. "46". With this little bit of code I could change the block rotation.
(Defun C:MLA (/) (Setq MLA_NEW_ANG 0) (Setq ed (entget (car (entsel)))) (setq MLA_EXISTING_ANG (cdr (assoc 46 ed))) (Prompt "\nExisting Block Angle = ") (Prin1 MLA_EXISTING_ANG) (Prompt "\n") (setq ed (subst (cons 46 0.0) (assoc 46 ed) ed )) (entmod ed) );end defun
But the leader landings are still in disarray. Especially if the leaders are off the right hand side of the block.
Before....
After....
I'm still looking but I cant seem to find what controls the "landing" for the leader lines.
Can anyone point me to what dxf codes control the glitch seen above.
Thanks
Dave
Hi Dave,
After some more testing I've updated this program.
The issue with upside down MLeader content was not related to the geometry of the MLeader and is resolved now by correctly redefining the MLeader plane X and Y axes that are saved with the MLeader object.
There is an issue with MLeaders that have been mirrored and I am still investigating.
I also found an issue with scaled MLeaders in that the scale factor is not applied and saved to the DXF codes that seem to be used for storing scale information.
For MLeaders with block content I've assumed (rightly or wrongly) that the Content Scale (Context Data Group code 40) should equal the Block Content Scale factor (Context Data Group code 16) which is actually a list of scale factors (X, Y and Z).
MText content does not seem to save any scaling information about itself and seems to be controlled by Context Data Group code 40 which does not update if the MLeader is scaled.
Again, still investigating 
Regards,
Trevor
;; MLeaderContentAlign.lsp by Trevor Bird
;;
;; 2016-08-12
;;------------------------------------------------------------------------------
(defun c:mleadercontentalign
(
/
BlockContentPosition_15
BlockContentRotation_46
BlockPlaneX:v_new
BlockPlaneY:v_new
BlockPlaneZ:v_new
BlockRotation:uv
ContentBasePosition_10
ContextData_10
ContextData_110
ContextData_111
ContextData_112
ContextData_12
ContextData_13
ContextData_14
ContextData_15
ContextData_16
ContextData_16_new
ContextData_171
ContextData_175
ContextData_297
ContextData_40
ContextData_40_new
ContextData_42
ContextData_46
ContextData_DXF
ContextData_DXF_copy
ContextData_DXF_new
DogLeg:uv
dp
flag_ContextData
flag_while
LeaderControl_10
LeaderControl_11
LeaderControl_40
LeaderControl_DXF
Leaders_DXF
Leaders_DXF_copy
Leaders_DXF_new
Leader_10
Leader_10_new
Leader_11
Leader_11_new
Leader_DXF
Leader_DXF_new
list_47
list_47_copy
list_47_new
list_Leaders
list_Leaders_copy
list_Leaders_new
list_vector
member_list
MULTILEADER_172
MULTILEADER_DXF
MULTILEADER_DXF_new
MULTILEADER_ename
m:Block2_list
m:BlockNew1_list
m:BlockNew2_list
ScalarDistance
ScalarSign
ssC
ss_MULTILEADER
sv_ucsxdir_wcs
sv_ucsydir_wcs
TextDirection_13
TextLocation_12
ucsxdir_angle
ucsydir_angle
ucszdir_wcs
Vector:uv
Vector:v
VectorsAngle
VectorsVDP
VectorX
VectorY
)
(setq ss_MULTILEADER (ssget ":L" (list '(0 . "MULTILEADER") (cons 410 (getvar 'CTAB)))))
(cond
( (not ss_MULTILEADER)
(princ "\nNo MLeaders selected.")
);(not ss_MULTILEADER)
(ss_MULTILEADER
(setq sv_ucsxdir_wcs (getvar 'UCSXDIR)
sv_ucsydir_wcs (getvar 'UCSYDIR)
ucsxdir_angle (atan (cadr sv_ucsxdir_wcs) (car sv_ucsxdir_wcs))
ucsydir_angle (atan (cadr sv_ucsydir_wcs) (car sv_ucsydir_wcs))
);setq
(setq ssC -1)
(repeat (sslength ss_MULTILEADER)
(setq MULTILEADER_ename (ssname ss_MULTILEADER (setq ssC (1+ ssC)))
MULTILEADER_DXF (entget MULTILEADER_ename)
MULTILEADER_DXF_new (reverse (cdr (member '(300 . "CONTEXT_DATA{") (reverse MULTILEADER_DXF))))
MULTILEADER_DXF_new (append MULTILEADER_DXF_new (cdr (member '(301 . "}") MULTILEADER_DXF)))
MULTILEADER_172 (cdr (assoc 172 MULTILEADER_DXF_new)) ; Content Type
ContextData_DXF (cdr (member '(300 . "CONTEXT_DATA{") MULTILEADER_DXF))
ContextData_DXF (reverse (cdr (member '(301 . "}") (reverse ContextData_DXF))))
ContextData_10 (cdr (assoc 10 ContextData_DXF)) ; Content Base Position
ContextData_40 (cdr (assoc 40 ContextData_DXF)) ; Content Scale
ContextData_110 (cdr (assoc 110 ContextData_DXF)) ; MLeader Plane Origin Point
ContextData_111 (cdr (assoc 111 ContextData_DXF)) ; MLeader Plane X-Axis Direction
ContextData_112 (cdr (assoc 112 ContextData_DXF)) ; MLeader Plane Y-Axis Direction
ContextData_297 (cdr (assoc 297 ContextData_DXF)) ; MLeader Plane Normal Reversed
);setq
;; <!-- ContextData
;; Reconstruct ContextData_DXF without LEADER data:
(setq ContextData_DXF_copy ContextData_DXF
ContextData_DXF_new nil
Leaders_DXF nil
flag_while T
flag_ContextData T
);setq
(while flag_while
(setq dp (car ContextData_DXF_copy)
ContextData_DXF_copy (cdr ContextData_DXF_copy)
);setq
(cond
( (equal dp '(302 . "LEADER{"))
(setq Leaders_DXF (append Leaders_DXF (list dp))
flag_ContextData nil
);setq
);(equal dp '(302 . "LEADER{"))
( (equal dp '(303 . "}"))
(setq Leaders_DXF (append Leaders_DXF (list dp))
flag_ContextData T
);setq
);(equal dp '(303 . "}"))
( (not flag_ContextData)
(setq Leaders_DXF (append Leaders_DXF (list dp)))
);(not flag_ContextData)
(flag_ContextData
(setq ContextData_DXF_new (append ContextData_DXF_new (list dp)))
);flag_ContextData
);cond
(if (not ContextData_DXF_copy)
(setq flag_while nil)
);if
);while flag_while
;; ContextData -->
;; <!-- Leaders
(setq Leaders_DXF_copy Leaders_DXF
list_Leaders nil
LeaderControl_DXF nil
flag_while T
);setq
(while flag_while
(setq member_list (member '(302 . "LEADER{") Leaders_DXF_copy))
(cond
( (not member_list)
(setq flag_while nil)
);(not member_list)
(member_list
(setq Leaders_DXF_copy (cdr (member '(303 . "}") member_list))
Leader_DXF nil
);setq
(while member_list
(setq dp (car member_list)
member_list (cdr member_list)
Leader_DXF (append Leader_DXF (list dp))
);setq
(if (equal dp '(303 . "}"))
(setq member_list nil)
);if
);while member_list
(cond
( (not LeaderControl_DXF)
;; Assume "Last Leader Line Point" of first leader in multileader is control point:
(setq LeaderControl_DXF Leader_DXF)
);(not LeaderControl_DXF)
(LeaderControl_DXF
(setq list_Leaders (append list_Leaders (list Leader_DXF)))
);LeaderControl_DXF
);cond
);member_list
);cond
);while flag_while
(setq LeaderControl_10 (cdr (assoc 10 LeaderControl_DXF)) ; Last Leader Line Point
LeaderControl_11 (cdr (assoc 11 LeaderControl_DXF)) ; Dogleg Vector
LeaderControl_40 (cdr (assoc 40 LeaderControl_DXF)) ; Dogleg Length
DogLeg:uv LeaderControl_11
);setq
;; Leaders -->
;; <!-- Content Type
(cond
( (= MULTILEADER_172 acMTextContent)
(setq ContextData_12 (cdr (assoc 12 ContextData_DXF)) ; Text Location
ContextData_13 (cdr (assoc 13 ContextData_DXF)) ; Text Direction
ContextData_42 (cdr (assoc 42 ContextData_DXF)) ; Text Rotation
ContextData_171 (cdr (assoc 171 ContextData_DXF)) ; Text Attachment
ContextData_175 (cdr (assoc 175 ContextData_DXF)) ; Text Alignment Type
);setq
(if (minusp (leemac:vxv LeaderControl_11 sv_ucsxdir_wcs))
(setq ScalarSign -1.0)
(setq ScalarSign 1.0)
);if
(setq DogLeg:uv (leemac:vxs sv_ucsxdir_wcs ScalarSign)
LeaderControl_DXF (subst (cons 11 DogLeg:uv) (assoc 11 LeaderControl_DXF) LeaderControl_DXF)
;; Reset Text Location:
Vector:v (mapcar '- ContextData_12 LeaderControl_10)
Vector:uv (leemac:unit Vector:v)
VectorsVDP (leemac:vxv Vector:uv LeaderControl_11)
VectorsAngle (leemac:acos VectorsVDP)
VectorsAngle (* ScalarSign VectorsAngle)
ScalarDistance (distance LeaderControl_10 ContextData_12)
;; 2D Vector Rotation:
VectorX (- (* (car DogLeg:uv) (cos VectorsAngle)) (* (cadr DogLeg:uv) (sin VectorsAngle)))
VectorY (+ (* (cadr DogLeg:uv) (cos VectorsAngle)) (* (car DogLeg:uv) (sin VectorsAngle)))
TextLocation_12 (mapcar '+ LeaderControl_10 (leemac:vxs (list VectorX VectorY 0.0) ScalarDistance))
TextDirection_13 sv_ucsxdir_wcs
ContextData_DXF_new (subst (cons 12 TextLocation_12) (assoc 12 ContextData_DXF_new) ContextData_DXF_new)
ContextData_DXF_new (subst (cons 13 TextDirection_13) (assoc 13 ContextData_DXF_new) ContextData_DXF_new)
);setq
;; <!-- Reset Content Base Postion:
(setq Vector:v (mapcar '- ContextData_10 LeaderControl_10)
Vector:uv (leemac:unit Vector:v)
VectorsVDP (leemac:vxv Vector:uv LeaderControl_11)
VectorsAngle (leemac:acos VectorsVDP)
VectorsAngle (* ScalarSign VectorsAngle)
ScalarDistance (distance LeaderControl_10 ContextData_10)
;; 2D Vector Rotation:
VectorX (- (* (car DogLeg:uv) (cos VectorsAngle)) (* (cadr DogLeg:uv) (sin VectorsAngle)))
VectorY (+ (* (cadr DogLeg:uv) (cos VectorsAngle)) (* (car DogLeg:uv) (sin VectorsAngle)))
ContentBasePosition_10 (mapcar '+ LeaderControl_10 (leemac:vxs (list VectorX VectorY 0.0) ScalarDistance))
ContextData_DXF_new (subst (cons 10 ContentBasePosition_10) (assoc 10 ContextData_DXF_new) ContextData_DXF_new)
);setq
;; Reset Content Base Postion -->
);(= MULTILEADER_172 acMTextContent)
( (= MULTILEADER_172 acBlockContent)
(setq ContextData_14 (cdr (assoc 14 ContextData_DXF)) ; Block Content Normal Direction
ContextData_15 (cdr (assoc 15 ContextData_DXF)) ; Block Content Position
ContextData_16 (cdr (assoc 16 ContextData_DXF)) ; Block Content Scale
ContextData_46 (cdr (assoc 46 ContextData_DXF)) ; Block Content Rotation
ContextData_16_new (mapcar 'abs ContextData_16)
;; Reset Content Scale
ContextData_40_new (car ContextData_16_new)
ContextData_DXF_new (subst (cons 40 ContextData_40_new) (assoc 40 ContextData_DXF_new) ContextData_DXF_new)
);setq
;; Block Content Axes in UCS:
(setq ucszdir_wcs (leemac:v^v sv_ucsxdir_wcs sv_ucsydir_wcs)
BlockPlaneX:v_new (mapcar '* ContextData_16_new sv_ucsxdir_wcs)
BlockPlaneY:v_new (mapcar '* ContextData_16_new sv_ucsydir_wcs)
BlockPlaneZ:v_new (mapcar '* ContextData_16_new ucszdir_wcs)
);setq
;; Determine new Dog Leg direction:
(setq Vector:v (mapcar '- ContextData_15 LeaderControl_10)
Vector:uv (leemac:unit Vector:v)
);setq
(if (minusp (leemac:vxv Vector:uv sv_ucsxdir_wcs))
(setq ScalarSign -1.0)
(setq ScalarSign 1.0)
);if
(setq DogLeg:uv (leemac:vxs sv_ucsxdir_wcs ScalarSign)
LeaderControl_DXF (subst (cons 11 DogLeg:uv) (assoc 11 LeaderControl_DXF) LeaderControl_DXF)
);setq
;; Determine new Block Content Rotation:
(cond
( (and (> ContextData_46 ucsydir_angle)
(< ContextData_46 (+ ucsydir_angle pi))
);and
(setq BlockContentRotation_46 ucsxdir_angle
ScalarDistance LeaderControl_40
);setq
)
(ContextData_46
(setq BlockContentRotation_46 ucsxdir_angle
ScalarDistance (distance LeaderControl_10 ContextData_15)
);setq
);ContextData_46
);cond
(setq ContextData_DXF_new (subst (cons 46 BlockContentRotation_46) (assoc 46 ContextData_DXF_new) ContextData_DXF_new))
;; Define block rotation as a vector:
(setq BlockRotation:uv (list (cos BlockContentRotation_46) (sin BlockContentRotation_46) 0.0))
;; <!-- Determine new Block Content Position:
(setq BlockContentPosition_15 (mapcar '+ LeaderControl_10 (leemac:vxs DogLeg:uv ScalarDistance))
ContextData_DXF_new (subst (cons 15 BlockContentPosition_15) (assoc 15 ContextData_DXF_new) ContextData_DXF_new)
);setq
;; Determine new Block Content Position: -->
;; <!-- Block Transformation Matrix
(setq list_47 (vl-remove-if-not '(lambda (_dp) (= (car _dp) 47)) ContextData_DXF_new)
list_47 (mapcar 'cdr list_47)
);setq
(setq m:Block2_list nil
list_47_copy list_47
);setq
(while list_47_copy
(setq list_vector nil)
(repeat 4
(setq list_vector (append list_vector (list (car list_47_copy)))
list_47_copy (cdr list_47_copy)
);setq
);repeat 4
(setq m:Block2_list (append m:Block2_list (list list_vector)))
);while list_47_copy
;; Block Transformation Matrix -->
;; <!-- Reconstruct Block Content Matrix (includes scaling):
(setq m:BlockNew1_list
(list
(append BlockPlaneX:v_new '(0.0))
(append BlockPlaneY:v_new '(0.0))
(append BlockPlaneZ:v_new '(0.0))
(append BlockContentPosition_15 '(1.0))
);list
m:BlockNew2_list (apply 'mapcar (cons 'list m:BlockNew1_list))
);setq
;; Reconstruct Block Content Matrix -->
(setq list_47_new (apply 'append m:BlockNew2_list)
list_47_new (mapcar '(lambda (_x) (cons 47 _x)) list_47_new)
ContextData_DXF_new (vl-remove-if '(lambda (_dp) (= (car _dp) 47)) ContextData_DXF_new)
ContextData_DXF_new (append ContextData_DXF_new list_47_new)
);setq
;; Reconstruct Block Content Matrix (includes scaling) -->
;; <!-- Reset Content Base Postion:
;; Compare block rotation with block plane axis X.
(if (minusp (leemac:vxv (leemac:unit BlockPlaneX:v_new) DogLeg:uv))
(setq ScalarSign -1.0
ScalarDistance (distance LeaderControl_10 ContextData_10)
);setq
(setq ScalarSign 1.0
ScalarDistance LeaderControl_40
);setq
);if
(setq ContentBasePosition_10 (mapcar '+ LeaderControl_10 (leemac:vxs DogLeg:uv (* ScalarDistance 1.0)))
ContextData_DXF_new (subst (cons 10 ContentBasePosition_10) (assoc 10 ContextData_DXF_new) ContextData_DXF_new)
);setq
;; Reset Content Base Postion -->
);(= MULTILEADER_172 acBlockContent)
);cond
;; Content Type -->
;; <!-- Reset MLeader Plane X-Axis and Y-Axis Directions:
(setq Vector:v (mapcar '- ContextData_110 LeaderControl_10)
Vector:uv (leemac:unit Vector:v)
VectorsVDP (leemac:vxv Vector:uv LeaderControl_11)
VectorsAngle (leemac:acos VectorsVDP)
ScalarDistance (distance LeaderControl_10 ContextData_110)
;; 2D Vector Rotation:
VectorX (- (* (car DogLeg:uv) (cos VectorsAngle)) (* (cadr DogLeg:uv) (sin VectorsAngle)))
VectorY (+ (* (cadr DogLeg:uv) (cos VectorsAngle)) (* (car DogLeg:uv) (sin VectorsAngle)))
ContextData_DXF_new (subst (cons 111 sv_ucsxdir_wcs) (assoc 111 ContextData_DXF_new) ContextData_DXF_new)
ContextData_DXF_new (subst (cons 112 sv_ucsydir_wcs) (assoc 112 ContextData_DXF_new) ContextData_DXF_new)
);setq
;; Reset MLeader Plane X-Axis and Y-Axis Directions -->
;; <!-- Reconstruct MLeader
(setq list_Leaders_new nil
list_Leaders_copy list_Leaders
);setq
;; Recalculate Leader_10 from LeaderControl_10 and DogLeg:uv for other leaders:
(while list_Leaders_copy
(setq Leader_DXF (car list_Leaders_copy)
Leader_10 (cdr (assoc 10 Leader_DXF)) ; Last Leader Line Point
Leader_11 (cdr (assoc 11 Leader_DXF)) ; Dogleg Vector
);setq
(if (minusp (leemac:vxv Leader_11 LeaderControl_11))
(setq ScalarSign -1.0)
(setq ScalarSign 1.0)
);if
(setq Leader_11_new (leemac:vxs DogLeg:uv ScalarSign)
ScalarDistance (distance Leader_10 LeaderControl_10)
Leader_10_new (mapcar '+ LeaderControl_10 (leemac:vxs DogLeg:uv ScalarDistance))
Leader_DXF_new Leader_DXF
Leader_DXF_new (subst (cons 11 Leader_11_new) (assoc 11 Leader_DXF_new) Leader_DXF_new)
Leader_DXF_new (subst (cons 10 Leader_10_new) (assoc 10 Leader_DXF_new) Leader_DXF_new)
list_Leaders_new (append list_Leaders_new (list Leader_DXF_new))
list_Leaders_copy (cdr list_Leaders_copy)
);setq
);while list_Leaders_copy
(setq list_Leaders (cons LeaderControl_DXF list_Leaders_new)
Leaders_DXF_new (apply 'append list_Leaders)
ContextData_DXF_new (append ContextData_DXF_new Leaders_DXF_new)
ContextData_DXF_new (cons '(300 . "CONTEXT_DATA{") ContextData_DXF_new)
ContextData_DXF_new (reverse (cons '(301 . "}") (reverse ContextData_DXF_new)))
);setq
(setq MULTILEADER_DXF_new
(append MULTILEADER_DXF_new
ContextData_DXF_new
);append
);setq
(entmod MULTILEADER_DXF_new)
(entupd MULTILEADER_ename)
;; Reconstruct MLeader -->
);repeat (sslength ss_MULTILEADER)
);ss_MULTILEADER
);cond
(princ)
);c:mleadercontentalign
;;------------------------------------------------------------------------------
;; Vector Norm - Lee Mac
;; Args: v - vector in R^n
(defun leemac:norm ( v )
(sqrt (apply '+ (mapcar '* v v)))
)
;; Vector x Scalar - Lee Mac
;; Args: v - vector in R^n, s - real scalar
(defun leemac:vxs ( v s )
(mapcar '(lambda ( n ) (* n s)) v)
)
;; Unit Vector - Lee Mac
;; Args: v - vector in R^n
(defun leemac:unit ( v )
( (lambda ( n ) (if (equal 0.0 n 1e-14) nil (leemac:vxs v (/ 1.0 n)))) (leemac:norm v))
)
;; Vector Cross Product - Lee Mac
;; Args: u,v - vectors in R^3
(defun leemac:v^v ( u v )
(list
(- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
(- (* (car v) (caddr u)) (* (car u) (caddr v)))
(- (* (car u) (cadr v)) (* (car v) (cadr u)))
)
)
;; Vector Dot Product - Lee Mac
;; Args: u,v - vectors in R^n
(defun leemac:vxv ( u v )
(apply '+ (mapcar '* u v))
)
;; ArcCosine - Lee Mac
;; Args: -1 <= x <= 1
(defun leemac:acos ( x )
(if (<= -1.0 x 1.0)
(atan (sqrt (- 1.0 (* x x))) x)
)
)
;;------------------------------------------------------------------------------
(princ "\nMLeaderContentAlign loaded. Start command with MLEADERCONTENTALIGN.")
(princ)
This is a handy routine! Nice work. Thanks for sharing!
We have an issue that I'd like to have you take a look at. In the example below, the original leaders are at the bottom, the "fixed" ones (via MLEADERCONTENTALIGN) are at the top. It only seems to happen on MLeaders in which the leader is I've attached a drawing file for you to experiment with if you are so inclined.
In reviewing the DXF info of each original MLeader, the only thing I see different (other than the obvious coordinates, etc.) is the first Group 90 code.
The MLeader that flipped correctly (A0202), was (90 . 0). The other (C1801) was (90 . 1).
Would love to have a fix for this.
Thanks, again.
I'm still trying to get my MLeaders to "straighten up"! 
I've noticed something interesting on leaders that have been re-aligned (via MLEADERSALIGN): when you attempt to add a leader, it adds it as if the block content was still rotated. And then, if you move or copy the modified leader, the "connection points" re-attach as if the block was still rotated.
Gotta love MLeaders!
Hi Chris,
My apologies for not replying to you sooner.
I did revisit this program when you provided your example drawing and hoped to reply with a solution but unfortunately the revisit has been a work in progress and then...Christmas
I appreciate the example drawings you've been providing; it's good to have more scenarios to test.
I'll also take into account the leader attachment point issue when leaders added.
Hopefully it will all fall into place soon...and yes, I agree, gotta love MLEADERS!
Regards,
Trevor
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
