Adding a background mask to mleader routine

[robw]

Hi, I've made a simple routine that draws a multileader on a layer.

What I don't know how to do is add a background mask to it.

I'd also like to be able to create different variations of the routine to change the background color and text frame size.

What I have so far:

(defun c:mleaderA1 (/)
  (command "-layer" "m" "TEXT-LEADERS" "c" "t" "0,0,0" "" "" "cmleaderstyle" "Standard")
  (command ".mleader")
)

I know - good eh...? lol

Any ideas?

Thanks

[ВeekeeCZ]

; for AutoCAD 2016+

(defun c:MleaderA1 ( / m l e)

  (setq m (getvar 'cmleaderstyle)
	l (getvar 'clayer))
  (setvar 'cmleaderstyle "STANDARD")
  (command "_.-LAYER" "_T" "TEXT-LEADERS" "_M" "TEXT-LEADERS" "_C" "_T" "0,0,0" "" "")

  (setq e (entlast))
  (command-s "_.MLEADER")
  (if (not (equal e (setq e (entlast))))
    (setpropertyvalue e "MText/BackgroundFill" 1))

  (setvar 'cmleaderstyle m)
  (setvar 'clayer l)
  (princ)
  )

[robw]

Hey, thanks for this.

Is there any way to set the color as well?

[ВeekeeCZ]

Color of what? A background?

Post a dwg with example.

[ronjonp]

Try THIS.

[robw]

Very good - thanks.
I'll give it a go

[robw]

Overall vision: 

Click on custom button on my ribbon. It starts the multileader object.

I choose the point of the arrow first, then where to place the text.

I enter my text, hit return to finish.

The routine automatically adds a text background mask, with a fill color and border offset specified within the routine.

Hey presto finished mutlileader.

Reason being I  wanted different routines for different text styles and sizes, so I'd need to be able to adjust them.

Thanks again

[robw]

Hi, something like the attached.

Thanks

[ВeekeeCZ]

Well, just you to know, setting a color to mleader, a TrueColor specifically, is not so a simple task.

And I really don't want to play with this so much... so I used some portions of the Lees code.

When you will do a clones, use the Lees routine to get the setting of color! Read the note. Watch the format... add an apostrophe!

(vl-load-com)
; for AutoCAD 2016+


(defun c:MleaderA1 ( / m l e mask:main mask:maskentity mask:substonce)
  
  
  ;; from "\n:: Mask.lsp | Version 1.5 | (c) Lee Mac "
  
  (defun mask:main ( ent msk off trn col )
    (mask:maskentity ent (= "1" msk) off (= "1" trn) col))
  
  ;;----------------------------------------------------------------------;;
  
  (defun mask:maskentity ( ent msk off trn col / enx )
    (setq enx (entget ent))
    (entmod (mask:substonce enx (if msk
				  (list (cons 091 (mask:color->mleadercolor (if trn '((62 . 256)) col)))
					(cons 141 off)
					(if trn '(291 . 1) '(291 . 0))
					'(292 . 1)
					)
				  '((292 . 0)))))
    (vla-put-textlinespacingfactor (vlax-ename->vla-object ent) (cdr (assoc 045 enx)))) ;; AutoCAD bug
  
  ;;----------------------------------------------------------------------;;
  
  (defun mask:substonce ( enx lst )
    (mapcar
      '(lambda ( dxf / itm )
	 (cond ((setq itm (assoc (car dxf) lst))
		(setq lst (vl-remove itm lst))
		itm)
	       (dxf)))
      enx))
  
  
  ; ----------------------------------------------------------------------------
  ; BeekeeCZ
  
  (setq m (getvar 'cmleaderstyle)
	l (getvar 'clayer))
  (setvar 'cmleaderstyle "STANDARD")
  (command "_.-LAYER" "_T" "TEXT-LEADERS" "_M" "TEXT-LEADERS" "_C" "_T" "0,0,0" "" "")
  
  (setq e (entlast))
  (command-s "MLEADER")
  (if (not (equal e (setq e (entlast))))
    (mask:main e "1" 1.6 "0" '((62 . 160) (420 . 19455))))      ; <---- to get this line run Lee's routine where 
  								; add this line: (print (cons sel tmp))    prior to this line (apply 'mask:main (cons sel tmp))
  (setvar 'cmleaderstyle m)
  (setvar 'clayer l)
  (princ)
  )

[robw]

Ok, the good ship Lisp has sailed well beyond my understanding horizon. 

I had hoped it would be fairly straight forward. I certainly didn't want anyone spending too long helping me. 

Maybe I'll just carry on matching properties to an existing mleader.

Thanks for your efforts/time.

[ronjonp]

Your sample drawing already has different mleader styles in it. Why does this not work for you?

All you need to do is set the correct CMLEADERSTYLE variable before starting the mleader command.

[ВeekeeCZ]

Can be a background color (mask) part of style? 

[ВeekeeCZ]

---

@robw wrote:

...

Maybe I'll just carry on matching properties to an existing mleader.

...

---

Don't you dare! At least don't tell me.

[robw]

I wanted each mleader style on a button on a custom ribbon, so when I install the ribbon on someone else's AutoCAD they don't have to do multiple steps to get the mleader to look correct. They just press the 'Woodland' mleader button and off they go.

[ronjonp]

---

@ВeekeeCZ wrote:

Can be a background color (mask) part of style? 

---

I thought so .. but after checking nope! 🤓

[robw]

Yeah, there's nothing about it inside the mleader dialog.

To me, it's more of a mtext function.

[ВeekeeCZ]

Here's version formatted a bit differently... to make clones easier. You still need to run Lee's routine when setting the color number.

(vl-load-com)
; for AutoCAD 2016+

;                     	 		style 	  layer         laycolor    mask offset color-index color-number  
(defun c:MLeaderA1 () (MleaderCustom "STANDARD" "TEXT-LEADERS"   "0,0,0"    T	1.6	160		19455)		(princ))
(defun c:MLeaderA2 () (MleaderCustom "woodland" "MLEDER WOODLAND" "1,150,0" nil 1.6	160		19455)		(princ))



; <---- to get last color number  run Lee's routine where
; add this line: (print (cons sel tmp))    prior to this line (apply 'mask:main (cons sel tmp))

(defun MleaderCustom (stl lay lct mas ofs mci mcn / m l e mask:main mask:maskentity mask:substonce)
  
  
  ;; from "\n:: Mask.lsp | Version 1.5 | (c) Lee Mac "
  
  (defun mask:main ( ent msk off trn col )
    (mask:maskentity ent (= "1" msk) off (= "1" trn) col))
  
  ;;----------------------------------------------------------------------;;
  
  (defun mask:maskentity ( ent msk off trn col / enx )
    (setq enx (entget ent))
    (entmod (mask:substonce enx (if msk
				  (list (cons 091 (mask:color->mleadercolor (if trn '((62 . 256)) col)))
					(cons 141 off)
					(if trn '(291 . 1) '(291 . 0))
					'(292 . 1)
					)
				  '((292 . 0)))))
    (vla-put-textlinespacingfactor (vlax-ename->vla-object ent) (cdr (assoc 045 enx)))) ;; AutoCAD bug
  
  ;;----------------------------------------------------------------------;;
  
  (defun mask:substonce ( enx lst )
    (mapcar
      '(lambda ( dxf / itm )
	 (cond ((setq itm (assoc (car dxf) lst))
		(setq lst (vl-remove itm lst))
		itm)
	       (dxf)))
      enx))
  
  
  ; ----------------------------------------------------------------------------
  ; BeekeeCZ
  
  (setq m (getvar 'cmleaderstyle)
	l (getvar 'clayer))
  (setvar 'cmleaderstyle stl)
  (setvar 'cmdecho 0)
  (command "_.-LAYER" "_T" lay "_M" lay "_C" "_T" lct "" "")
  (setvar 'cmdecho 1)
  
  (setq e (entlast))
  (command-s "MLEADER")
  (if (not (equal e (setq e (entlast))))
    (mask:main e T ofs nil (list (cons 62 mci) (cons 420 mcn))))     
  (setvar 'cmleaderstyle m)
  (setvar 'clayer l)
  (princ)
  )

[ВeekeeCZ]

---

@ronjonp wrote:

---

@ВeekeeCZ wrote:

Can be a background color (mask) part of style? 

---

I thought so .. but after checking nope! 🤓

---

Well, I thought that the mask setting is just on/off for mleaders. Did not know that color setting is buried somewhere in mtext ribbon. We all learn.

[ronjonp]

Maybe try this to quickly set the current mleader style:

(defun c:foo (/ ml)
  ;; RJP » 2020-10-08
  ;; Set current mleaderstyle
  (if (setq ml (dictsearch (namedobjdict) "ACAD_MLEADERSTYLE"))
    (progn (setq ml (mapcar 'cdr (vl-remove-if '(lambda (x) (/= 3 (car x))) ml)))
	   (or *glbl* (setq *glbl* (car ml)))
	   (setq ml (mapcar '(lambda (x) (strcat (vl-string-translate " " "+" x) " ")) ml))
	   (initget 0 (apply 'strcat ml))
	   (setq
	     *glbl* (cond ((getkword (strcat "\n["
					     (apply 'strcat (mapcar '(lambda (x) (strcat x "/")) ml))
					     "]: <"
					     *glbl*
					     ">: "
				     )
			   )
			  )
			  (*glbl*)
		    )
	   )
	   (setvar 'cmleaderstyle (vl-string-translate "+" " " *glbl*))
    )
  )
  (princ)
)