@kmohs wrote:
.... I switched to ANSI31.
In regards to hpang, can that be set to be 45d from the line selected for the offset?
Is your intent to use ANSI31 [which already makes lines at 45° to the HPANG setting's direction] and set the angle to 45° so that the Hatch lines will be perpendicular to the selected edge? Or do you want the Hatch lines at 45° relative to the selected edge?
I would forget about using ANSI31, and use the User-specified option. That way, you can set the angle directly, rather than "correcting for" the native 45° angle of ANSI31's definition. And you can set the line spacing directly, in drawing units, rather than calculate something based on what the spacing happens to be in ANSI31's definition [1/8" in the Imperial-variety definition, 3.175 units in ISO].
Kent Cooper, AIA 
@john.uhden wrote:
He is absolutely smart to use ANSI31. At a rotation of 0°, it is naturally at 45° to the X and Y axes. ....
That's why I asked the question in reply to their:
"In regards to hpang, can that be set to be 45d...?"
Setting HPANG to 45° will turn ANSI31's diagonals to orthogonal, or perpendicular to an edge if HPANG is set to 45° relative to that edge. I suspect maybe that is not what they really want.
Kent Cooper, AIA
@kmohs wrote:
You're correct in that the hatch should be _user, and set at 45° relative to the selected edge.
Here's an adjustment of my earlier routine to do that. The 0.75-unit line spacing seemed a reasonable one for a 2-unit perimeter Hatch-band width, but you can change that to suit. Also note the need to give it the right Layer name. Lightly tested.
(defun C:OI2H ; = Offset Inward by 2 drawing units, and Hatch
(/ *error* doc ss ent obj oarea pickpt pl2)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); if
(vla-endundomark doc)
(princ)
); defun - *error*
(vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
(prompt "\nBuilding outline to Offset Inward and Hatch: ")
(if (setq ss (ssget "_:S+." '((0 . "LWPOLYLINE") (-4 . "&") (70 . 1)))); one, closed only
(progn ; then
(setq
obj (vlax-ename->vla-object (setq ent (ssname ss 0)))
oarea (vla-get-Area obj)
pickpt (vlax-curve-getClosestPointTo obj (last (last (last (ssnamex ss)))))
); setq
(vla-offset obj 2)
(if (> (vla-get-Area (vlax-ename->vla-object (entlast))) oarea)
(progn ; then -- went wrong way
(entdel (entlast))
(vla-offset obj -2)
); progn
); if [went wrong way -- no else; do nothing if it went right way]
(command
"_.hatch" "USER"
(cvunit
(+
(angle '(0 0 0) (vlax-curve-getFirstDeriv obj (vlax-curve-getParamAtPoint obj pickpt)))
(/ pi 4)
); +
"radian" "degree"
); cvunit
0.75 "_no" ent (setq pl2 (entlast)) "" "" ; <-- EDIT 0.75 as preferred
"_.chprop" "_last" "" "_layer" "YourLayerName" "" ; <-- EDIT Layer name
"_.erase" pl2 ""
)
); progn -- then
); if
(vla-endundomark doc)
(princ)
); defun -- C:OI2H
(vl-load-com)
(prompt "\nType OI2H to Offset Inward by 2 drawing units and Hatch.")
Kent Cooper, AIA
John and Kent, just a out there having a play with linetype using "/" then its always in direction of line. This is close maybe change angle a bit. R=? Not sure can remove the dot.
*BLD,bld ----------/----------/----------/----------
A,0.0,-1.5,["/",STANDARD,S=1.8,R=0.0,X=-.9,Y=-.9]
You have much more control if you use the TXT.shx font, and the "pipe" character | which in that font is exactly the specified text height in length, and vertical so you can be exact about the rotation, and you can get the dots buried. [The dots in the image "show" only at certain zoom levels, but except at the corners they are, in fact, buried in the text elements.]
*BLD,bld / / / / / / /
A,0,["|",TXT,S=1.41421356,X=-.5,Y=-.5,R=-45],-1.5
The linetype scale is the width of the "hatched" band -- no guesswork or weird calculations needed to know how far to Offset the building footprint to where the path of the band needs to be. Change the -1.5 for a different density.
It uses the midline for the path, which is why the dots show at the corners, because when I define it to use one edge (the building outline so dots would be buried in that), it can do this kind of thing:
Kent Cooper, AIA